sbin/devd/token.l

   1 %{
   2 /*-
   3  * DEVD (Device action daemon)
   4  *
   5  * Copyright (c) 2002 M. Warner Losh <imp@freebsd.org>.
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  *
  29  * $FreeBSD: head/sbin/devd/token.l 250227 2013-05-03 23:51:32Z jkim $
  30  */
  31
  32 #include <ctype.h>
  33 #include <stdlib.h>
  34 #include <string.h>
  35 #include <syslog.h>
  36 #include "devd.h"
  37 #include "y.tab.h"
  38
  39 int lineno = 1;
  40
  41 static void
  42 update_lineno(const char *cp)
  43 {
  44         while (*cp)
  45                 if (*cp++ == '\n')
  46                         lineno++;
  47 }
  48
  49 %}
  50
  51 %option nounput
  52 %option noinput
  53
  54 %%
  55
  56 [ \t]+                  ;
  57 \n                      lineno++;
  58 ;                       { return SEMICOLON; }
  59 #.*$                    ;
  60 \/\/.*$                 ;
  61 \/\*([^*]|(\*+([^*\/])))*\*+\/ { update_lineno(yytext); }
  62 \{                      { return BEGINBLOCK; }
  63 \}                      { return ENDBLOCK; }
  64 [0-9]+                  { yylval.i = atoi(yytext); return NUMBER; }
  65 \"[^"]+\"               {
  66                                 int len = strlen(yytext) - 2;
  67                                 char *walker;
  68                                 int i;
  69                                 update_lineno(yytext);
  70                                 if ((yylval.str = (char *) malloc(len + 1)) == NULL)
  71                                         goto out;
  72                                 walker = yylval.str;
  73                                 for (i = 1; i <= len; i++) {
  74                                         if (yytext[i] == '\\' &&
  75                                             yytext[i + 1] == '\n') {
  76                                                 i += 2;
  77                                                 while(isspace(yytext[i]))
  78                                                         i++;
  79                                         }
  80                                         *walker++ = yytext[i];
  81                                 }
  82                                 *walker++ = '\0';
  83                         out:;
  84                                 return STRING;
  85                         }
  86
  87
  88 options                 { return OPTIONS; }
  89 set                     { return SET; }
  90 directory               { return DIRECTORY; }
  91 pid-file                { return PID_FILE; }
  92 attach                  { return ATTACH; }
  93 detach                  { return DETACH; }
  94 device-name             { return DEVICE_NAME; }
  95 media-type              { return MEDIA_TYPE; }
  96 class                   { return CLASS; }
  97 subdevice               { return SUBDEVICE; }
  98 action                  { return ACTION; }
  99 match                   { return MATCH; }
 100 nomatch                 { return NOMATCH; }
 101 notify                  { return NOTIFY; }
 102 [A-Za-z][A-Za-z0-9_-]*  {
 103                                 yylval.str = strdup(yytext);
 104                                 return ID;
 105                         }
 106 %%
 107
 108 void
 109 yyerror(const char *s)
 110 {
 111         syslog(LOG_ERR, "line %d: %s%s %s.\n", lineno, yytext, yytext?":":"", s);
 112 }