sys/platform/pc32/i386/bioscall.s

   1 /*-
   2  * Copyright (c) 1997 Jonathan Lemon
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD: src/sys/i386/i386/bioscall.s,v 1.6.2.1 2000/07/07 00:38:46 obrien Exp $
  27  * $DragonFly: src/sys/platform/pc32/i386/bioscall.s,v 1.4 2003/11/07 17:59:23 dillon Exp $
  28  */
  29
  30 /*
  31  * Functions for calling x86 BIOS functions from the BSD kernel
  32  */
  33
  34 #include <machine/asmacros.h>
  35
  36 #include "assym.s"
  37
  38         .data
  39         ALIGN_DATA
  40 bioscall_frame:         .long   0
  41 bioscall_stack:         .long   0
  42
  43         .text
  44 /*
  45  * bios32(regs, offset, segment)
  46  *      struct bios_regs *regs;
  47  *      u_int offset;
  48  *      u_short segment;
  49  */
  50 ENTRY(bios32)
  51         pushl   %ebp
  52         movl    16(%esp),%ebp
  53         mov     %bp,bioscall_vector+4
  54         movl    12(%esp),%ebp
  55         movl    %ebp,bioscall_vector
  56         movl    8(%esp),%ebp
  57         pushl   %ebx
  58         pushl   %esi
  59         pushl   %edi
  60         movl    0(%ebp),%eax
  61         movl    4(%ebp),%ebx
  62         movl    8(%ebp),%ecx
  63         movl    12(%ebp),%edx
  64         movl    16(%ebp),%esi
  65         movl    20(%ebp),%edi
  66         pushl   %ebp
  67         lcall   *bioscall_vector
  68         popl    %ebp
  69         movl    %eax,0(%ebp)
  70         movl    %ebx,4(%ebp)
  71         movl    %ecx,8(%ebp)
  72         movl    %edx,12(%ebp)
  73         movl    %esi,16(%ebp)
  74         movl    %edi,20(%ebp)
  75         movl    $0,%eax                 /* presume success */
  76         jnc     1f
  77         movl    $1,%eax                 /* nope */
  78 1:
  79         popl    %edi
  80         popl    %esi
  81         popl    %ebx
  82         popl    %ebp
  83         ret
  84
  85
  86 /*
  87  * bios16_call(regs, stack)
  88  *      struct bios_regs *regs;
  89  *      char *stack;
  90  */
  91 ENTRY(bios16_call)
  92         pushl   %ebp
  93         movl    %esp,%ebp
  94         addl    $4,%ebp                 /* frame pointer */
  95         movl    %ebp,bioscall_frame     /* ... save it */
  96         pushl   %ebx
  97         pushl   %esi
  98         pushl   %edi
  99 /*
 100  * the problem with a full 32-bit stack segment is that 16-bit code
 101  * tends to do a pushf, which only pushes %sp, not %esp.  This value
 102  * is then popped off (into %esp) which causes a page fault because
 103  * it is the wrong address.
 104  *
 105  * the reverse problem happens for 16-bit stack addresses; the kernel
 106  * code attempts to get the address of something on the stack, and the
 107  * value returned is the address relative to %ss, not %ds.
 108  *
 109  * we fix this by installing a temporary stack at page 0, so the
 110  * addresses are always valid in both 32 bit and 16 bit modes.
 111  */
 112         movl    %esp,bioscall_stack     /* save current stack location */
 113         movl    8(%ebp),%esp            /* switch to page 0 stack */
 114
 115         movl    4(%ebp),%ebp            /* regs */
 116
 117         movl    0(%ebp),%eax
 118         movl    4(%ebp),%ebx
 119         movl    8(%ebp),%ecx
 120         movl    12(%ebp),%edx
 121         movl    16(%ebp),%esi
 122         movl    20(%ebp),%edi
 123
 124         pushl   $BC32SEL
 125         leal    CNAME(bios16_jmp),%ebp
 126         andl    $PAGE_MASK,%ebp
 127         pushl   %ebp                    /* reload %cs and */
 128         lret                            /* ...continue below */
 129         .globl  CNAME(bios16_jmp)
 130 CNAME(bios16_jmp):
 131         lcallw  *bioscall_vector        /* 16-bit call */
 132
 133         jc      1f
 134         pushl   $0                      /* success */
 135         jmp     2f
 136 1:
 137         pushl   $1                      /* failure */
 138 2:
 139         movl    bioscall_frame,%ebp
 140
 141         movl    4(%ebp),%ebp            /* regs */
 142
 143         movl    %eax,0(%ebp)
 144         movl    %ebx,4(%ebp)
 145         movl    %ecx,8(%ebp)
 146         movl    %edx,12(%ebp)
 147         movl    %esi,16(%ebp)
 148         movl    %edi,20(%ebp)
 149
 150         popl    %eax                    /* recover return value */
 151         movl    bioscall_stack,%esp     /* return to normal stack */
 152
 153         popl    %edi
 154         popl    %esi
 155         popl    %ebx
 156         popl    %ebp
 157
 158         movl    (%esp),%ecx
 159         pushl   %ecx                    /* return address */
 160         movl    $KCSEL,4(%esp)
 161         lret                            /* reload %cs on the way out */