configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 m4_pattern_forbid([^_?DPKG_])
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([dpkg], m4_esyscmd([build-aux/get-version]),
   7         [debian-dpkg@lists.debian.org], [dpkg],
   8         [https://wiki.debian.org/Teams/Dpkg])
   9 DPKG_DIST_IS_RELEASE
  10 AC_SUBST([PACKAGE_COPYRIGHT_HOLDER], ['Dpkg Developers'])
  11 AC_SUBST([PACKAGE_VCS_TYPE], [git])
  12 AC_SUBST([PACKAGE_VCS_URL], [https://git.dpkg.org/git/dpkg/dpkg.git])
  13 AC_SUBST([PACKAGE_VCS_WEB], [https://git.dpkg.org/cgit/dpkg/dpkg.git])
  14 AC_SUBST([PACKAGE_BUG_WEB], [https://bugs.debian.org/src:dpkg])
  15 AC_SUBST([PACKAGE_CPAN_NAME], [Dpkg])
  16 AC_CONFIG_SRCDIR([lib/dpkg/dpkg.h])
  17 AC_CONFIG_MACRO_DIR([m4])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 AM_INIT_AUTOMAKE(
  23   [1.11]
  24   [-Wall]
  25   [foreign]
  26   [nostdinc]
  27   [subdir-objects]
  28   [tar-ustar no-dist-gzip dist-xz]
  29 )
  30 AM_SILENT_RULES([yes])
  31
  32 # Require at least this gettext version, but will take any later version too.
  33 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.8])
  34 # XXX: We cannot remove the following macro due to backwards compatibility
  35 # reasons. The above macro is set unconditionally to the minimal version
  36 # required, and the below is set to 0.19.6, the first version introducing
  37 # the AM_GNU_GETTEXT_REQUIRE_VERSION macro.
  38 AM_GNU_GETTEXT_VERSION([0.19.6])
  39 AM_GNU_GETTEXT([external])
  40 DPKG_DIST_CHECK([test "$GMSGFMT" = ":" && test "$USE_NLS" = "yes"],
  41   [gettext required when NLS support enabled])
  42
  43 # Shared libraries are disabled on purpose, currently there is no ABI stability
  44 # guarantee, and it will be broken at will. The infrastructure is in place just
  45 # to be able to test that its future activation will work.
  46 AM_PROG_AR
  47 LT_INIT([disable-shared])
  48 DPKG_BUILD_SHARED_LIBS
  49 DPKG_LINKER_AS_NEEDED
  50 DPKG_LINKER_VERSION_SCRIPT
  51
  52 # Allow compilation without optional programs
  53 DPKG_BUILD_PROG([dselect])
  54 DPKG_BUILD_PROG([start-stop-daemon])
  55 DPKG_BUILD_PROG([update-alternatives])
  56
  57 DPKG_BUILD_RELEASE_DATE
  58 DPKG_BUILD_DEVEL_DOCS
  59
  60 # Allow alternate directories
  61 DPKG_WITH_DIR([devlibdir], [${libdir}],
  62   [dpkg development library directory [LIBDIR]])
  63 DPKG_WITH_DIR([pkgconfdir], [${sysconfdir}/${PACKAGE_NAME}],
  64   [dpkg configuration directory [SYSCONFDIR/dpkg]])
  65 DPKG_WITH_DIR([admindir], [${localstatedir}/lib/${PACKAGE_NAME}],
  66   [dpkg database directory [LOCALSTATEDIR/lib/dpkg]])
  67 DPKG_WITH_DIR([backupsdir], [${localstatedir}/backups],
  68   [dpkg database backups directory [LOCALSTATEDIR/backups]])
  69 DPKG_WITH_DIR([logdir], [${localstatedir}/log],
  70   [system logging directory [LOCALSTATEDIR/log]])
  71 DPKG_WITH_DIR([zshcompletionsdir], [${datadir}/zsh/vendor-completions],
  72   [zsh vendor completions directory [DATADIR/zsh/vendor-completions]])
  73
  74 # Set default dpkg-deb values
  75 DPKG_DEB_COMPRESSOR([xz])
  76
  77 # Checks for programs.
  78 AC_PROG_SED
  79 AC_PROG_CC
  80 DPKG_C_C99
  81 AC_PROG_CXX
  82 DPKG_CXX_CXX11
  83 DPKG_PROG_PATCH
  84 AC_CHECK_PROGS([DOXYGEN], [doxygen])
  85 AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
  86 DPKG_PROG_TAR
  87 DPKG_PROG_PO4A
  88 DPKG_PROG_PERL
  89 DPKG_PROG_POD2MAN
  90 DPKG_CODE_COVERAGE
  91
  92 # Checks for operating system services and capabilities.
  93 AC_SYS_LARGEFILE
  94
  95 # Checks for libraries.
  96 DPKG_LIB_MD
  97 DPKG_LIB_Z
  98 DPKG_LIB_BZ2
  99 DPKG_LIB_LZMA
 100 DPKG_LIB_SELINUX
 101 AS_IF([test "x$build_dselect" = "xyes"], [
 102   DPKG_LIB_CURSES
 103 ])
 104 AS_IF([test "x$build_start_stop_daemon" = "xyes"], [
 105   DPKG_LIB_SOCKET
 106   DPKG_LIB_PS
 107   DPKG_LIB_KVM
 108 ])
 109
 110 # Checks for header files.
 111 AC_CHECK_HEADERS([\
 112   stddef.h \
 113   error.h \
 114   err.h \
 115   locale.h \
 116   xlocale.h \
 117   libintl.h \
 118   kvm.h \
 119   sys/sysmacros.h \
 120   sys/param.h \
 121   sys/syscall.h \
 122   sys/user.h \
 123   sys/procfs.h \
 124   sys/pstat.h \
 125   linux/fiemap.h \
 126 ])
 127 AS_CASE([$host_os],
 128   [linux-gnu*], [
 129     # The glibc project has deprecated the <sys/sysctl.h> header and emits
 130     # warnings on its usage, and removed it in 2.32. The Linux kernel removed
 131     # support for it in 5.5.
 132   ], [
 133     # On other systems, we need to check whether to use it.
 134     AC_CHECK_HEADERS([\
 135       sys/sysctl.h \
 136     ])
 137   ]
 138 )
 139 AC_CHECK_HEADERS([sys/proc.h], [], [], [
 140 #ifdef HAVE_SYS_PARAM_H
 141 #include <sys/param.h>
 142 #endif
 143 ])
 144
 145 AS_IF([test "x$build_dselect" = "xyes"], [
 146   AC_LANG_PUSH([C++])
 147   AC_CHECK_HEADERS([cxxabi.h])
 148   AC_LANG_POP([C++])
 149 ])
 150
 151 # Checks for typedefs, structures, and compiler characteristics.
 152 AC_C_BIGENDIAN
 153 AC_C_CONST
 154 AC_C_INLINE
 155 AC_C_VOLATILE
 156 AC_TYPE_MODE_T
 157 AC_TYPE_PID_T
 158 AC_TYPE_SIZE_T
 159 DPKG_TYPE_PTRDIFF_T
 160 AC_CHECK_SIZEOF([unsigned int])
 161 AC_CHECK_SIZEOF([unsigned long])
 162 DPKG_DECL_SYS_SIGLIST
 163 DPKG_DECL_SYS_ERRLIST
 164
 165 # Checks for library functions.
 166 DPKG_FUNC_VA_COPY
 167 DPKG_FUNC_C99_SNPRINTF
 168 DPKG_FUNC_FSYNC_DIR
 169 DPKG_CHECK_DECL([offsetof], [stddef.h])
 170 DPKG_CHECK_DECL([makedev], [sys/types.h])
 171 DPKG_CHECK_DECL([WCOREDUMP], [sys/wait.h])
 172 DPKG_CHECK_DECL([TIOCNOTTY], [sys/ioctl.h])
 173 DPKG_CHECK_DECL([O_NOFOLLOW], [fcntl.h])
 174 DPKG_CHECK_DECL([F_ALLOCSP64], [fcntl.h])
 175 DPKG_CHECK_DECL([F_PREALLOCATE], [fcntl.h])
 176 DPKG_CHECK_DECL([P_tmpdir], [stdio.h])
 177 DPKG_CHECK_PROGNAME
 178 DPKG_CHECK_COMPAT_FUNCS([\
 179   getopt \
 180   getopt_long \
 181   obstack_free \
 182   strchrnul \
 183   strnlen \
 184   strndup \
 185   strerror \
 186   strsignal \
 187   asprintf \
 188   scandir \
 189   alphasort \
 190   unsetenv \
 191 ])
 192 AC_CHECK_FUNCS([memcpy lchown],
 193   [], [AC_MSG_ERROR([missing required function])])
 194 AC_CHECK_FUNCS([\
 195   strtoimax \
 196   isascii \
 197   setsid \
 198   getdtablesize \
 199   getprocs64 \
 200   getprogname \
 201   getexecname \
 202   lutimes \
 203   fallocate \
 204   posix_fallocate \
 205   posix_fadvise \
 206   uselocale \
 207 ])
 208
 209 AS_IF([test "x$build_dselect" = "xyes"], [
 210   AC_LANG_PUSH([C++])
 211   AC_CHECK_FUNCS([__cxa_pure_virtual])
 212   AC_LANG_POP([C++])
 213 ])
 214
 215 DPKG_USE_MMAP
 216 DPKG_USE_DISK_PREALLOCATE
 217
 218 # Checks for the build machinery.
 219 AC_DEFINE([LIBDPKG_VOLATILE_API], [1], [Acknowledge the volatility of the API.])
 220 DPKG_COMPILER_WARNINGS
 221 DPKG_COMPILER_OPTIMIZATIONS
 222 DPKG_LINKER_OPTIMIZATIONS
 223 DPKG_ARCHITECTURE
 224 AC_DEFINE([PACKAGE_RELEASE], [PACKAGE_VERSION " (" ARCHITECTURE ")"],
 225   [Define the project release information, version and architecture])
 226
 227 AC_CONFIG_TESTDIR([src/at])
 228 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 229
 230 AC_CONFIG_FILES([
 231   Makefile
 232   dselect/Makefile
 233   dselect/methods/Makefile
 234   dselect/po/Makefile.in
 235   lib/Makefile
 236   lib/compat/Makefile
 237   lib/dpkg/Makefile
 238   lib/dpkg/libdpkg.pc
 239   doc/Doxyfile
 240   man/Makefile
 241   po/Makefile.in
 242   scripts/Build.PL
 243   scripts/Makefile
 244   scripts/README.cpan
 245   scripts/mk/Makefile
 246   scripts/po/Makefile.in
 247   src/Makefile
 248   src/at/atlocal
 249   utils/Makefile
 250 ])
 251 AC_CONFIG_HEADERS([config.h])
 252 AC_OUTPUT
 253
 254 # Print the current configuration
 255 cat <<CONFIG
 256
 257 Configuration:
 258   Features:
 259     native language support . . . : $USE_NLS
 260     unicode support . . . . . . . : $USE_UNICODE
 261     development documentation . . : $build_devel_docs
 262     code coverage . . . . . . . . : $enable_coverage
 263     build shared libraries  . . . : $enable_shared
 264     mmap loaders  . . . . . . . . : $enable_mmap
 265     disk pre-allocation . . . . . : $enable_disk_preallocate
 266     default dpkg-deb compressor . : $with_dpkg_deb_compressor
 267
 268   Paths:
 269     devlibdir . . . . . . . . . . : $devlibdir
 270     pkgconfdir  . . . . . . . . . : $pkgconfdir
 271     admindir  . . . . . . . . . . : $admindir
 272     backupsdir  . . . . . . . . . : $backupsdir
 273     logdir  . . . . . . . . . . . : $logdir
 274     perl interpreter  . . . . . . : $PERL
 275     perl libdir . . . . . . . . . : $PERL_LIBDIR
 276
 277   Programs:
 278     update-alternatives . . . . . : $build_update_alternatives
 279     start-stop-daemon . . . . . . : $build_start_stop_daemon
 280     dselect . . . . . . . . . . . : $build_dselect
 281
 282   System Libraries:
 283     libsocket . . . . . . . . . . : ${have_libsocket:-no}
 284     libps . . . . . . . . . . . . : ${have_libps:-no}
 285     libkvm  . . . . . . . . . . . : ${have_libkvm:-no}
 286     libselinux  . . . . . . . . . : $have_libselinux
 287     libmd . . . . . . . . . . . . : $have_libmd
 288     libz  . . . . . . . . . . . . : $have_libz_impl
 289     liblzma . . . . . . . . . . . : $have_liblzma
 290     libbz2  . . . . . . . . . . . : $have_libbz2
 291     libcurses . . . . . . . . . . : ${have_libcurses:-no}
 292 CONFIG