usr.bin/mkcsmapper/lex.l

   1 /*      $NetBSD: lex.l,v 1.4 2006/02/09 22:03:15 dogcow Exp $   */
   2 /*      $DragonFly: src/usr.bin/mkcsmapper/lex.l,v 1.3 2008/04/10 10:21:13 hasso Exp $ */
   3
   4 %{
   5 /*-
   6  * Copyright (c)2003 Citrus Project,
   7  * All rights reserved.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  */
  30
  31 #include <machine/endian.h>
  32 #include <assert.h>
  33 #include <errno.h>
  34 #include <limits.h>
  35 #include <stdio.h>
  36 #include <stdlib.h>
  37 #include <string.h>
  38
  39 #include "ldef.h"
  40 #include "yacc.h"
  41
  42 #define YY_NO_UNPUT
  43
  44 int line_number = 1;
  45 %}
  46
  47 %x      COMMENT
  48
  49 %%
  50
  51 [ \t]+  { }
  52 #.*[\n]|"//".*[\n]|[\n] { line_number++; return (R_LN); }
  53
  54 "/*"            { BEGIN COMMENT; }
  55 <COMMENT>"*/"   { BEGIN 0; }
  56 <COMMENT>[\n]   { line_number++; }
  57 <COMMENT>.      { }
  58 <COMMENT><<EOF>>        {
  59                 yyerror("unexpected file end (unterminate comment)\n");
  60                 exit(1);
  61         }
  62
  63 "="|"/"|"-"     { return (int)yytext[0]; }
  64
  65 ([1-9][0-9]*)|(0[0-9]*)|(0[xX][0-9A-Fa-f]+)     {
  66                 yylval.i_value = strtoul(yytext, NULL, 0);
  67                 return L_IMM;
  68         }
  69
  70 "TYPE"          { return (R_TYPE); }
  71 "NAME"          { return (R_NAME); }
  72 "SRC_ZONE"      { return (R_SRC_ZONE); }
  73 "DST_INVALID"   { return (R_DST_INVALID); }
  74 "DST_ILSEQ"     { return (R_DST_ILSEQ); }
  75 "DST_UNIT_BITS" { return (R_DST_UNIT_BITS); }
  76 "BEGIN_MAP"     { return (R_BEGIN_MAP); }
  77 "END_MAP"       { return (R_END_MAP); }
  78 "INVALID"       { return (R_INVALID); }
  79 "ILSEQ"         { return (R_ILSEQ); }
  80 "OOB_MODE"      { return (R_OOB_MODE); }
  81 "ROWCOL"        { return (R_ROWCOL); }
  82
  83 \"([^\"\n]*(\\\")?)*\"|\'([^\'\n]*(\\\')?)*\'   {
  84                 size_t len;
  85                 len = strlen(yytext);
  86                 yylval.s_value = malloc(len-1);
  87                 strlcpy(yylval.s_value, yytext+1, len-1);
  88                 return L_STRING;
  89         }
  90 [^ =/\-0-9\t\n][^ \t\n]*        {
  91                 yylval.s_value = strdup(yytext);
  92                 return L_STRING;
  93         }
  94
  95 %%
  96
  97 #ifndef yywrap
  98 int
  99 yywrap(void)
 100 {
 101         return (1);
 102 }
 103 #endif