usr.sbin/config/lang.l

   1 %{
   2 /*-
   3  * Copyright (c) 1980, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. All advertising materials mentioning features or use of this software
  15  *    must display the following acknowledgement:
  16  *      This product includes software developed by the University of
  17  *      California, Berkeley and its contributors.
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      @(#)lang.l      8.1 (Berkeley) 6/6/93
  35  * $FreeBSD: src/usr.sbin/config/lang.l,v 1.27 1999/11/09 07:20:22 peter Exp $
  36  * $DragonFly: src/usr.sbin/config/lang.l,v 1.14 2008/05/01 09:24:42 swildner Exp $
  37  */
  38
  39 #include <ctype.h>
  40 #include <string.h>
  41 #include "y.tab.h"
  42 #include "config.h"
  43
  44 #define YY_NO_UNPUT
  45
  46 /*
  47  * Key word table
  48  */
  49
  50 struct kt {
  51         const char *kt_name;
  52         int kt_val;
  53 } key_words[] = {
  54         { "at",         AT },
  55         { "bus",        BUS },
  56         { "config",     CONFIG },
  57         { "cpu",        CPU },
  58         { "device",     DEVICE },
  59         { "disable",    DISABLE },
  60         { "drive",      DRIVE },
  61         { "drq",        DRQ },
  62         { "flags",      FLAGS },
  63         { "ident",      IDENT },
  64         { "iomem",      IOMEM },
  65         { "iosiz",      IOSIZ },
  66         { "irq",        IRQ },
  67         { "machine",    CONFIG_MACHINE },
  68         { "machine_arch", CONFIG_MACHINE_ARCH },
  69         { "makeoptions", MAKEOPTIONS },
  70         { "maxusers",   MAXUSERS },
  71         { "nexus",      NEXUS },
  72         { "option",     OPTIONS },
  73         { "options",    OPTIONS },
  74         { "platform",   CONFIG_PLATFORM },
  75         { "port",       PORT },
  76         { "pseudo-device",PSEUDO_DEVICE },
  77         { "target",     TARGET },
  78         { "unit",       UNIT },
  79         { 0, 0 },
  80 };
  81
  82
  83 int kw_lookup(char *);
  84 int octal(char *);
  85 int hex(char *);
  86
  87 %}
  88 WORD    [A-Za-z_][-A-Za-z_]*
  89 ID      [A-Za-z_][-A-Za-z_0-9]*
  90 %START NONUM TOEOL
  91 %%
  92 <NONUM>{WORD}   {
  93                         int i;
  94
  95                         BEGIN 0;
  96                         if ((i = kw_lookup(yytext)) == -1)
  97                         {
  98                                 yylval.str = strdup(yytext);
  99                                 return(ID);
 100                         }
 101                         return(i);
 102                 }
 103 <INITIAL>{WORD}/[0-9]* {
 104                         int i;
 105
 106                         if ((i = kw_lookup(yytext)) == -1)
 107                                 REJECT;
 108                         if (i == DEVICE || i == PSEUDO_DEVICE || i == AT)
 109                                 BEGIN NONUM;
 110                         return(i);
 111                 }
 112 <INITIAL>{ID}   {
 113                         BEGIN 0;
 114                         yylval.str = strdup(yytext);
 115                         return(ID);
 116                 }
 117 \\\"[^"]+\\\"   {
 118                         BEGIN 0;
 119                         yytext[yyleng-2] = '"';
 120                         yytext[yyleng-1] = '\0';
 121                         yylval.str = strdup(yytext + 1);
 122                         return(ID);
 123                 }
 124 \"[^"]+\"       {
 125                         BEGIN 0;
 126                         yytext[yyleng-1] = '\0';
 127                         yylval.str = strdup(yytext + 1);
 128                         return(ID);
 129                 }
 130 <TOEOL>[^# \t\n]*       {
 131                         BEGIN 0;
 132                         yylval.str = strdup(yytext);
 133                         return(ID);
 134                 }
 135 0[0-7]*         {
 136                         yylval.val = octal(yytext);
 137                         return(NUMBER);
 138                 }
 139 0x[0-9a-fA-F]+  {
 140                         yylval.val = hex(yytext);
 141                         return(NUMBER);
 142                 }
 143 -?[1-9][0-9]*   {
 144                         yylval.val = atoi(yytext);
 145                         return(NUMBER);
 146                 }
 147 [0-9]"."[0-9]*  {
 148                         yylval.val = (int)(60 * atof(yytext) + 0.5);
 149                         return(FPNUMBER);
 150                 }
 151 "?"             {
 152                         yylval.val = -1;
 153                         return(NUMBER);
 154                 }
 155 \n/[ \t]        {
 156                         yyline++;
 157                 }
 158 \n              {
 159                         yyline++;
 160                         return(SEMICOLON);
 161                 }
 162 #.*             {       /* Ignored (comment) */;        }
 163 [ \t\f]*        {       /* Ignored (white space) */;    }
 164 ";"             {       return(SEMICOLON);              }
 165 ","             {       return(COMMA);                  }
 166 "="             {       BEGIN TOEOL; return(EQUALS);    }
 167 "@"             {       return(AT);                     }
 168 .               {       return(yytext[0]);              }
 169
 170 %%
 171 /*
 172  * kw_lookup
 173  *      Look up a string in the keyword table.  Returns a -1 if the
 174  *      string is not a keyword otherwise it returns the keyword number
 175  */
 176
 177 int
 178 kw_lookup(char *word)
 179 {
 180         struct kt *kp;
 181
 182         for (kp = key_words; kp->kt_name != NULL; kp++)
 183                 if (!strcmp(word, kp->kt_name))
 184                         return(kp->kt_val);
 185         return(-1);
 186 }
 187
 188 /*
 189  * Number conversion routines
 190  */
 191
 192 int
 193 octal(char *str)
 194 {
 195         int num;
 196
 197         sscanf(str, "%o", &num);
 198         return(num);
 199 }
 200
 201 int
 202 hex(char *str)
 203 {
 204         int num;
 205
 206         sscanf(str + 2, "%x", &num);
 207         return(num);
 208 }