configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 m4_pattern_forbid([^_?DPKG_])
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([dpkg], m4_esyscmd([./get-version]), [debian-dpkg@lists.debian.org],
   7         [dpkg], [https://wiki.debian.org/Teams/Dpkg])
   8 DPKG_DIST_IS_RELEASE
   9 AC_SUBST([PACKAGE_COPYRIGHT_HOLDER], ['Dpkg Developers'])
  10 AC_SUBST([PACKAGE_VCS_TYPE], [git])
  11 AC_SUBST([PACKAGE_VCS_URL], [https://git.dpkg.org/git/dpkg/dpkg.git])
  12 AC_SUBST([PACKAGE_VCS_WEB], [https://git.dpkg.org/cgit/dpkg/dpkg.git])
  13 AC_SUBST([PACKAGE_BUG_WEB], [https://bugs.debian.org/src:dpkg])
  14 AC_SUBST([PACKAGE_CPAN_NAME], [Dpkg])
  15 AC_CONFIG_SRCDIR([lib/dpkg/dpkg.h])
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_AUX_DIR([build-aux])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_INIT_AUTOMAKE(
  22   [1.11]
  23   [-Wall]
  24   [foreign]
  25   [nostdinc]
  26   [tar-ustar no-dist-gzip dist-xz]
  27 )
  28 AM_SILENT_RULES([yes])
  29
  30 # Require at least this gettext version, but will take any later version too.
  31 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.8])
  32 # XXX: We cannot remove the following macro due to backwards compatibility
  33 # reasons. The above macro is set unconditionally to the minimal version
  34 # required, and the below is set to 0.19.6, the first version introducing
  35 # the AM_GNU_GETTEXT_REQUIRE_VERSION macro.
  36 AM_GNU_GETTEXT_VERSION([0.19.6])
  37 AM_GNU_GETTEXT([external])
  38 DPKG_DIST_CHECK([test "$GMSGFMT" = ":" && test "$USE_NLS" = "yes"],
  39   [gettext required when NLS support enabled])
  40
  41 # Shared libraries are disabled on purpose, currently there is no ABI stability
  42 # guarantee, and it will be broken at will. The infrastructure is in place just
  43 # to be able to test that its future activation will work.
  44 AM_PROG_AR
  45 LT_INIT([disable-shared])
  46 DPKG_BUILD_SHARED_LIBS
  47 DPKG_LINKER_AS_NEEDED
  48 DPKG_LINKER_VERSION_SCRIPT
  49
  50 # Allow compilation without optional programs
  51 DPKG_BUILD_PROG([dselect])
  52 DPKG_BUILD_PROG([start-stop-daemon])
  53 DPKG_BUILD_PROG([update-alternatives])
  54
  55 DPKG_BUILD_RELEASE_DATE
  56 DPKG_BUILD_DEVEL_DOCS
  57
  58 # Allow alternate directories
  59 DPKG_WITH_DIR([devlibdir], [${libdir}],
  60   [dpkg development library directory [LIBDIR]])
  61 DPKG_WITH_DIR([pkgconfdir], [${sysconfdir}/${PACKAGE_NAME}],
  62   [dpkg configuration directory [SYSCONFDIR/dpkg]])
  63 DPKG_WITH_DIR([admindir], [${localstatedir}/lib/${PACKAGE_NAME}],
  64   [dpkg database directory [LOCALSTATEDIR/lib/dpkg]])
  65 DPKG_WITH_DIR([logdir], [${localstatedir}/log],
  66   [system logging directory [LOCALSTATEDIR/log]])
  67
  68 # Set default dpkg-deb values
  69 DPKG_DEB_COMPRESSOR([xz])
  70 DPKG_DEB_PROG_TAR
  71
  72 # Checks for programs.
  73 AC_PROG_CC
  74 DPKG_C_C99
  75 AC_PROG_CXX
  76 DPKG_CXX_CXX11
  77 DPKG_PROG_PATCH
  78 AC_CHECK_PROGS([DOXYGEN], [doxygen])
  79 AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
  80 DPKG_PROG_PO4A
  81 DPKG_PROG_PERL
  82 DPKG_PROG_POD2MAN
  83 DPKG_CODE_COVERAGE
  84
  85 # Checks for operating system services and capabilities.
  86 AC_SYS_LARGEFILE
  87
  88 # Checks for libraries.
  89 DPKG_LIB_MD
  90 DPKG_LIB_Z
  91 DPKG_LIB_BZ2
  92 DPKG_LIB_LZMA
  93 DPKG_LIB_SELINUX
  94 AS_IF([test "x$build_dselect" = "xyes"], [
  95   DPKG_LIB_CURSES
  96 ])
  97 AS_IF([test "x$build_start_stop_daemon" = "xyes"], [
  98   DPKG_LIB_PS
  99   DPKG_LIB_KVM
 100 ])
 101
 102 # Checks for header files.
 103 AC_HEADER_STDC
 104 AC_CHECK_HEADERS([\
 105   stddef.h \
 106   error.h \
 107   err.h \
 108   locale.h \
 109   libintl.h \
 110   kvm.h \
 111   sys/sysmacros.h \
 112   sys/param.h \
 113   sys/sysctl.h \
 114   sys/syscall.h \
 115   sys/user.h \
 116   sys/procfs.h \
 117   sys/pstat.h \
 118   linux/fiemap.h \
 119 ])
 120 AC_CHECK_HEADERS([sys/proc.h], [], [], [
 121 #ifdef HAVE_SYS_PARAM_H
 122 #include <sys/param.h>
 123 #endif
 124 ])
 125
 126 AS_IF([test "x$build_dselect" = "xyes"], [
 127   AC_LANG_PUSH([C++])
 128   AC_CHECK_HEADERS([cxxabi.h])
 129   AC_LANG_POP([C++])
 130 ])
 131
 132 # Checks for typedefs, structures, and compiler characteristics.
 133 AC_C_BIGENDIAN
 134 AC_C_CONST
 135 AC_C_INLINE
 136 AC_C_VOLATILE
 137 AC_TYPE_MODE_T
 138 AC_TYPE_PID_T
 139 AC_TYPE_SIZE_T
 140 DPKG_TYPE_PTRDIFF_T
 141 AC_CHECK_SIZEOF([unsigned int])
 142 AC_CHECK_SIZEOF([unsigned long])
 143 DPKG_DECL_SYS_SIGLIST
 144 DPKG_DECL_SYS_ERRLIST
 145
 146 # Checks for library functions.
 147 DPKG_FUNC_VA_COPY
 148 DPKG_FUNC_C99_SNPRINTF
 149 DPKG_CHECK_DECL([offsetof], [stddef.h])
 150 DPKG_CHECK_DECL([makedev], [sys/types.h])
 151 DPKG_CHECK_DECL([WCOREDUMP], [sys/wait.h])
 152 DPKG_CHECK_DECL([TIOCNOTTY], [sys/ioctl.h])
 153 DPKG_CHECK_DECL([O_NOFOLLOW], [fcntl.h])
 154 DPKG_CHECK_DECL([F_ALLOCSP64], [fcntl.h])
 155 DPKG_CHECK_DECL([F_PREALLOCATE], [fcntl.h])
 156 DPKG_CHECK_DECL([P_tmpdir], [stdio.h])
 157 DPKG_CHECK_PROGNAME
 158 DPKG_CHECK_COMPAT_FUNCS([\
 159   getopt \
 160   getopt_long \
 161   obstack_free \
 162   strchrnul \
 163   strnlen \
 164   strndup \
 165   strerror \
 166   strsignal \
 167   asprintf \
 168   scandir \
 169   alphasort \
 170   unsetenv \
 171 ])
 172 AC_CHECK_FUNCS([memcpy lchown],
 173   [], [AC_MSG_ERROR([missing required function])])
 174 AC_CHECK_FUNCS([\
 175   strtoimax \
 176   isascii \
 177   setsid \
 178   getdtablesize \
 179   getprogname \
 180   getexecname \
 181   lutimes \
 182   fallocate \
 183   posix_fallocate \
 184   posix_fadvise \
 185   uselocale \
 186 ])
 187
 188 AS_IF([test "x$build_dselect" = "xyes"], [
 189   AC_LANG_PUSH([C++])
 190   AC_CHECK_FUNCS([__cxa_pure_virtual])
 191   AC_LANG_POP([C++])
 192 ])
 193
 194 DPKG_USE_MMAP
 195 DPKG_USE_DISK_PREALLOCATE
 196
 197 # Checks for the build machinery.
 198 AC_DEFINE([LIBDPKG_VOLATILE_API], [1], [Acknowledge the volatility of the API.])
 199 DPKG_COMPILER_WARNINGS
 200 DPKG_COMPILER_OPTIMIZATIONS
 201 DPKG_LINKER_OPTIMIZATIONS
 202 DPKG_ARCHITECTURE
 203 AC_DEFINE([PACKAGE_RELEASE], [PACKAGE_VERSION " (" ARCHITECTURE ")"],
 204   [Define the project release information, version and architecture])
 205
 206 AC_CONFIG_TESTDIR([t-func])
 207 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 208
 209 AC_CONFIG_FILES([
 210   Makefile
 211   t-func/Makefile
 212   t-func/atlocal
 213   dpkg-deb/Makefile
 214   dpkg-split/Makefile
 215   dselect/Makefile
 216   dselect/methods/Makefile
 217   dselect/po/Makefile.in
 218   lib/Makefile
 219   lib/compat/Makefile
 220   lib/dpkg/Makefile
 221   lib/dpkg/libdpkg.pc
 222   lib/dpkg/t/Makefile
 223   doc/Doxyfile
 224   man/Makefile
 225   po/Makefile.in
 226   scripts/Build.PL
 227   scripts/Makefile
 228   scripts/mk/Makefile
 229   scripts/po/Makefile.in
 230   src/Makefile
 231   utils/Makefile
 232 ])
 233 AC_CONFIG_HEADERS([config.h])
 234 AC_OUTPUT
 235
 236 # Print the current configuration
 237 cat <<CONFIG
 238
 239 Configuration:
 240   Features:
 241     native language support . . . : $USE_NLS
 242     unicode support . . . . . . . : $USE_UNICODE
 243     development documentation . . : $build_devel_docs
 244     code coverage . . . . . . . . : $enable_coverage
 245     build shared libraries  . . . : $enable_shared
 246     mmap loaders  . . . . . . . . : $enable_mmap
 247     disk pre-allocation . . . . . : $enable_disk_preallocate
 248     default dpkg-deb compressor . : $with_dpkg_deb_compressor
 249
 250   Paths:
 251     devlibdir . . . . . . . . . . : $devlibdir
 252     pkgconfdir  . . . . . . . . . : $pkgconfdir
 253     admindir  . . . . . . . . . . : $admindir
 254     logdir  . . . . . . . . . . . : $logdir
 255     perl interpreter  . . . . . . : $PERL
 256     perl libdir . . . . . . . . . : $PERL_LIBDIR
 257
 258   Programs:
 259     update-alternatives . . . . . : $build_update_alternatives
 260     start-stop-daemon . . . . . . : $build_start_stop_daemon
 261     dselect . . . . . . . . . . . : $build_dselect
 262
 263   System Libraries:
 264     libps . . . . . . . . . . . . : ${have_libps:-no}
 265     libkvm  . . . . . . . . . . . : ${have_libkvm:-no}
 266     libselinux  . . . . . . . . . : $have_libselinux
 267     libmd . . . . . . . . . . . . : $have_libmd
 268     libz  . . . . . . . . . . . . : $have_libz
 269     liblzma . . . . . . . . . . . : $have_liblzma
 270     libbz2  . . . . . . . . . . . : $have_libbz2
 271     libcurses . . . . . . . . . . : ${have_libcurses:-no}
 272 CONFIG