bin/sh/arith_lex.l

   1 %{
   2 /*-
   3  * Copyright (c) 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * Kenneth Almquist.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed by the University of
  20  *      California, Berkeley and its contributors.
  21  * 4. Neither the name of the University nor the names of its contributors
  22  *    may be used to endorse or promote products derived from this software
  23  *    without specific prior written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  29  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  30  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  31  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  32  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  33  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  34  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  35  * SUCH DAMAGE.
  36  *
  37  * @(#)arith_lex.l      8.3 (Berkeley) 5/4/95
  38  * $FreeBSD: src/bin/sh/arith_lex.l,v 1.24 2005/08/13 07:59:46 stefanf Exp $
  39  * $DragonFly: src/bin/sh/arith_lex.l,v 1.5 2007/01/04 14:06:21 pavalos Exp $
  40  */
  41
  42 #include <string.h>
  43 #include <unistd.h>
  44
  45 #include "arith.h"
  46 #include "shell.h"
  47 #include "y.tab.h"
  48 #include "error.h"
  49 #include "memalloc.h"
  50 #include "var.h"
  51
  52 int yylex(void);
  53
  54 #undef YY_INPUT
  55 #define YY_INPUT(buf,result,max) \
  56         result = (*buf = *arith_buf++) ? 1 : YY_NULL;
  57 #define YY_NO_UNPUT
  58 %}
  59
  60 %%
  61 [ \t\n] { ; }
  62
  63 0x[a-fA-F0-9]+  {
  64                         yylval.l_value = strtoarith_t(yytext, NULL, 16);
  65                         return ARITH_NUM;
  66                 }
  67
  68 0[0-7]+         {
  69                         yylval.l_value = strtoarith_t(yytext, NULL, 8);
  70                         return ARITH_NUM;
  71                 }
  72
  73 [0-9]+          {
  74                         yylval.l_value = strtoarith_t(yytext, NULL, 10);
  75                         return ARITH_NUM;
  76                 }
  77
  78 [A-Za-z][A-Za-z0-9_]*   {
  79                         /*
  80                          * If variable doesn't exist, we should initialize
  81                          * it to zero.
  82                          */
  83                         char *temp;
  84                         if (lookupvar(yytext) == NULL)
  85                                 setvarsafe(yytext, "0", 0);
  86                         temp = (char *)ckmalloc(strlen(yytext) + 1);
  87                         yylval.s_value = strcpy(temp, yytext);
  88
  89                         return ARITH_VAR;
  90                 }
  91
  92 "("             {       return ARITH_LPAREN;    }
  93 ")"             {       return ARITH_RPAREN;    }
  94 "||"            {       return ARITH_OR;        }
  95 "&&"            {       return ARITH_AND;       }
  96 "|"             {       return ARITH_BOR;       }
  97 "^"             {       return ARITH_BXOR;      }
  98 "&"             {       return ARITH_BAND;      }
  99 "=="            {       return ARITH_EQ;        }
 100 "!="            {       return ARITH_NE;        }
 101 ">"             {       return ARITH_GT;        }
 102 ">="            {       return ARITH_GE;        }
 103 "<"             {       return ARITH_LT;        }
 104 "<="            {       return ARITH_LE;        }
 105 "<<"            {       return ARITH_LSHIFT;    }
 106 ">>"            {       return ARITH_RSHIFT;    }
 107 "*"             {       return ARITH_MUL;       }
 108 "/"             {       return ARITH_DIV;       }
 109 "%"             {       return ARITH_REM;       }
 110 "+"             {       return ARITH_ADD;       }
 111 "-"             {       return ARITH_SUB;       }
 112 "~"             {       return ARITH_BNOT;      }
 113 "!"             {       return ARITH_NOT;       }
 114 "="             {       return ARITH_ASSIGN;    }
 115 "+="            {       return ARITH_ADDASSIGN; }
 116 "-="            {       return ARITH_SUBASSIGN; }
 117 "*="            {       return ARITH_MULASSIGN; }
 118 "/="            {       return ARITH_DIVASSIGN; }
 119 "%="            {       return ARITH_REMASSIGN; }
 120 ">>="           {       return ARITH_RSHASSIGN; }
 121 "<<="           {       return ARITH_LSHASSIGN; }
 122 "&="            {       return ARITH_BANDASSIGN; }
 123 "^="            {       return ARITH_BXORASSIGN; }
 124 "|="            {       return ARITH_BORASSIGN; }
 125 .               {
 126                         error("arith: syntax error: \"%s\"\n", arith_startbuf);
 127                 }
 128 %%
 129
 130 void
 131 arith_lex_reset(void)
 132 {
 133         YY_NEW_FILE;
 134 }