crypto/heimdal-0.6.3/cf/aix.m4

   1 dnl
   2 dnl $Id: aix.m4,v 1.9.6.1 2004/04/01 07:27:32 joda Exp $
   3 dnl
   4
   5 AC_DEFUN([rk_AIX],[
   6
   7 aix=no
   8 case "$host" in
   9 *-*-aix3*)
  10         aix=3
  11         ;;
  12 *-*-aix4*|*-*-aix5*)
  13         aix=4
  14         ;;
  15 esac
  16
  17 AM_CONDITIONAL(AIX, test "$aix" != no)dnl
  18 AM_CONDITIONAL(AIX4, test "$aix" = 4)
  19
  20
  21 AC_ARG_ENABLE(dynamic-afs,
  22         AC_HELP_STRING([--disable-dynamic-afs],
  23                 [do not use loaded AFS library with AIX]))
  24
  25 if test "$aix" != no; then
  26         if test "$enable_dynamic_afs" != no; then
  27                 AC_REQUIRE([rk_DLOPEN])
  28                 if test "$ac_cv_func_dlopen" = no; then
  29                         AC_FIND_FUNC_NO_LIBS(loadquery, ld)
  30                 fi
  31                 if test "$ac_cv_func_dlopen" != no; then
  32                         AIX_EXTRA_KAFS='$(LIB_dlopen)'
  33                 elif test "$ac_cv_func_loadquery" != no; then
  34                         AIX_EXTRA_KAFS='$(LIB_loadquery)'
  35                 else
  36                         AC_MSG_NOTICE([not using dynloaded AFS library])
  37                         AIX_EXTRA_KAFS=
  38                         enable_dynamic_afs=no
  39                 fi
  40         else
  41                 AIX_EXTRA_KAFS=
  42         fi
  43 fi
  44
  45 AM_CONDITIONAL(AIX_DYNAMIC_AFS, test "$enable_dynamic_afs" != no)dnl
  46 AC_SUBST(AIX_EXTRA_KAFS)dnl
  47
  48 AH_BOTTOM([#if _AIX
  49 #define _ALL_SOURCE
  50 /* XXX this is gross, but kills about a gazillion warnings */
  51 struct ether_addr;
  52 struct sockaddr;
  53 struct sockaddr_dl;
  54 struct sockaddr_in;
  55 #endif])
  56
  57 ])