lisp/echistory.el

   1 ;;; echistory.el --- Electric Command History Mode
   2
   3 ;; Copyright (C) 1985, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: FSF
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'electric)                     ; command loop
  29 (require 'chistory)                     ; history lister
  30
  31 ;;;###autoload
  32 (defun Electric-command-history-redo-expression (&optional noconfirm)
  33   "Edit current history line in minibuffer and execute result.
  34 With prefix arg NOCONFIRM, execute current line as-is without editing."
  35   (interactive "P")
  36   (let (todo)
  37     (save-excursion
  38       (set-buffer "*Command History*")
  39       (beginning-of-line)
  40       (setq todo (read (current-buffer)))
  41       (if (boundp 'electric-history-in-progress)
  42           (if todo (throw 'electric-history-quit (list noconfirm todo)))))))
  43
  44 (defvar electric-history-map
  45   (let ((map (make-sparse-keymap)))
  46     (define-key map [t] 'Electric-history-undefined)
  47     (define-key map "\e" (make-sparse-keymap))
  48     (define-key map [?\e t] 'Electric-history-undefined)
  49     (define-key map "\C-u" 'universal-argument)
  50     (define-key map " " 'Electric-command-history-redo-expression)
  51     (define-key map "!" 'Electric-command-history-redo-expression)
  52     (define-key map "\e\C-x" 'eval-sexp)
  53     (define-key map "\e\C-d" 'down-list)
  54     (define-key map "\e\C-u" 'backward-up-list)
  55     (define-key map "\e\C-b" 'backward-sexp)
  56     (define-key map "\e\C-f" 'forward-sexp)
  57     (define-key map "\e\C-a" 'beginning-of-defun)
  58     (define-key map "\e\C-e" 'end-of-defun)
  59     (define-key map "\e\C-n" 'forward-list)
  60     (define-key map "\e\C-p" 'backward-list)
  61     (define-key map "q" 'Electric-history-quit)
  62     (define-key map "\C-c" nil)
  63     (define-key map "\C-c\C-c" 'Electric-history-quit)
  64     (define-key map "\C-]" 'Electric-history-quit)
  65     (define-key map "\C-z" 'suspend-frame)
  66     (define-key map (char-to-string help-char) 'Helper-help)
  67     (define-key map "?" 'Helper-describe-bindings)
  68     (define-key map "\e>" 'end-of-buffer)
  69     (define-key map "\e<" 'beginning-of-buffer)
  70     (define-key map "\n" 'next-line)
  71     (define-key map "\r" 'next-line)
  72     (define-key map "\177" 'previous-line)
  73     (define-key map "\C-n" 'next-line)
  74     (define-key map "\C-p" 'previous-line)
  75     (define-key map "\ev" 'scroll-down)
  76     (define-key map "\C-v" 'scroll-up)
  77     (define-key map [home] 'beginning-of-buffer)
  78     (define-key map [down] 'next-line)
  79     (define-key map [up] 'previous-line)
  80     (define-key map [prior] 'scroll-down)
  81     (define-key map [next] 'scroll-up)
  82     (define-key map "\C-l" 'recenter)
  83     (define-key map "\e\C-v" 'scroll-other-window)
  84     map)
  85   "Keymap for Electric Command History mode.")
  86
  87 (defvar electric-command-history-hook nil
  88   "If non-nil, its value is called by `electric-command-history'.")
  89
  90 (defun electric-command-history ()
  91   "\\<electric-history-map>Major mode for examining and redoing commands from `command-history'.
  92 This pops up a window with the Command History listing.
  93 The number of command listed is controlled by `list-command-history-max'.
  94 The command history is filtered by `list-command-history-filter' if non-nil.
  95 Combines typeout Command History list window with menu like selection
  96 of an expression from the history for re-evaluation in the *original* buffer.
  97
  98 The history displayed is filtered by `list-command-history-filter' if non-nil.
  99
 100 Like Emacs-Lisp mode except that characters do not insert themselves and
 101 Tab and Linefeed do not indent.  Instead these commands are provided:
 102 \\{electric-history-map}
 103
 104 Calls the value of `electric-command-history-hook' if that is non-nil.
 105 The Command History listing is recomputed each time this mode is invoked."
 106   (interactive)
 107   (let ((electric-history-in-progress t)
 108         (old-buffer (current-buffer))
 109         (todo))
 110     (unwind-protect
 111         (setq todo
 112               (catch 'electric-history-quit
 113                 (save-window-excursion
 114                   (save-window-excursion
 115                     (list-command-history)
 116                     (set-buffer "*Command History*")
 117                     (Command-history-setup)
 118                     (setq major-mode 'electric-command-history)
 119                     (setq mode-name "Electric History")
 120                     (use-local-map electric-history-map))
 121                   (Electric-pop-up-window "*Command History*")
 122                   (run-hooks 'electric-command-history-hook)
 123                   (if (eobp)
 124                       (progn (ding)
 125                              (message "No command history.")
 126                              (throw 'electric-history-quit nil))
 127                     (let ((Helper-return-blurb "return to History"))
 128                       (Electric-command-loop 'electric-history-quit
 129                                              "->" t))))))
 130       (set-buffer "*Command History*")
 131       (command-history-mode)
 132       (bury-buffer (current-buffer)))
 133     (if (consp todo)
 134         (progn (set-buffer old-buffer)
 135                (if (car todo)
 136                    (apply (car (car (cdr todo))) (cdr (car (cdr todo))))
 137                  (edit-and-eval-command "Redo: " (car (cdr todo))))))))
 138
 139 (defun Electric-history-undefined ()
 140   (interactive)
 141   (ding)
 142   (message "%s" (substitute-command-keys "Type \\[Helper-help] for help, ? for commands, C-c C-c to quit, Space to execute"))
 143   (sit-for 4))
 144
 145 (defun Electric-history-quit ()
 146   "Quit Electric Command History, restoring previous window configuration."
 147   (interactive)
 148   (if (boundp 'electric-history-in-progress)
 149       (progn (message "")
 150              (throw 'electric-history-quit nil))))
 151
 152 (provide 'echistory)
 153
 154 ;; arch-tag: 1e5018fe-190f-44a7-9109-a895dcac4c50
 155 ;;; echistory.el ends here