lisp/mwheel.el

   1 ;;; mwheel.el --- Wheel mouse support
   2
   3 ;; Copyright (C) 1998, 2000, 2001, 2002, 2002, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009  Free Software Foundation, Inc.
   5 ;; Maintainer: William M. Perry <wmperry@gnu.org>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This code will enable the use of the infamous 'wheel' on the new
  26 ;; crop of mice.  Under XFree86 and the XSuSE X Servers, the wheel
  27 ;; events are sent as button4/button5 events.
  28
  29 ;; I for one would prefer some way of converting the button4/button5
  30 ;; events into different event types, like 'mwheel-up' or
  31 ;; 'mwheel-down', but I cannot find a way to do this very easily (or
  32 ;; portably), so for now I just live with it.
  33
  34 ;; To enable this code, simply put this at the top of your .emacs
  35 ;; file:
  36 ;;
  37 ;; (mouse-wheel-mode 1)
  38
  39 ;;; Code:
  40
  41 (require 'custom)
  42 (require 'timer)
  43
  44 (defvar mouse-wheel-mode)
  45
  46 ;; Setter function for mouse-button user-options.  Switch Mouse Wheel
  47 ;; mode off and on again so that the old button is unbound and
  48 ;; new button is bound to mwheel-scroll.
  49
  50 (defun mouse-wheel-change-button (var button)
  51   (set-default var button)
  52   ;; Sync the bindings.
  53   (when (bound-and-true-p mouse-wheel-mode) (mouse-wheel-mode 1)))
  54
  55 (defvar mouse-wheel-down-button 4)
  56 (make-obsolete-variable 'mouse-wheel-down-button
  57                         'mouse-wheel-down-event
  58                         "22.1")
  59 (defcustom mouse-wheel-down-event
  60   (if (or (featurep 'w32-win) (featurep 'ns-win))
  61       'wheel-up
  62     (intern (format "mouse-%s" mouse-wheel-down-button)))
  63   "Event used for scrolling down."
  64   :group 'mouse
  65   :type 'symbol
  66   :set 'mouse-wheel-change-button)
  67
  68 (defvar mouse-wheel-up-button 5)
  69 (make-obsolete-variable 'mouse-wheel-up-button
  70                         'mouse-wheel-up-event
  71                         "22.1")
  72 (defcustom mouse-wheel-up-event
  73   (if (or (featurep 'w32-win) (featurep 'ns-win))
  74       'wheel-down
  75     (intern (format "mouse-%s" mouse-wheel-up-button)))
  76   "Event used for scrolling up."
  77   :group 'mouse
  78   :type 'symbol
  79   :set 'mouse-wheel-change-button)
  80
  81 (defvar mouse-wheel-click-button 2)
  82 (make-obsolete-variable 'mouse-wheel-click-button
  83                         'mouse-wheel-click-event
  84                         "22.1")
  85 (defcustom mouse-wheel-click-event
  86   (intern (format "mouse-%s" mouse-wheel-click-button))
  87   "Event that should be temporarily inhibited after mouse scrolling.
  88 The mouse wheel is typically on the mouse-2 button, so it may easily
  89 happen that text is accidentally yanked into the buffer when
  90 scrolling with the mouse wheel.  To prevent that, this variable can be
  91 set to the event sent when clicking on the mouse wheel button."
  92   :group 'mouse
  93   :type 'symbol
  94   :set 'mouse-wheel-change-button)
  95
  96 (defcustom mouse-wheel-inhibit-click-time 0.35
  97   "Time in seconds to inhibit clicking on mouse wheel button after scroll."
  98   :group 'mouse
  99   :type 'number)
 100
 101 (defcustom mouse-wheel-scroll-amount '(5 ((shift) . 1) ((control) . nil))
 102   "Amount to scroll windows by when spinning the mouse wheel.
 103 This is an alist mapping the modifier key to the amount to scroll when
 104 the wheel is moved with the modifier key depressed.
 105 Elements of the list have the form (MODIFIERS . AMOUNT) or just AMOUNT if
 106 MODIFIERS is nil.
 107
 108 AMOUNT should be the number of lines to scroll, or nil for near full
 109 screen.  It can also be a floating point number, specifying the fraction of
 110 a full screen to scroll.  A near full screen is `next-screen-context-lines'
 111 less than a full screen."
 112   :group 'mouse
 113   :type '(cons
 114           (choice :tag "Normal"
 115                   (const :tag "Full screen" :value nil)
 116                   (integer :tag "Specific # of lines")
 117                   (float :tag "Fraction of window")
 118                   (cons
 119                    (repeat (choice :tag "modifier"
 120                                    (const alt) (const control) (const hyper)
 121                                    (const meta) (const shift) (const super)))
 122                    (choice :tag "scroll amount"
 123                            (const :tag "Full screen" :value nil)
 124                            (integer :tag "Specific # of lines")
 125                            (float :tag "Fraction of window"))))
 126           (repeat
 127            (cons
 128             (repeat (choice :tag "modifier"
 129                             (const alt) (const control) (const hyper)
 130                             (const meta) (const shift) (const super)))
 131             (choice :tag "scroll amount"
 132                     (const :tag "Full screen" :value nil)
 133                     (integer :tag "Specific # of lines")
 134                     (float :tag "Fraction of window")))))
 135   :set 'mouse-wheel-change-button)
 136
 137 (defcustom mouse-wheel-progressive-speed t
 138   "If non-nil, the faster the user moves the wheel, the faster the scrolling.
 139 Note that this has no effect when `mouse-wheel-scroll-amount' specifies
 140 a \"near full screen\" scroll or when the mouse wheel sends key instead
 141 of button events."
 142   :group 'mouse
 143   :type 'boolean)
 144
 145 (defcustom mouse-wheel-follow-mouse t
 146   "Whether the mouse wheel should scroll the window that the mouse is over.
 147 This can be slightly disconcerting, but some people prefer it."
 148   :group 'mouse
 149   :type 'boolean)
 150
 151 (eval-and-compile
 152   (if (fboundp 'event-button)
 153       (fset 'mwheel-event-button 'event-button)
 154     (defun mwheel-event-button (event)
 155       (let ((x (event-basic-type event)))
 156         ;; Map mouse-wheel events to appropriate buttons
 157         (if (eq 'mouse-wheel x)
 158             (let ((amount (car (cdr (cdr (cdr event))))))
 159               (if (< amount 0)
 160                   mouse-wheel-up-event
 161                 mouse-wheel-down-event))
 162           x))))
 163
 164   (if (fboundp 'event-window)
 165       (fset 'mwheel-event-window 'event-window)
 166     (defun mwheel-event-window (event)
 167       (posn-window (event-start event)))))
 168
 169 (defvar mwheel-inhibit-click-event-timer nil
 170   "Timer running while mouse wheel click event is inhibited.")
 171
 172 (defun mwheel-inhibit-click-timeout ()
 173   "Handler for `mwheel-inhibit-click-event-timer'."
 174   (setq mwheel-inhibit-click-event-timer nil)
 175   (remove-hook 'pre-command-hook 'mwheel-filter-click-events))
 176
 177 (defun mwheel-filter-click-events ()
 178   "Discard `mouse-wheel-click-event' while scrolling the mouse."
 179   (if (eq (event-basic-type last-input-event) mouse-wheel-click-event)
 180       (setq this-command 'ignore)))
 181
 182 (defun mwheel-scroll (event)
 183   "Scroll up or down according to the EVENT.
 184 This should only be bound to mouse buttons 4 and 5."
 185   (interactive (list last-input-event))
 186   (let* ((curwin (if mouse-wheel-follow-mouse
 187                      (prog1
 188                          (selected-window)
 189                        (select-window (mwheel-event-window event)))))
 190          (buffer (window-buffer curwin))
 191          (opoint (with-current-buffer buffer
 192                    (when (eq (car-safe transient-mark-mode) 'only)
 193                      (point))))
 194          (mods
 195           (delq 'click (delq 'double (delq 'triple (event-modifiers event)))))
 196          (amt (assoc mods mouse-wheel-scroll-amount)))
 197     ;; Extract the actual amount or find the element that has no modifiers.
 198     (if amt (setq amt (cdr amt))
 199       (let ((list-elt mouse-wheel-scroll-amount))
 200         (while (consp (setq amt (pop list-elt))))))
 201     (if (floatp amt) (setq amt (1+ (truncate (* amt (window-height))))))
 202     (when (and mouse-wheel-progressive-speed (numberp amt))
 203       ;; When the double-mouse-N comes in, a mouse-N has been executed already,
 204       ;; So by adding things up we get a squaring up (1, 3, 6, 10, 15, ...).
 205       (setq amt (* amt (event-click-count event))))
 206     (unwind-protect
 207         (let ((button (mwheel-event-button event)))
 208           (cond ((eq button mouse-wheel-down-event)
 209                  (condition-case nil (scroll-down amt)
 210                    ;; Make sure we do indeed scroll to the beginning of
 211                    ;; the buffer.
 212                    (beginning-of-buffer
 213                     (unwind-protect
 214                         (scroll-down)
 215                       ;; If the first scroll succeeded, then some scrolling
 216                       ;; is possible: keep scrolling til the beginning but
 217                       ;; do not signal an error.  For some reason, we have
 218                       ;; to do it even if the first scroll signaled an
 219                       ;; error, because otherwise the window is recentered
 220                       ;; for a reason that escapes me.  This problem seems
 221                       ;; to only affect scroll-down.  --Stef
 222                       (set-window-start (selected-window) (point-min))))))
 223                 ((eq button mouse-wheel-up-event)
 224                  (condition-case nil (scroll-up amt)
 225                    ;; Make sure we do indeed scroll to the end of the buffer.
 226                    (end-of-buffer (while t (scroll-up)))))
 227                 (t (error "Bad binding in mwheel-scroll"))))
 228       (if curwin (select-window curwin)))
 229     ;; If there is a temporarily active region, deactivate it iff
 230     ;; scrolling moves point.
 231     (when opoint
 232       (with-current-buffer buffer
 233         (when (/= opoint (point))
 234           (deactivate-mark)))))
 235   (when (and mouse-wheel-click-event mouse-wheel-inhibit-click-time)
 236     (if mwheel-inhibit-click-event-timer
 237         (cancel-timer mwheel-inhibit-click-event-timer)
 238       (add-hook 'pre-command-hook 'mwheel-filter-click-events))
 239     (setq mwheel-inhibit-click-event-timer
 240           (run-with-timer mouse-wheel-inhibit-click-time nil
 241                           'mwheel-inhibit-click-timeout))))
 242
 243 (defvar mwheel-installed-bindings nil)
 244
 245 ;; preloaded ;;;###autoload
 246 (define-minor-mode mouse-wheel-mode
 247   "Toggle mouse wheel support.
 248 With prefix argument ARG, turn on if positive, otherwise off.
 249 Return non-nil if the new state is enabled."
 250   :init-value t
 251   ;; We'd like to use custom-initialize-set here so the setup is done
 252   ;; before dumping, but at the point where the defcustom is evaluated,
 253   ;; the corresponding function isn't defined yet, so
 254   ;; custom-initialize-set signals an error.
 255   :initialize 'custom-initialize-delay
 256   :global t
 257   :group 'mouse
 258   ;; Remove previous bindings, if any.
 259   (while mwheel-installed-bindings
 260     (let ((key (pop mwheel-installed-bindings)))
 261       (when (eq (lookup-key (current-global-map) key) 'mwheel-scroll)
 262         (global-unset-key key))))
 263   ;; Setup bindings as needed.
 264   (when mouse-wheel-mode
 265     (dolist (event (list mouse-wheel-down-event mouse-wheel-up-event))
 266       (dolist (key (mapcar (lambda (amt) `[(,@(if (consp amt) (car amt)) ,event)])
 267                            mouse-wheel-scroll-amount))
 268         (global-set-key key 'mwheel-scroll)
 269         (push key mwheel-installed-bindings)))))
 270
 271 ;;; Compatibility entry point
 272 ;; preloaded ;;;###autoload
 273 (defun mwheel-install (&optional uninstall)
 274   "Enable mouse wheel support."
 275   (mouse-wheel-mode (if uninstall -1 1)))
 276
 277 (provide 'mwheel)
 278
 279 ;; arch-tag: 50ed00e7-3686-4b7a-8037-fb31aa5c237f
 280 ;;; mwheel.el ends here