lisp/ediff-merg.el

   1 ;;; ediff-merg.el --- merging utilities
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27
  28 ;; compiler pacifier
  29 (defvar ediff-window-A)
  30 (defvar ediff-window-B)
  31 (defvar ediff-window-C)
  32 (defvar ediff-merge-window-share)
  33 (defvar ediff-window-config-saved)
  34
  35 (eval-when-compile
  36   (require 'ediff-util))
  37 ;; end pacifier
  38
  39 (require 'ediff-init)
  40
  41 (defcustom ediff-quit-merge-hook 'ediff-maybe-save-and-delete-merge
  42   "Hooks to run before quitting a merge job.
  43 The most common use is to save and delete the merge buffer."
  44   :type 'hook
  45   :group 'ediff-merge)
  46
  47
  48 (defcustom ediff-default-variant 'combined
  49   "The variant to be used as a default for buffer C in merging.
  50 Valid values are the symbols `default-A', `default-B', and `combined'."
  51   :type '(radio (const default-A) (const default-B) (const combined))
  52   :group 'ediff-merge)
  53
  54 (defcustom ediff-combination-pattern
  55   '("<<<<<<< variant A" A ">>>>>>> variant B" B  "####### Ancestor" Ancestor "======= end")
  56   "Pattern to be used for combining difference regions in buffers A and B.
  57 The value must be a list of the form
  58 \(STRING1 bufspec1  STRING2 bufspec2 STRING3 bufspec3 STRING4)
  59 where bufspec is the symbol A, B, or Ancestor. For instance, if the value is
  60 '(STRING1 A  STRING2 Ancestor STRING3 B STRING4) then the
  61 combined text will look like this:
  62
  63 STRING1
  64 diff region from variant A
  65 STRING2
  66 diff region from the ancestor
  67 STRING3
  68 diff region from variant B
  69 STRING4
  70 "
  71   :type '(choice (list string symbol string symbol string)
  72                  (list string symbol string symbol string symbol string))
  73   :group 'ediff-merge)
  74
  75 (defcustom ediff-show-clashes-only nil
  76   "If t, show only those diff regions where both buffers disagree with the ancestor.
  77 This means that regions that have status prefer-A or prefer-B will be
  78 skipped over.  A value of nil means show all regions."
  79   :type 'boolean
  80   :group 'ediff-merge
  81   )
  82 (make-variable-buffer-local 'ediff-show-clashes-only)
  83
  84 (defcustom ediff-skip-merge-regions-that-differ-from-default nil
  85   "If t, show only the regions that have not been changed by the user.
  86 A region is considered to have been changed if it is different from the current
  87 default (`default-A', `default-B', `combined') and it hasn't been marked as
  88 `prefer-A' or `prefer-B'.
  89 A region is considered to have been changed also when it is marked as
  90 as `prefer-A', but is different from the corresponding difference region in
  91 Buffer A or if it is marked as `prefer-B' and is different from the region in
  92 Buffer B."
  93   :type 'boolean
  94   :group 'ediff-merge
  95   )
  96 (make-variable-buffer-local 'ediff-skip-merge-regions-that-differ-from-default)
  97
  98 ;; check if there is no clash between the ancestor and one of the variants.
  99 ;; if it is not a merge job then return true
 100 (defun ediff-merge-region-is-non-clash (n)
 101   (if (ediff-merge-job)
 102       (string-match "prefer" (or (ediff-get-state-of-merge n) ""))
 103     t))
 104
 105 ;; If ediff-show-clashes-only, check if there is no clash between the ancestor
 106 ;; and one of the variants.
 107 (defun ediff-merge-region-is-non-clash-to-skip (n)
 108   (and (ediff-merge-job)
 109        ediff-show-clashes-only
 110        (ediff-merge-region-is-non-clash n)))
 111
 112 ;; If ediff-skip-changed-regions, check if the merge region differs from
 113 ;; the current default. If a region is different from the default, it means
 114 ;; that the user has made determination as to how to merge for this particular
 115 ;; region.
 116 (defun ediff-skip-merge-region-if-changed-from-default-p (n)
 117   (and (ediff-merge-job)
 118        ediff-skip-merge-regions-that-differ-from-default
 119        (ediff-merge-changed-from-default-p n 'prefers-too)))
 120
 121
 122 (defun ediff-get-combined-region (n)
 123   (let ((pattern-list ediff-combination-pattern)
 124         (combo-region "")
 125         (err-msg
 126          "ediff-combination-pattern: Invalid format. Please consult the documentation")
 127         region-delim region-spec)
 128
 129     (if (< (length pattern-list) 5)
 130         (error err-msg))
 131
 132     (while (> (length pattern-list) 2)
 133       (setq region-delim (nth 0 pattern-list)
 134             region-spec (nth 1 pattern-list))
 135       (or (and (stringp region-delim) (memq region-spec '(A B Ancestor)))
 136           (error err-msg))
 137
 138       (condition-case nil
 139           (setq combo-region
 140                 (concat combo-region
 141                         region-delim "\n"
 142                         (ediff-get-region-contents
 143                          n region-spec ediff-control-buffer)))
 144         (error ""))
 145       (setq pattern-list (cdr (cdr pattern-list)))
 146       )
 147
 148     (setq region-delim (nth 0 pattern-list))
 149     (or (stringp region-delim)
 150         (error err-msg))
 151     (setq combo-region (concat combo-region region-delim "\n"))
 152   ))
 153
 154 ;;(defsubst ediff-make-combined-diff (regA regB)
 155 ;;  (concat (nth 0 ediff-combination-pattern) "\n"
 156 ;;        regA
 157 ;;        (nth 1 ediff-combination-pattern) "\n"
 158 ;;        regB
 159 ;;        (nth 2 ediff-combination-pattern) "\n"))
 160
 161 (defsubst ediff-set-state-of-all-diffs-in-all-buffers (ctl-buf)
 162   (let ((n 0))
 163     (while (< n ediff-number-of-differences)
 164       (ediff-set-state-of-diff-in-all-buffers n ctl-buf)
 165       (setq n (1+ n)))))
 166
 167 (defun ediff-set-state-of-diff-in-all-buffers (n ctl-buf)
 168   (let ((regA (ediff-get-region-contents n 'A ctl-buf))
 169         (regB (ediff-get-region-contents n 'B ctl-buf))
 170         (regC (ediff-get-region-contents n 'C ctl-buf)))
 171     (cond ((and (string= regA regB) (string= regA  regC))
 172            (ediff-set-state-of-diff n 'A "=diff(B)")
 173            (ediff-set-state-of-diff n 'B "=diff(C)")
 174            (ediff-set-state-of-diff n 'C "=diff(A)"))
 175           ((string= regA regB)
 176            (ediff-set-state-of-diff n 'A "=diff(B)")
 177            (ediff-set-state-of-diff n 'B "=diff(A)")
 178            (ediff-set-state-of-diff n 'C nil))
 179           ((string= regA regC)
 180            (ediff-set-state-of-diff n 'A "=diff(C)")
 181            (ediff-set-state-of-diff n 'C "=diff(A)")
 182            (ediff-set-state-of-diff n 'B nil))
 183           ((string= regB regC)
 184            (ediff-set-state-of-diff n 'C "=diff(B)")
 185            (ediff-set-state-of-diff n 'B "=diff(C)")
 186            (ediff-set-state-of-diff n 'A nil))
 187           ((string= regC (ediff-get-combined-region n))
 188            (ediff-set-state-of-diff n 'A nil)
 189              (ediff-set-state-of-diff n 'B nil)
 190              (ediff-set-state-of-diff n 'C "=diff(A+B)"))
 191           (t (ediff-set-state-of-diff n 'A nil)
 192              (ediff-set-state-of-diff n 'B nil)
 193              (ediff-set-state-of-diff n 'C nil)))
 194     ))
 195
 196 (defun ediff-set-merge-mode ()
 197   (normal-mode t)
 198   (remove-hook 'local-write-file-hooks 'ediff-set-merge-mode))
 199
 200
 201 ;; Go over all diffs starting with DIFF-NUM and copy regions into buffer C
 202 ;; according to the state of the difference.
 203 ;; Since ediff-copy-diff refuses to copy identical diff regions, there is
 204 ;; no need to optimize ediff-do-merge any further.
 205 ;;
 206 ;; If re-merging, change state of merge in all diffs starting with
 207 ;; DIFF-NUM, except those where the state is prefer-* or where it is
 208 ;; `default-*' or `combined' but the buf C region appears to be modified
 209 ;; since last set by default.
 210 (defun ediff-do-merge (diff-num &optional remerging)
 211   (if (< diff-num 0) (setq diff-num 0))
 212   (let ((n diff-num)
 213         ;;(default-state-of-merge (format "%S" ediff-default-variant))
 214         do-not-copy state-of-merge)
 215     (while (< n ediff-number-of-differences)
 216       (setq do-not-copy nil) ; reset after each cycle
 217       (if (= (mod n 10) 0)
 218           (message "%s buffers A & B into C ... region %d of %d"
 219                    (if remerging "Re-merging" "Merging")
 220                    n
 221                    ediff-number-of-differences))
 222
 223       (setq state-of-merge (ediff-get-state-of-merge n))
 224
 225       (if remerging
 226           ;;(let ((reg-A (ediff-get-region-contents n 'A ediff-control-buffer))
 227           ;;    (reg-B (ediff-get-region-contents n 'B ediff-control-buffer))
 228           ;;    (reg-C (ediff-get-region-contents n 'C ediff-control-buffer)))
 229           (progn
 230
 231             ;; if region was edited since it was first set by default
 232             (if (or (ediff-merge-changed-from-default-p n)
 233                     ;; was preferred
 234                     (string-match "prefer" state-of-merge))
 235                 ;; then ignore
 236                 (setq do-not-copy t))
 237
 238             ;; change state of merge for this diff, if necessary
 239             (if (and (string-match "\\(default\\|combined\\)" state-of-merge)
 240                      (not do-not-copy))
 241                 (ediff-set-state-of-merge
 242                  n (format "%S" ediff-default-variant)))
 243             ))
 244
 245       ;; state-of-merge may have changed via ediff-set-state-of-merge, so
 246       ;; check it once again
 247       (setq state-of-merge (ediff-get-state-of-merge n))
 248
 249       (or do-not-copy
 250           (if (string= state-of-merge "combined")
 251               ;; use n+1 because ediff-combine-diffs works via user numbering
 252               ;; of diffs, which is 1+ to what ediff uses internally
 253               (ediff-combine-diffs (1+ n) 'batch)
 254             (ediff-copy-diff
 255              n (if (string-match "-A" state-of-merge) 'A 'B) 'C 'batch)))
 256       (setq n (1+ n)))
 257     (message "Merging buffers A & B into C ... Done")
 258     ))
 259
 260
 261 (defun ediff-re-merge ()
 262   "Remerge unmodified diff regions using a new default.  Start with the current region."
 263   (interactive)
 264   (let* ((default-variant-alist
 265            (list '("default-A") '("default-B") '("combined")))
 266          (actual-alist
 267           (delete (list (symbol-name ediff-default-variant))
 268                   default-variant-alist)))
 269     (setq ediff-default-variant
 270           (intern
 271            (completing-read
 272             (format "Current merge default is `%S'.  New default: "
 273                     ediff-default-variant)
 274             actual-alist nil 'must-match)))
 275     (ediff-do-merge ediff-current-difference 'remerge)
 276     (ediff-recenter)
 277   ))
 278
 279 (defun ediff-shrink-window-C (arg)
 280   "Shrink window C to just one line.
 281 With a prefix argument, returns window C to its normal size.
 282 Used only for merging jobs."
 283   (interactive "P")
 284   (if (not ediff-merge-job)
 285       (error "ediff-shrink-window-C can be used only for merging jobs"))
 286   (cond ((eq arg '-) (setq arg -1))
 287         ((not (numberp arg)) (setq arg nil)))
 288   (cond ((null arg)
 289          (let ((ediff-merge-window-share
 290                 (if (< (window-height ediff-window-C) 3)
 291                     ediff-merge-window-share 0)))
 292            (setq ediff-window-config-saved "") ; force redisplay
 293            (ediff-recenter 'no-rehighlight)))
 294         ((and (< arg 0) (> (window-height ediff-window-C) 2))
 295          (setq ediff-merge-window-share (* ediff-merge-window-share 0.9))
 296          (setq ediff-window-config-saved "") ; force redisplay
 297          (ediff-recenter 'no-rehighlight))
 298         ((and (> arg 0) (> (window-height ediff-window-A) 2))
 299          (setq ediff-merge-window-share (* ediff-merge-window-share 1.1))
 300          (setq ediff-window-config-saved "") ; force redisplay
 301          (ediff-recenter 'no-rehighlight))))
 302
 303
 304 ;; N here is the user's region number.  It is 1+ what Ediff uses internally.
 305 (defun ediff-combine-diffs (n &optional batch-invocation)
 306   "Combine Nth diff regions of buffers A and B and place the combination in C.
 307 N is a prefix argument.  If nil, combine the current difference regions.
 308 Combining is done according to the specifications in variable
 309 `ediff-combination-pattern'."
 310   (interactive "P")
 311   (setq n (if (numberp n) (1- n) ediff-current-difference))
 312
 313   (let (reg-combined)
 314     ;;(setq regA (ediff-get-region-contents n 'A ediff-control-buffer)
 315     ;;    regB (ediff-get-region-contents n 'B ediff-control-buffer))
 316     ;;(setq reg-combined (ediff-make-combined-diff regA regB))
 317     (setq reg-combined (ediff-get-combined-region n))
 318
 319     (ediff-copy-diff n nil 'C batch-invocation reg-combined))
 320     (or batch-invocation (ediff-jump-to-difference (1+ n))))
 321
 322
 323 ;; Checks if the region in buff C looks like a combination of the regions
 324 ;; in buffers A and B.  Return a list (reg-a-beg reg-a-end reg-b-beg reg-b-end)
 325 ;; These refer to where the delimiters for region A, B, Ancestor start and end
 326 ;; in buffer C
 327 (defun ediff-looks-like-combined-merge (region-num)
 328   (if ediff-merge-job
 329       (let ((combined (string-match (regexp-quote "(A+B)")
 330                                     (or (ediff-get-state-of-diff region-num 'C)
 331                                         "")))
 332             (mrgreg-beg (ediff-get-diff-posn 'C 'beg region-num))
 333             (mrgreg-end (ediff-get-diff-posn 'C 'end region-num))
 334             (pattern-list ediff-combination-pattern)
 335             delim reg-beg reg-end delim-regs-list)
 336
 337         (if combined
 338             (ediff-with-current-buffer ediff-buffer-C
 339               (while pattern-list
 340                 (goto-char mrgreg-beg)
 341                 (setq delim (nth 0 pattern-list))
 342                 (search-forward delim mrgreg-end 'noerror)
 343                 (setq reg-beg (match-beginning 0))
 344                 (setq reg-end (match-end 0))
 345                 (if (and reg-beg reg-end)
 346                     (setq delim-regs-list
 347                           ;; in reverse
 348                           (cons reg-end (cons reg-beg delim-regs-list))))
 349                 (if (> (length pattern-list) 1)
 350                     (setq pattern-list (cdr (cdr pattern-list)))
 351                   (setq pattern-list nil))
 352                 )))
 353
 354         (reverse delim-regs-list)
 355         )))
 356
 357 (defvar state-of-merge)                 ; dynamic var
 358
 359 ;; Check if the non-preferred merge has been modified since originally set.
 360 ;; This affects only the regions that are marked as default-A/B or combined.
 361 ;; If PREFERS-TOO is non-nil, then look at the regions marked as prefers-A/B as
 362 ;; well.
 363 (defun ediff-merge-changed-from-default-p (diff-num &optional prefers-too)
 364   (let ((reg-A (ediff-get-region-contents diff-num 'A ediff-control-buffer))
 365         (reg-B (ediff-get-region-contents diff-num 'B ediff-control-buffer))
 366         (reg-C (ediff-get-region-contents diff-num 'C ediff-control-buffer)))
 367
 368     (setq state-of-merge (ediff-get-state-of-merge diff-num))
 369
 370     ;; if region was edited since it was first set by default
 371     (or (and (string= state-of-merge "default-A")
 372              (not (string= reg-A reg-C)))
 373         (and (string= state-of-merge "default-B")
 374              (not (string= reg-B reg-C)))
 375         (and (string= state-of-merge "combined")
 376              ;;(not (string= (ediff-make-combined-diff reg-A reg-B) reg-C)))
 377              (not (string= (ediff-get-combined-region diff-num) reg-C)))
 378         (and prefers-too
 379              (string= state-of-merge "prefer-A")
 380              (not (string= reg-A reg-C)))
 381         (and prefers-too
 382              (string= state-of-merge "prefer-B")
 383              (not (string= reg-B reg-C)))
 384         )))
 385
 386
 387 (provide 'ediff-merg)
 388
 389
 390 ;; Local Variables:
 391 ;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
 392 ;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
 393 ;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
 394 ;; End:
 395
 396 ;; arch-tag: 9b798cf9-02ba-487f-a62e-b63aa823dbfb
 397 ;;; ediff-merg.el ends here