sys/cpu/x86_64/misc/in_cksum2.s

   1 /*
   2  * Copyright (c) 2003,2004,2008 The DragonFly Project.  All rights reserved.
   3  *
   4  * This code is derived from software contributed to The DragonFly Project
   5  * by Matthew Dillon <dillon@backplane.com>
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in
  15  *    the documentation and/or other materials provided with the
  16  *    distribution.
  17  * 3. Neither the name of The DragonFly Project nor the names of its
  18  *    contributors may be used to endorse or promote products derived
  19  *    from this software without specific, prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asmacros.h>           /* miscellaneous asm macros */
  36
  37 #include "assym.s"
  38
  39         .text
  40
  41         /*
  42          * asm_ones32(32bitalignedbuffer, numberof32bitwords)
  43          *
  44          * Returns the 32 bit one complement partial checksum.  This is
  45          * basically a 1's complement checksum without the inversion (~)
  46          * at the end.  A 32 bit value is returned.  If the caller is
  47          * calculating a 16 bit 1's complement checksum the caller must
  48          * collapse the 32 bit return value via:
  49          *
  50          *      result = (result >> 16) + (result & 0xFFFF)
  51          *      if (result > 0xFFFF)
  52          *          result -= 0xFFFF;   <<< same as (result + 1) & 0xFFFF
  53          *                                  within the range of result.
  54          * Note that worst case 0xFFFFFFFF + 0xFFFFFFFF = 0xFFFFFFFE + CARRY,
  55          * so no double-carry ever occurs.
  56          */
  57         .p2align 4
  58 ENTRY(asm_ones32)
  59         movq    %rdi,%rdx       /* %rdx = buffer pointer */
  60         movl    %esi,%ecx       /* %ecx = counter */
  61         xorl    %eax,%eax       /* %eax = checksum */
  62         cmpl    $5,%ecx
  63         jl      2f
  64 1:
  65         subl    $5,%ecx
  66         addl    (%rdx),%eax
  67         adcl    4(%rdx),%eax
  68         adcl    8(%rdx),%eax
  69         adcl    12(%rdx),%eax
  70         adcl    16(%rdx),%eax
  71         adcl    $0,%eax
  72         addq    $20,%rdx
  73         cmpl    $5,%ecx
  74         jge     1b
  75 2:
  76         testl   %ecx,%ecx
  77         je      4f
  78 3:
  79         addl    (%rdx),%eax
  80         adcl    $0,%eax
  81         addq    $4,%rdx
  82         decl    %ecx
  83         jnz     3b
  84 4:
  85         ret