sys/dev/agp/agp_if.m

   1 #
   2 # Copyright (c) 2000 Doug Rabson
   3 # All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 # 1. Redistributions of source code must retain the above copyright
   9 #    notice, this list of conditions and the following disclaimer.
  10 # 2. Redistributions in binary form must reproduce the above copyright
  11 #    notice, this list of conditions and the following disclaimer in the
  12 #    documentation and/or other materials provided with the distribution.
  13 #
  14 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17 # ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24 # SUCH DAMAGE.
  25 #
  26 # $FreeBSD: src/sys/dev/agp/agp_if.m,v 1.4 2007/11/12 21:51:36 jhb Exp $
  27 # $DragonFly: src/sys/dev/agp/agp_if.m,v 1.4 2008/01/07 01:34:58 corecode Exp $
  28 #
  29
  30 #include <sys/bus.h>
  31
  32 #
  33 # The AGP interface is used internally to the agp driver to isolate the
  34 # differences between various AGP chipsets into chipset mini drivers. It
  35 # should not be used outside the AGP driver. The kernel api for accessing
  36 # AGP functionality is described in <pci/agpvar.h>
  37 #
  38 INTERFACE agp;
  39
  40 CODE {
  41         static int
  42         null_agp_chipset_flush(device_t dev)
  43         {
  44                 return (ENXIO);
  45         }
  46 };
  47
  48 #
  49 # Return the current aperture size.
  50 #
  51 METHOD u_int32_t get_aperture {
  52         device_t        dev;
  53 };
  54
  55 #
  56 # Set the size of the aperture. Return EINVAL on error or 0 on success.
  57 #
  58 METHOD int set_aperture {
  59         device_t        dev;
  60         u_int32_t       aperture;
  61 };
  62
  63 #
  64 # Bind a single page in the AGP aperture to a given physical address.
  65 # The offset is a byte offset within the aperture which must be
  66 # aligned to an AGP page boundary.
  67 #
  68 METHOD int bind_page {
  69         device_t        dev;
  70         vm_offset_t     offset;
  71         vm_offset_t     physical;
  72 };
  73
  74 #
  75 # Unbind a single page in the AGP aperture.
  76 #
  77 METHOD int unbind_page {
  78         device_t        dev;
  79         vm_offset_t     offset;
  80 };
  81
  82 #
  83 # Flush the GATT TLB. This is used after a call to bind_page to
  84 # ensure that any mappings cached in the chipset are discarded.
  85 #
  86 METHOD void flush_tlb {
  87         device_t        dev;
  88 };
  89
  90 #
  91 # Enable the agp hardware with the relavent mode. The mode bits are
  92 # defined in <pci/agpreg.h>
  93 #
  94 METHOD int enable {
  95         device_t        dev;
  96         u_int32_t       mode;
  97 };
  98
  99 #
 100 # Allocate memory of a given type. The type is a chipset-specific
 101 # code which is used by certain integrated agp graphics chips
 102 # (basically just the i810 for now) to access special features of
 103 # the chipset. An opaque handle representing the memory region is
 104 # returned and can be used as an argument to free_memory, bind_memory
 105 # and unbind_memory.
 106 #
 107 # The size is specified in bytes but must be a multiple of the AGP
 108 # page size.
 109 #
 110 METHOD struct agp_memory * alloc_memory {
 111         device_t        dev;
 112         int             type;
 113         vm_size_t       size;
 114 };
 115
 116 #
 117 # Free a memory region previously allocated with alloc_memory. Return
 118 # EBUSY if the memory is bound.
 119 #
 120 METHOD int free_memory {
 121         device_t        dev;
 122         struct agp_memory *mem;
 123 };
 124
 125 #
 126 # Bind a memory region to a specific byte offset within the chipset's
 127 # AGP aperture. This effectively defines a range of contiguous
 128 # physical address which alias the (possibly uncontiguous) pages in
 129 # the memory region.
 130 #
 131 METHOD int bind_memory {
 132         device_t        dev;
 133         struct agp_memory *mem;
 134         vm_offset_t     offset;
 135 };
 136
 137 #
 138 # Unbind a memory region bound with bind_memory.
 139 #
 140 METHOD int unbind_memory {
 141         device_t        dev;
 142         struct agp_memory *handle;
 143 };
 144
 145 METHOD int chipset_flush {
 146         device_t        dev;
 147 } DEFAULT null_agp_chipset_flush;