lib/libipsec/policy_token.l

   1 /*      $FreeBSD: src/lib/libipsec/policy_token.l,v 1.2.2.2 2001/07/03 11:01:15 ume Exp $       */
   2 /*      $DragonFly: src/lib/libipsec/policy_token.l,v 1.4 2008/09/30 16:57:05 swildner Exp $    */
   3 /*      $KAME: policy_token.l,v 1.11 2000/12/01 10:08:29 sakane Exp $   */
   4
   5 /*
   6  * Copyright (C) 1995, 1996, 1997, 1998, and 1999 WIDE Project.
   7  * All rights reserved.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. Neither the name of the project nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  */
  33
  34 %{
  35 #include <sys/types.h>
  36 #include <sys/param.h>
  37 #include <sys/socket.h>
  38 #include <net/route.h>
  39 #include <net/pfkeyv2.h>
  40 #include <netkey/keydb.h>
  41 #include <netinet/in.h>
  42 #include <netinet6/ipsec.h>
  43
  44 #include <stdlib.h>
  45 #include <limits.h>
  46 #include <string.h>
  47 #include <unistd.h>
  48 #include <errno.h>
  49
  50 #define YY_NO_INPUT
  51
  52 #ifndef __NetBSD__
  53 #include "y.tab.h"
  54 #else
  55 #include "policy_parse.h"
  56 #endif
  57 #define yylval __libipsecyylval /* XXX */
  58
  59 int yylex (void);
  60 %}
  61
  62 %option noyywrap
  63 %option nounput
  64
  65 /* common section */
  66 nl              \n
  67 ws              [ \t]+
  68 digit           [0-9]
  69 hexdigit        [0-9A-Fa-f]
  70 special         [()+\|\?\*,]
  71 dot             \.
  72 comma           \,
  73 hyphen          \-
  74 colon           \:
  75 slash           \/
  76 bcl             \{
  77 ecl             \}
  78 blcl            \[
  79 elcl            \]
  80 percent         \%
  81 semi            \;
  82 usec            {dot}{digit}{1,6}
  83 comment         \#.*
  84 ccomment        "/*"
  85 bracketstring   \<[^>]*\>
  86 quotedstring    \"[^"]*\"
  87 decstring       {digit}+
  88 hexpair         {hexdigit}{hexdigit}
  89 hexstring       0[xX]{hexdigit}+
  90 octetstring     {octet}({dot}{octet})+
  91 ipaddress       [a-zA-Z0-9:\._][a-zA-Z0-9:\._]*(%[a-zA-Z0-9]+)?
  92
  93 %%
  94
  95 in              { yylval.num = IPSEC_DIR_INBOUND; return(DIR); }
  96 out             { yylval.num = IPSEC_DIR_OUTBOUND; return(DIR); }
  97
  98 discard         { yylval.num = IPSEC_POLICY_DISCARD; return(ACTION); }
  99 none            { yylval.num = IPSEC_POLICY_NONE; return(ACTION); }
 100 ipsec           { yylval.num = IPSEC_POLICY_IPSEC; return(ACTION); }
 101 bypass          { yylval.num = IPSEC_POLICY_BYPASS; return(ACTION); }
 102 entrust         { yylval.num = IPSEC_POLICY_ENTRUST; return(ACTION); }
 103
 104 esp             { yylval.num = IPPROTO_ESP; return(PROTOCOL); }
 105 ah              { yylval.num = IPPROTO_AH; return(PROTOCOL); }
 106 ipcomp          { yylval.num = IPPROTO_IPCOMP; return(PROTOCOL); }
 107 tcp             { yylval.num = IPPROTO_TCP; return(PROTOCOL); }
 108
 109 transport       { yylval.num = IPSEC_MODE_TRANSPORT; return(MODE); }
 110 tunnel          { yylval.num = IPSEC_MODE_TUNNEL; return(MODE); }
 111
 112 me              { return(ME); }
 113 any             { return(ANY); }
 114
 115 default         { yylval.num = IPSEC_LEVEL_DEFAULT; return(LEVEL); }
 116 use             { yylval.num = IPSEC_LEVEL_USE; return(LEVEL); }
 117 require         { yylval.num = IPSEC_LEVEL_REQUIRE; return(LEVEL); }
 118 unique{colon}{decstring} {
 119                         yylval.val.len = strlen(yytext + 7);
 120                         yylval.val.buf = yytext + 7;
 121                         return(LEVEL_SPECIFY);
 122                 }
 123 unique          { yylval.num = IPSEC_LEVEL_UNIQUE; return(LEVEL); }
 124 {slash}         { return(SLASH); }
 125
 126 {ipaddress}     {
 127                         yylval.val.len = strlen(yytext);
 128                         yylval.val.buf = yytext;
 129                         return(IPADDRESS);
 130                 }
 131
 132 {hyphen}        { return(HYPHEN); }
 133
 134 {ws}            { ; }
 135 {nl}            { ; }
 136
 137 %%
 138
 139 void __policy__strbuffer__init__ (char *);
 140
 141 void
 142 __policy__strbuffer__init__(char *msg)
 143 {
 144         YY_BUFFER_STATE yyb;
 145
 146         yyb = (YY_BUFFER_STATE)yy_scan_string(msg);
 147         yy_switch_to_buffer(yyb);
 148
 149         return;
 150 }
 151