configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.59 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.
  11 AC_PREREQ(2.59)
  12 AC_INIT
  13 AC_CONFIG_SRCDIR([src/main/main.c])
  14 AC_CONFIG_AUX_DIR(config)
  15
  16 PACKAGE=elinks
  17 VERSION=0.12.GIT
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  21 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  22 AC_CONFIG_HEADERS(config.h)
  23
  24 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  25 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  26 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  27
  28 MAKE=
  29
  30 for make in gnumake gmake make false; do
  31         if test "x$MAKE" = x; then
  32                 AC_PATH_PROGS(MAKE, "$make")
  33         fi
  34 done
  35
  36 builddir="`pwd`"
  37
  38 # Cleanup if we are configuring with a previous build in the tree
  39 if test -e Makefile.config; then
  40         AC_MSG_CHECKING([for previous build to clean])
  41         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  42         AC_MSG_RESULT(done)
  43 fi
  44
  45 # ===================================================================
  46 # Load feature configuration file and start logging features.
  47 # ===================================================================
  48
  49 features="features.conf"
  50 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  51 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  52 echo "Feature summary:" > features.log
  53
  54 # ===================================================================
  55 # Checks for programs.
  56 # ===================================================================
  57
  58 AC_PROG_CC
  59 AC_PROG_AWK
  60 AC_PATH_PROGS(AWK, "$AWK")
  61 AC_PROG_RANLIB
  62 AC_PROG_INSTALL
  63
  64 AC_PATH_PROGS(CG_COMMIT_ID, "cg-commit-id")
  65 AC_PATH_PROGS(SPARSE, "sparse")
  66
  67 CONFIG_ASCIIDOC="no"
  68 CONFIG_POD2HTML="no"
  69 CONFIG_XMLTO="no"
  70 CONFIG_JW="no"
  71
  72 if test "x$CONFIG_DOC" != xno; then
  73         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  74         if test "x$ASCIIDOC" != "x"; then
  75                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  76                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  77                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  78
  79                 echo > config.asciidoc-unsafe.txt
  80                 if "$ASCIIDOC" --unsafe config.asciidoc-unsafe.txt >/dev/null 2>/dev/null; then
  81                         ASCIIDOC_FLAGS=--unsafe
  82                 fi
  83                 rm config.asciidoc-unsafe.*
  84         fi
  85
  86         AC_PATH_PROGS(XMLTO, "xmlto")
  87         if test "x$XMLTO" != "x"; then
  88                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  89                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  90                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  91         fi
  92
  93         AC_PATH_PROGS(JW, "jw")
  94         if test "x$JW" != "x"; then
  95                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  96                 EL_CONFIG(MANUAL_JW, [PDF])
  97         fi
  98
  99         AC_PATH_PROGS(POD2HTML, "pod2html")
 100         if test "x$POD2HTML" != "x"; then
 101                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
 102         fi
 103
 104         AC_PATH_PROGS(DOXYGEN, "doxygen")
 105         if test "x$DOXYGEN" != "x"; then
 106                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 107                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 108                 AC_SUBST(api_srcdir)
 109         fi
 110 fi
 111
 112 AC_SUBST(ASCIIDOC_FLAGS)
 113 AC_SUBST(CONFIG_ASCIIDOC)
 114 AC_SUBST(CONFIG_DOXYGEN)
 115 AC_SUBST(CONFIG_POD2HTML)
 116 AC_SUBST(CONFIG_XMLTO)
 117 AC_SUBST(CONFIG_JW)
 118
 119 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 120 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 121 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 122 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 123
 124 # gcc specific options (to be continued at the bottom of configure)
 125 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 126   # We want to see all warnings and live with none.
 127   # We can't set up -Werror here as there may be some warnings in test
 128   # suite of configure, and we don't want to fail them.
 129   CFLAGS="$CFLAGS -Wall"
 130 fi
 131
 132 # ===================================================================
 133 # Checks for special OSes.
 134 # ===================================================================
 135
 136 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 137 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 138 [
 139         AC_MSG_CHECKING([for $2])
 140
 141         for flag in $3; do
 142                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 143 kill me!
 144 #endif ]])],[$1=yes],[$1=no])
 145                 if test "[$]$1" = yes; then
 146                         EL_CONFIG([$1], [$2])
 147                         break
 148                 fi
 149         done
 150
 151         AC_MSG_RESULT([$]$1)
 152 ])
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 155 AC_SUBST(CONFIG_OS_BEOS)
 156
 157 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 158 AC_SUBST(CONFIG_OS_RISCOS)
 159
 160 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 161 AC_SUBST(CONFIG_OS_WIN32)
 162
 163 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 164 AC_SUBST(CONFIG_OS_OS2)
 165 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 166
 167 AC_MSG_CHECKING([for UNIX])
 168 dnl FIXME: some depend kind of mechanism
 169 if test "$CONFIG_OS_BEOS" = no && \
 170    test "$CONFIG_OS_RISCOS" = no && \
 171    test "$CONFIG_OS_WIN32" = no && \
 172    test "$CONFIG_OS_OS2" = no; then
 173         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 174 else
 175         CONFIG_OS_UNIX=no
 176 fi
 177 AC_MSG_RESULT($CONFIG_OS_UNIX)
 178 AC_SUBST(CONFIG_OS_UNIX)
 179
 180 # ===================================================================
 181 # Checks for header files.
 182 # ===================================================================
 183
 184 AC_HEADER_DIRENT
 185 AC_HEADER_STDC
 186 AC_HEADER_SYS_WAIT
 187 AC_HEADER_TIME
 188
 189 AC_CHECK_HEADERS(wctype.h)
 190 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 191 AC_CHECK_HEADERS(sigaction.h)
 192 AC_CHECK_HEADERS(arpa/inet.h)
 193 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 194 AC_CHECK_HEADERS(net/if.h netdb.h netinet/in.h netinet/in6_var.h)
 195 AC_CHECK_HEADERS(ifaddrs.h)
 196 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 197 AC_CHECK_HEADERS(sys/fmutex.h)
 198 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 199 AC_CHECK_HEADERS(sys/resource.h)
 200 AC_CHECK_HEADERS(sys/select.h)
 201 AC_CHECK_HEADERS(sys/signal.h)
 202 AC_CHECK_HEADERS(sys/socket.h)
 203 AC_CHECK_HEADERS(sys/time.h)
 204 AC_CHECK_HEADERS(sys/utsname.h)
 205 AC_CHECK_HEADERS(stdint.h inttypes.h)
 206 AC_CHECK_HEADERS(locale.h pwd.h)
 207 AC_CHECK_HEADERS(termios.h)
 208
 209
 210 AC_CHECK_HEADERS(sys/un.h,
 211         [CONFIG_INTERLINK=yes
 212          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 213         [CONFIG_INTERLINK=no])
 214 AC_SUBST(CONFIG_INTERLINK)
 215
 216 # ===================================================================
 217 # Checks for typedefs, structures, and compiler characteristics.
 218 # ===================================================================
 219
 220 AC_STRUCT_TM
 221 AC_C_CONST
 222 AC_C_INLINE
 223 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 224
 225 AC_SYS_LARGEFILE
 226 AC_TYPE_SIZE_T
 227 AC_TYPE_OFF_T
 228 EL_CHECK_TYPE(ssize_t, int)
 229 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 230 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 231 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 232 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 233 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 234
 235 AC_CHECK_SIZEOF(char, 1)
 236 AC_CHECK_SIZEOF(short, 2)
 237 AC_CHECK_SIZEOF(int, 4)
 238 AC_CHECK_SIZEOF(long, 4)
 239 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 240 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 241
 242 # Check for variadic macros
 243 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 244                 [#include <stdio.h>
 245                  #define a(b,c...) printf(b,##c)],
 246                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 247
 248 # Check for -rdynamic
 249 #
 250 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
 251 # the executable to its dynamic symbol table.  ELinks uses this for
 252 # two purposes:
 253 #
 254 # 1. If ELinks detects a bug, it can try to display a backtrace by
 255 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
 256 #    manual states users of GNU ld must pass -rdynamic to make the
 257 #    symbols available to the program.
 258 #
 259 # 2. It would eventually be nice to dynamically load shared
 260 #    libraries as plugins (bug 73).  The plugins must be able to
 261 #    call ELinks functions.  This can be implemented either by
 262 #    registering all callable functions in ELinks-specific data
 263 #    structures, or by letting the dynamic linker handle them.
 264 #    The latter way requires something equivalent to -rdynamic.
 265 #
 266 # Because backtraces are not needed for correct operation, and bug
 267 # 73 is not yet being fixed, the configure script and makefiles
 268 # should not complain to the user if they find that -rdynamic does
 269 # not work.  Besides, it was reported at elinks-users on 2006-09-12
 270 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
 271 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
 272 # -rdynamic but does something equivalent automatically.  (This was
 273 # tested with "nm -D elinks | grep redraw_from_window".)
 274 #
 275 # FIXME: This check doesn't work. Something to do with the compiler
 276 # happily ignoring it and stderr not being checked for error messages.
 277 AC_MSG_CHECKING([for -rdynamic])
 278 LDFLAGS_X="$LDFLAGS"
 279 LDFLAGS="$LDFLAGS -rdynamic"
 280 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
 281 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
 282 AC_MSG_RESULT($have_rdynamic)
 283
 284 # ===================================================================
 285 # Check for POSIX <regex.h>
 286 # ===================================================================
 287
 288 EL_CHECK_SYS_TYPE(regex_t, HAVE_REGEX_H, [#include <regex.h>])
 289
 290 # ===================================================================
 291 # Checks for library functions.
 292 # ===================================================================
 293
 294 AC_PROG_GCC_TRADITIONAL
 295 AC_FUNC_MEMCMP
 296 AC_FUNC_MMAP
 297 AC_FUNC_STRFTIME
 298 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 299 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 300 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 301 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 302 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 303 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 304 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 305 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 306
 307 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 308
 309 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 310 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 311 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 312
 313 # These aren't probably needed now, as they are commented in links.h.
 314 # I've no idea about their historical background, but I keep them here
 315 # just in the case they will help later. --pasky
 316 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 317 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 318 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 319 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 320
 321 if test x"$HAVE_RAISE" = x; then
 322         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 323                 AC_MSG_ERROR([Unable to emulate raise()])
 324         fi
 325 fi
 326
 327 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 328 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 329 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 330 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 331         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 332 fi
 333
 334 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 335 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 336 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 337 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 338         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 339 fi
 340
 341 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 342 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 343 #include <stdio.h>
 344 #include <stdarg.h>
 345 #include <stdlib.h>
 346 #include <string.h>
 347
 348 char buf[8];
 349
 350 int bar(char *buf, const char *format, va_list ap)
 351 {
 352        return vsnprintf(buf, 0, format, ap);
 353 }
 354
 355 void foo(const char *format, ...) {
 356        va_list ap;
 357        int len;
 358
 359        va_start(ap, format);
 360        len = bar(buf, format, ap);
 361        va_end(ap);
 362        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 363
 364        va_start(ap, format);
 365        len = bar(buf, format, ap);
 366        va_end(ap);
 367        if ((len != 6) && (len != 7)) exit(1);
 368
 369        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 370
 371        exit(0);
 372 }
 373 main() { foo("hello\n"); }
 374 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 375 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 376         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 377 fi
 378
 379 # OpenSSL and Lua frequently need dlopen
 380 AC_CHECK_LIB(dl, dlopen)
 381
 382 # ===================================================================
 383 # Checks for libraries.
 384 # ===================================================================
 385
 386 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 387 if test "$cf_result" = no; then
 388         AC_CHECK_LIB(socket, socket)
 389 fi
 390
 391 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 392 if test "$cf_result" = no; then
 393         AC_CHECK_LIB(socket, setsockopt)
 394 fi
 395
 396 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 397 if test "$cf_result" = no; then
 398         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 399         if test "$cf_result" = no; then
 400                 AC_CHECK_LIB(nsl, gethostbyname)
 401         else
 402                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 403         fi
 404 fi
 405
 406 # ===================================================================
 407 # Checks for packaging specific options.
 408 # ===================================================================
 409
 410 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 411             [ if test "$withval" != no && test "$withval" != yes; then
 412                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 413               fi ])
 414
 415 # ===================================================================
 416 # Checks for a libraries, optional even if installed.
 417 # ===================================================================
 418
 419 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 420 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 421 [
 422         AC_MSG_CHECKING([for $2 support])
 423
 424         if test "[$]$1" != no; then
 425                 AC_MSG_RESULT(yes)
 426                 EL_SAVE_FLAGS
 427                 if test -n "$withval" && test -d "$withval"; then
 428                         # Be a little more careful when setting
 429                         # include and lib directories. This way
 430                         # $withval will work when includes are
 431                         # there but the library is in the common
 432                         # /usr/lib ... Does the right thing when
 433                         # looking for gc on Debian.
 434                         if test -d "$withval/include"; then
 435                                 CFLAGS="$CFLAGS -I$withval/include"
 436                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 437                         else
 438                                 CFLAGS="$CFLAGS -I$withval"
 439                                 CPPFLAGS="$CPPFLAGS -I$withval"
 440                         fi
 441                         if test -d "$withval/lib"; then
 442                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 443                         fi
 444                 fi
 445
 446                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 447                 if test "[$]$1" = yes; then
 448                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 449                 fi
 450
 451                 if test "[$]$1" = yes; then
 452                         EL_CONFIG([$1], [$2])
 453                         LIBS="$LIBS -l$4"
 454                 else
 455                         if test -n "[$]WITHVAL_$1" &&
 456                            test "[$]WITHVAL_$1" != xno; then
 457                                 AC_MSG_ERROR([$2 not found])
 458                         fi
 459                         EL_RESTORE_FLAGS
 460                 fi
 461         else
 462                 AC_MSG_RESULT(disabled)
 463         fi
 464 ])
 465
 466 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 467 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 468 [
 469         $1=yes
 470         WITHVAL_$1=
 471
 472         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 473         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 474
 475         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 476
 477         EL_LOG_CONFIG([$1], [$2], [])
 478 ])
 479
 480 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 481         [  --without-gpm           disable gpm (mouse) support])
 482
 483 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 484         [  --without-zlib          disable zlib support])
 485
 486 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 487         [  --without-bzlib         disable bzlib support])
 488
 489 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 490         [  --without-idn           disable international domain names support])
 491
 492 if test "x{with_gc}" != xno; then
 493         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 494                 [  --with-gc               enable Boehm's garbage collector])
 495 fi
 496
 497 EL_ARG_ENABLE(CONFIG_LZMA, lzma, [lzma],
 498               [  --enable-lzma           enable lzma encoding support])
 499
 500 # ===================================================================
 501 # Check for GSSAPI, optional even if installed.
 502 # ===================================================================
 503
 504 enable_gssapi="no";
 505
 506 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 507             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 508
 509 AC_MSG_CHECKING([for GSSAPI])
 510
 511 if test "$enable_gssapi" = "yes"; then
 512         AC_MSG_RESULT(yes)
 513         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 514         GSSAPI_LIBS=`krb5-config --libs gssapi`
 515         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 516         LIBS="$GSSAPI_LIBS $LIBS"
 517         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 518 else
 519         AC_MSG_RESULT(no)
 520 fi
 521
 522 AC_SUBST(CONFIG_GSSAPI)
 523
 524 # ===================================================================
 525 # Bookmark and XBEL support
 526 # ===================================================================
 527
 528 EL_SAVE_FLAGS
 529
 530 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 531               [  --disable-bookmarks     disable bookmark support])
 532
 533 # Check whether --enable-xbel or --disable-xbel was given.
 534 if test "x${enable_xbel}" != xno; then
 535         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 536
 537         if test "$HAVE_LIBEXPAT" = yes; then
 538                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 539                 if test "$HAVE_LIBEXPAT" = yes; then
 540                         LIBS="$LIBS -lexpat"
 541                 fi
 542         fi
 543 fi
 544
 545
 546 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 547               [XBEL bookmarks],
 548               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 549
 550 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 551         EL_RESTORE_FLAGS
 552 fi
 553
 554 # ===================================================================
 555 # Checks for BSD sysmouse
 556 # ===================================================================
 557
 558 HAVE_SYSMOUSE_HEADER="no"
 559
 560 # Either of these header files provides the (same) sysmouse interface
 561 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 562
 563 # ===================================================================
 564 # Checks for OS/2
 565 # ===================================================================
 566
 567 if test "$CONFIG_OS_OS2" = yes; then
 568         EL_CONFIG_OS_OS2
 569 fi
 570
 571 # ===================================================================
 572 # Checks for Win32
 573 # ===================================================================
 574
 575 if test "$CONFIG_OS_WIN32" = yes; then
 576         EL_CONFIG_OS_WIN32
 577 fi
 578
 579 # ===================================================================
 580 # Check for SEE (Simple Ecmascript Engine)
 581 # ===================================================================
 582 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 583             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 584
 585 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 586 # SEE_FLAGS but I really don't want to require people to have Guile in order
 587 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 588 # for Guile in $PATH etc. --pasky
 589
 590 CONFIG_ECMASCRIPT_SEE=no
 591
 592 if test "$enable_see" = "yes"; then
 593         if test -d "$withval"; then
 594                 SEE_PATH="$withval:$PATH"
 595         else
 596                 SEE_PATH="$PATH"
 597         fi
 598
 599         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 600         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 601         if test "$SEE_CONFIG" != no; then
 602                 EL_SAVE_FLAGS
 603                 SEE_LIBS="`$SEE_CONFIG --libs`"
 604                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 605                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 606                 LIBS="$SEE_LIBS $LIBS_X"
 607                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 608                         #error SEE too old
 609                         #endif
 610                 ]])],[cf_result=yes],[cf_result=no])
 611                 EL_RESTORE_FLAGS
 612                 if test "$cf_result" = yes; then
 613                         LIBS="$SEE_LIBS $LIBS"
 614                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 615                         AC_SUBST(SEE_CFLAGS)
 616                 fi
 617                 AC_MSG_RESULT($cf_result)
 618         else
 619                 if test -n "$withval" && test "x$withval" != xno; then
 620                         AC_MSG_ERROR([SEE not found])
 621                 else
 622                         AC_MSG_WARN([SEE support disabled])
 623                 fi
 624         fi
 625 fi
 626
 627 # ===================================================================
 628 # Check for SpiderMonkey, optional even if installed.
 629 # ===================================================================
 630
 631 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 632             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 633 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 634
 635 EL_SAVE_FLAGS
 636 cf_result=no
 637
 638 if test -z "$disable_spidermonkey"; then
 639         if test ! -d "$withval"; then
 640                 withval="";
 641         fi
 642         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 643                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 644                         for spidermonkeylib in js smjs mozjs; do
 645                                 if test "$cf_result" = no &&
 646                                    test -f "$spidermonkeydir$spidermonkeyinclude/jsapi.h"; then
 647                                         SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 648                                         SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 649
 650                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 651                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 652                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 653
 654                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 655                                                      #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 656                                 fi
 657                         done
 658                 done
 659         done
 660 fi
 661
 662 AC_MSG_RESULT($cf_result)
 663 CONFIG_SPIDERMONKEY="$cf_result"
 664 EL_RESTORE_FLAGS
 665
 666 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 667    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 668         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 669 else
 670         CONFIG_ECMASCRIPT_SMJS=no
 671 fi
 672
 673 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 674 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 675 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 676
 677
 678 # ===================================================================
 679 # Optional Spidermonkey-based ECMAScript browser scripting
 680 # ===================================================================
 681
 682 AC_ARG_ENABLE(sm-scripting,
 683               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 684               [if test "$enableval" != no; then enableval="yes"; fi
 685                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 686
 687 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 688    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 689         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 690 else
 691         CONFIG_SCRIPTING_SPIDERMONKEY=no
 692 fi
 693
 694 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 695    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 696         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 697         AC_SUBST(SPIDERMONKEY_LIBS)
 698         AC_SUBST(SPIDERMONKEY_CFLAGS)
 699         AC_SUBST(CONFIG_SPIDERMONKEY)
 700 fi
 701
 702 # ===================================================================
 703 # Check for Guile, optional even if installed.
 704 # ===================================================================
 705
 706 enable_guile="no";
 707
 708 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 709             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 710
 711 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 712 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 713 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 714 # for Guile in $PATH etc. --pasky
 715
 716 AC_MSG_CHECKING([for Guile])
 717
 718 if test "$enable_guile" = "yes"; then
 719         AC_MSG_RESULT(yes);
 720         ## Based on the GUILE_FLAGS macro.
 721
 722         if test -d "$withval"; then
 723                 GUILE_PATH="$withval:$PATH"
 724         else
 725                 GUILE_PATH="$PATH"
 726         fi
 727
 728         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 729
 730         ## First, let's just see if we can find Guile at all.
 731         if test "$GUILE_CONFIG" != no; then
 732                 cf_result="yes";
 733
 734                 GUILE_LIBS="`guile-config link`"
 735                 GUILE_CFLAGS="`guile-config compile`"
 736                 LIBS="$GUILE_LIBS $LIBS"
 737                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 738                 AC_SUBST(GUILE_CFLAGS)
 739                 cat <<EOF
 740 ***********************************************************************
 741 The Guile support is incomplete and not so well integrated to ELinks
 742 yet. That means, e.g., that you have no Guile console and there might
 743 not be all the necessary hooks. Also, the Guile interface is not too
 744 well tested (success stories heartily welcomed!).  See
 745 src/scripting/guile/README for further details and hints.
 746 ***********************************************************************
 747 EOF
 748         else
 749                 if test -n "$withval" && test "x$withval" != xno; then
 750                         AC_MSG_ERROR([Guile not found])
 751                 else
 752                         AC_MSG_WARN([Guile support disabled])
 753                 fi
 754         fi
 755 else
 756         AC_MSG_RESULT(no);
 757 fi
 758
 759 # ===================================================================
 760 # Check for Perl
 761 # ===================================================================
 762 enable_perl="no";
 763
 764 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 765             [
 766 if test "$withval" = yes; then
 767         # FIXME: If withval is a valid directory append it to PATH
 768         # so that you can specify one of several perl installations.
 769         withval="";
 770         enable_perl=yes;
 771 fi
 772             ])
 773
 774 AC_MSG_CHECKING([for Perl])
 775
 776 cf_result=no
 777
 778 EL_SAVE_FLAGS
 779
 780 if test "$enable_perl" = "yes"; then
 781         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 782         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 783         LIBS="$PERL_LIBS $LIBS"
 784         CFLAGS="$PERL_CFLAGS $CFLAGS"
 785         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 786         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 787 #include <EXTERN.h>
 788 #include <perl.h>
 789 #include <perlapi.h>
 790 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 791 fi
 792
 793 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 794
 795 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 796 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 797 #include <EXTERN.h>
 798 #include <perl.h>
 799 extern PerlInterpreter *my_perl;
 800 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 801 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 802                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 803 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 804
 805 if test "$cf_result" != "yes"; then
 806         EL_RESTORE_FLAGS
 807 else
 808         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 809
 810         CFLAGS="$CFLAGS_X"
 811         CPPFLAGS="$CPPFLAGS_X"
 812         AC_SUBST(PERL_LIBS)
 813         AC_SUBST(PERL_CFLAGS)
 814 fi
 815
 816 # ===================================================================
 817 # Check for Python
 818 # ===================================================================
 819 enable_python="no";
 820
 821 AC_ARG_WITH(python, [  --with-python=[DIR]     enable Python support],
 822             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 823
 824 EL_SAVE_FLAGS
 825 cf_result=no
 826
 827 AC_MSG_CHECKING([for Python])
 828
 829 if test "$enable_python" = "yes"; then
 830         AC_MSG_RESULT(yes);
 831
 832         if test -d "$withval"; then
 833                 PYTHON_PATH="$withval:$PATH"
 834         else
 835                 PYTHON_PATH="$PATH"
 836         fi
 837
 838         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 839
 840         if test "$PYTHON" != no; then
 841                 cf_result="yes";
 842
 843                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 844                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 845                 LIBS="$PYTHON_LIBS $LIBS"
 846                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 847                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 848
 849                 if test "$cf_result" != "yes"; then
 850                         EL_RESTORE_FLAGS
 851                 else
 852                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 853                         AC_SUBST(PYTHON_LIBS)
 854                         AC_SUBST(PYTHON_CFLAGS)
 855                         CPPFLAGS="$CPPFLAGS_X"
 856                         cat <<EOF
 857 ***********************************************************************
 858 The Python support is incomplete and not so well integrated to ELinks
 859 yet. That means, e.g., that you have no Python console and there might
 860 not be all the necessary hooks. Also, the Python interface is not too
 861 well tested (success stories heartily welcomed!).
 862 ***********************************************************************
 863 EOF
 864                 fi
 865         else
 866                 if test -n "$withval" && test "x$withval" != xno; then
 867                         AC_MSG_ERROR([Python not found])
 868                 else
 869                         AC_MSG_WARN([Python support disabled])
 870                 fi
 871         fi
 872 else
 873         AC_MSG_RESULT(no);
 874 fi
 875
 876
 877 # ===================================================================
 878 # Check for Lua, optional even if installed.
 879 # ===================================================================
 880
 881 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 882 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 883
 884 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 885             [if test "$withval" = no; then disable_lua=yes; fi])
 886 AC_MSG_CHECKING([for Lua])
 887
 888 EL_SAVE_FLAGS
 889 cf_result=no
 890
 891 if test -z "$disable_lua"; then
 892         if test ! -d "$withval"; then
 893                 withval="";
 894         fi
 895         for luadir in "$withval" "" /usr /usr/local; do
 896                 for suffix in "" 50; do
 897                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 898                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 899                                 LUA_LIBS="-L$luadir/lib -llua$suffix -llualib$suffix -lm"
 900                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 901
 902                                 LIBS="$LUA_LIBS $LIBS_X"
 903                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 904                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 905
 906                                 # Check that it is a compatible Lua version
 907                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lua.h>
 908                                                 #include <lualib.h>]], [[       lua_State *L = lua_open();
 909                                                 luaopen_base(L);
 910                                                 luaopen_table(L);
 911                                                 luaopen_io(L);
 912                                                 luaopen_string(L);
 913                                                 luaopen_math(L);
 914                                                 lua_pushboolean(L, 1);
 915                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 916                         fi
 917                 done
 918         done
 919 fi
 920
 921 AC_MSG_RESULT($cf_result)
 922
 923 if test "$cf_result" != yes; then
 924         EL_RESTORE_FLAGS
 925 else
 926         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 927         AC_CHECK_HEADERS(lauxlib.h)
 928
 929         CFLAGS="$CFLAGS_X"
 930         CPPFLAGS="$CPPFLAGS_X"
 931         AC_SUBST(LUA_LIBS)
 932         AC_SUBST(LUA_CFLAGS)
 933 fi
 934
 935
 936 # ===================================================================
 937 # Check for Ruby, optional even if installed.
 938 # ===================================================================
 939
 940 EL_CONFIG_SCRIPTING_RUBY
 941
 942 # ===================================================================
 943 # Setup global scripting
 944 # ===================================================================
 945
 946 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 947 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 948 AC_SUBST(CONFIG_SCRIPTING_LUA)
 949 AC_SUBST(CONFIG_SCRIPTING_PERL)
 950 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 951 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 952 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 953 AC_SUBST(CONFIG_SCRIPTING)
 954
 955
 956 # ===================================================================
 957 # Check for SSL support.
 958 # ===================================================================
 959
 960 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 961 # is enabled, we won't try to use OpenSSL anymore.
 962
 963 # For wiping SSL hooks..
 964 #ifdef CONFIG_SSL
 965
 966 disable_openssl=""
 967 disable_gnutls=""
 968 enable_gnutls=""
 969
 970 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 971             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 972 AC_ARG_WITH(gnutls, [  --with-gnutls[=DIR]     enable GNUTLS SSL support],
 973             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 974 gnutls_withval="$withval"
 975
 976 if test "$enable_gnutls" = yes; then
 977         disable_openssl=yes;
 978 fi
 979
 980 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 981             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 982 AC_ARG_WITH(openssl, [  --with-openssl[=DIR]    enable OpenSSL support (default)])
 983 openssl_withval="$withval"
 984
 985 # ---- OpenSSL
 986
 987 AC_MSG_CHECKING([for OpenSSL])
 988
 989 EL_SAVE_FLAGS
 990 cf_result="no"
 991
 992 if test "$disable_openssl" = yes; then
 993         cf_result="not used"
 994 else
 995         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
 996                          /usr/lib/openssl /usr/local/ssl \
 997                          /usr/local/www /usr/lib/ssl /usr/local \
 998                          /usr/pkg /opt /opt/openssl; do
 999                 if test "$cf_result" = no; then
1000                         if test -d "$ssldir"; then
1001                                 OPENSSL_CFLAGS="-I$ssldir/include"
1002                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1003                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1004                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1005 #                               # FIXME: This created serious portability problems. --pasky
1006 #                               if test "$CC" == "gcc"; then
1007 #                                       # I'm not sure about compatibility here. --pasky
1008 #                                       LIBS="$LIBS -R$ssldir/lib"
1009 #                               fi
1010                         else
1011                                 LIBS="-lssl -lcrypto $LIBS_X"
1012                         fi
1013                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1014                         if test "$cf_result" != yes; then
1015                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1016                         fi
1017                 fi
1018         done
1019
1020         if test "$cf_result" != yes; then
1021                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
1022                         AC_MSG_ERROR([OpenSSL not found])
1023                 fi
1024                 EL_RESTORE_FLAGS
1025         else
1026                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1027
1028                 CFLAGS="$CFLAGS_X"
1029                 AC_SUBST(OPENSSL_CFLAGS)
1030         fi
1031 fi
1032
1033 AC_MSG_RESULT($cf_result)
1034
1035 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1036 # ---- GNU TLS
1037 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
1038 dnl it looks ugly then.
1039
1040 if test "$cf_result" = yes; then
1041         cf_result="not used"
1042
1043 else
1044         EL_SAVE_FLAGS
1045         cf_result="no"
1046
1047         if test -z "$disable_gnutls"; then
1048                 # Sure, we maybe _could_ use their macro, but how to ensure
1049                 # that the ./configure script won't fail if the macro won't be
1050                 # found..? :( --pasky
1051
1052                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
1053
1054                 if test -d "$gnutls_withval"; then
1055                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
1056                 fi
1057
1058                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
1059
1060                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
1061                         cf_result=no
1062                 else
1063                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
1064                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
1065
1066                         LIBS="$GNUTLS_LIBS $LIBS_X"
1067                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
1068                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
1069
1070                         # Verify if it's really usable.  gnutls_session was
1071                         # renamed to gnutls_session_t before GNU TLS 1.2.0
1072                         # (on 2004-06-13); ELinks now requires this.
1073                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[gnutls_session_t dummy;
1074                                      gnutls_check_version(NULL)]])],[cf_result=yes],[cf_result=no])
1075                 fi
1076
1077                 if test "$cf_result" = yes; then
1078                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1079
1080                         CFLAGS="$CFLAGS_X"
1081                         AC_SUBST(GNUTLS_CFLAGS)
1082
1083                         # Verify if the MD5 compatibility layer is usable.
1084                         CONFIG_GNUTLS_OPENSSL_COMPAT=yes
1085                         EL_CHECK_OPTIONAL_LIBRARY(CONFIG_GNUTLS_OPENSSL_COMPAT,
1086                                                   [GNU TLS OpenSSL compatibility],
1087                                                   gnutls/openssl.h, gnutls-openssl,
1088                                                   MD5_Init)
1089                 else
1090                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
1091                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
1092                         fi
1093                         EL_RESTORE_FLAGS
1094                 fi
1095         fi
1096 fi
1097
1098 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
1099 AC_MSG_RESULT($cf_result)
1100
1101 # Final SSL setup
1102
1103 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
1104 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1105 AC_SUBST(CONFIG_OPENSSL)
1106 AC_SUBST(CONFIG_GNUTLS)
1107
1108 #endif
1109
1110 AC_MSG_CHECKING([whether to be or not to be])
1111 AC_MSG_RESULT([needs to be determined experimentally])
1112
1113 # ===================================================================
1114 # Check for IPv6 support and related functions.
1115 # ===================================================================
1116
1117 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1118 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1119 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1120
1121 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1122 if test "$HAVE_GETADDRINFO" != yes; then
1123         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1124         if test "$HAVE_GETADDRINFO" = yes; then
1125                 LIBS="$LIBS -linet6"
1126         fi
1127 fi
1128
1129
1130 # ===================================================================
1131 # Checking for X11 (window title restoring).
1132 # ===================================================================
1133
1134 AC_PATH_X
1135 if test x"$no_x" != xyes; then
1136         EL_SAVE_FLAGS
1137         if test -n "$x_includes"; then
1138                 X_CFLAGS="-I$x_includes"
1139                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1140                 CFLAGS="$CFLAGS $X_CFLAGS"
1141         fi
1142         if test -n "$x_libraries"; then
1143                 LDFLAGS="$LDFLAGS -L$x_libraries"
1144         fi
1145         LIBS="-lX11 $LIBS"
1146         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1147         EL_RESTORE_FLAGS
1148         if test "$cf_result" = yes; then
1149                 if test -n "$x_libraries"; then
1150                         LDFLAGS="$LDFLAGS -L$x_libraries"
1151                 fi
1152                 LIBS="-lX11 $LIBS"
1153                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1154                 AC_SUBST(X_CFLAGS)
1155         fi
1156 fi
1157
1158
1159 # ===================================================================
1160 # Backtraces displaying support.
1161 # ===================================================================
1162
1163 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1164 # possible checks for other system-specific means go here
1165
1166
1167 # ===================================================================
1168 # Gettext grey zone. Beware.
1169 # ===================================================================
1170
1171 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1172
1173 AM_GNU_GETTEXT
1174
1175 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1176 dnl # f33r d4 l33t... I hope it's portable. :)
1177 dnl cf_result=$((48#z - 48#a + 1));
1178 dnl AC_MSG_RESULT($cf_result)
1179
1180
1181 # ===================================================================
1182 # Compile-time features control
1183 # ===================================================================
1184
1185 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1186               [  --disable-cookies       disable cookie support])
1187
1188 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1189               [  --disable-formhist      disable form history support])
1190
1191 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1192               [  --disable-globhist      disable global history support])
1193
1194
1195 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1196               [  --disable-mailcap       disable mailcap support])
1197
1198 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1199               [  --disable-mimetypes     disable mimetypes files support])
1200
1201
1202 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1203               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1204               [IPv6],
1205               [  --disable-ipv6          disable IPv6 support])
1206
1207 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1208               [  --enable-bittorrent     enable BitTorrent protocol support])
1209
1210 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1211               [  --disable-data          disable data protocol support])
1212
1213 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1214               [  --disable-uri-rewrite   disable URI rewrite support])
1215
1216 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1217               [  --enable-cgi            enable local CGI support])
1218
1219 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1220               [  --enable-finger         enable finger protocol support])
1221
1222 # ===================================================================
1223 # FSP protocol
1224 # ===================================================================
1225 EL_SAVE_FLAGS
1226
1227 if test "x${enable_fsp}" != xno; then
1228         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1229
1230         if test "$HAVE_FSPLIB" = yes; then
1231                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1232                 if test "$HAVE_FSPLIB" = yes; then
1233                         LIBS="$LIBS -lfsplib"
1234                 else
1235                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1236                         if test "$HAVE_FSPLIB" = yes; then
1237                                 LIBS="$LIBS -lfsp"
1238                         fi
1239                 fi
1240         fi
1241 fi
1242
1243 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1244               [  --enable-fsp            enable FSP protocol support])
1245
1246 if test "x$CONFIG_FSP" = xno; then
1247         EL_RESTORE_FLAGS
1248 fi
1249
1250 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1251               [  --disable-ftp           disable ftp protocol support])
1252
1253 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1254               [  --enable-gopher         enable gopher protocol support])
1255
1256 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1257               [  --enable-nntp           enable nntp protocol support])
1258
1259 # ===================================================================
1260 # SMB protocol support.
1261 # ===================================================================
1262 EL_SAVE_FLAGS
1263
1264 if test "x${enable_smb}" != xno; then
1265         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1266
1267         if test "$HAVE_SMBCLIENT" = yes; then
1268                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1269                 if test "$HAVE_SMBCLIENT" = yes; then
1270                         LIBS="$LIBS -lsmbclient"
1271                 fi
1272         fi
1273 fi
1274
1275 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1276               [  --enable-smb            enable Samba protocol support])
1277
1278 if test "x$CONFIG_SMB" = xno; then
1279         EL_RESTORE_FLAGS
1280 fi
1281
1282
1283 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1284               [  --disable-mouse         disable mouse support])
1285
1286 # GPM mouse is Linux specific, so ...
1287 CONFIG_SYSMOUSE=yes
1288 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1289               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1290               [BSD sysmouse],
1291               [  --disable-sysmouse      disable BSD sysmouse support])
1292
1293 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1294               [  --enable-88-colors      enable 88 color support])
1295
1296 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1297               [  --enable-256-colors     enable 256 color support])
1298
1299 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1300               [  --enable-true-color     enable true color support])
1301
1302 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1303               [  --enable-exmode         enable exmode (CLI) interface])
1304
1305 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1306               [  --disable-leds          disable LEDs support])
1307
1308 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1309               [  --disable-marks         disable document marks support])
1310
1311
1312 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1313               [  --disable-css           disable Cascading Style Sheet support])
1314
1315 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1316               [  --enable-html-highlight HTML highlighting using DOM engine])
1317
1318 # Everything in the tree already uses CONFIG_DOM
1319 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1320 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1321
1322 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1323               [  --disable-backtrace     disable backtrace support])
1324
1325 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1326               [  --enable-no-root        enable prevention of usage by root])
1327
1328
1329 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1330               [  --enable-debug          enable leak debug and internal error checking])
1331
1332 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1333               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1334
1335 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1336               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1337
1338 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1339               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1340
1341 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1342               [  --disable-utf-8         disable UTF-8 support])
1343
1344
1345 AC_ARG_ENABLE(weehoofooboomookerchoo,
1346               [
1347     Also check out the features.conf file for more information about features!
1348               ],
1349               [AC_MSG_ERROR(Are you strange, or what?)])
1350
1351
1352 # == EMX hack
1353
1354 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1355 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1356
1357
1358 # ===================================================================
1359 # Export directory paths
1360 # ===================================================================
1361
1362 # Set up the ``entry points'' if they were not supplied by builder
1363 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1364 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1365
1366 # Create CONFDIR #define for config.h
1367
1368 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1369 # it's autoconf fault to force us to do such hacks ;p.
1370 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1371   # sysconfdir is set to its default value... fine, let's append /elinks/
1372   # XXX: We can't modify listing of the default in ./configure --help :-(
1373   sysconfdir_n=`eval echo "$sysconfdir"`
1374   sysconfdir=$sysconfdir_n
1375   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1376         sysconfdir="$sysconfdir/elinks"
1377 fi
1378
1379 CONFDIR=$sysconfdir
1380 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1381 AC_SUBST(CONFDIR)
1382
1383 # Create LOCALEDIR #define for config.h
1384 LOCALEDIR=`eval echo "$datadir/locale"`
1385 while echo "$LOCALEDIR" | grep "\\$"
1386 do
1387         LOCALEDIR=`eval echo "$LOCALEDIR"`
1388 done > /dev/null 2> /dev/null
1389 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1390 AC_SUBST(LOCALEDIR)
1391
1392 # Create LIBDIR #define for config.h
1393 LIBDIR=`eval echo "$libdir"`
1394 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1395 AC_SUBST(LIBDIR)
1396
1397 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1398 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1399
1400 # ===================================================================
1401 # A little fine tuning of gcc specific options (continued)
1402 # ===================================================================
1403
1404 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1405   if test "$CONFIG_DEBUG" = "yes"; then
1406     # We want to see all warnings and live with none (in debug mode).
1407     CFLAGS="$CFLAGS -Werror"
1408   fi
1409
1410   case "`$CC -dumpversion`" in
1411     3.0|3.1|3.2)
1412       # These should be ok using -Werror
1413       ;;
1414     3.*)
1415       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1416       # "dereferencing type-punned pointer will break strict-aliasing rules"
1417       # warnings. Disable them by not doing any strict-aliasing. The
1418       # alternative is just too ugly. Thanks gcc guys!! ;)
1419       CFLAGS="$CFLAGS -fno-strict-aliasing"
1420       ;;
1421     4.*)
1422       # Do not show warnings related to (char * | unsigned char *) type
1423       # difference.
1424       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1425       ;;
1426     *)
1427       # These should be ok using -Werror
1428       ;;
1429   esac
1430
1431   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1432   # warning: the address of `builtin_modules' will always evaluate as `true'
1433   # This hits the object_lock and foreach_module macros in particular.
1434   # It would be okay to put something in the macros to avoid the warning,
1435   # but currently this seems to require defining parallel macros that skip
1436   # the NULL check, and that's too ugly.  So we instead disable the warning.
1437   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1438   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1439   for warning_flag in -Wno-address -Wno-always-true; do
1440     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1441     EL_SAVE_FLAGS
1442     CFLAGS="$CFLAGS $warning_flag"
1443     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1444       [AC_MSG_RESULT([yes])
1445        break],
1446       [AC_MSG_RESULT([no])])
1447     EL_RESTORE_FLAGS
1448   done
1449 fi
1450
1451 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1452 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1453 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1454 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1455
1456 # ===================================================================
1457 # Colored make output
1458 # ===================================================================
1459
1460 if test $(`which tput` colors) -ge 4; then
1461         MAKE_COLOR=1
1462         AC_SUBST(MAKE_COLOR)
1463 fi
1464
1465 # ===================================================================
1466 # Generated files
1467 # ===================================================================
1468
1469 AC_CONFIG_FILES([ \
1470  Makefile.config \
1471  contrib/elinks.spec \
1472  contrib/lua/hooks.lua \
1473  contrib/conv/w3m2links.awk \
1474  doc/Doxyfile \
1475  doc/man/man1/elinks.1 \
1476  src/intl/gettext/ref-add.sed \
1477  src/intl/gettext/ref-del.sed
1478 ])
1479 AC_OUTPUT
1480
1481 abs_srcdir="$(cd "$srcdir" && pwd)"
1482 # builddir is always absolute!
1483 if test "$abs_srcdir" != "$builddir"; then
1484         # Bootstrap the Makefile creation
1485         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1486         "$MAKE" "SRC=$abs_srcdir" init
1487
1488         # Make cg-status ignore this build directory
1489         echo "*" > "$builddir/.gitignore"
1490 fi
1491
1492 # ===================================================================
1493 # Configuration summary
1494 # ===================================================================
1495
1496 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1497 cat features.log