src/dix-utils.vala

   1 /**
   2  * Dictix / DixUtils - dix-utils.vala
   3  *
   4  * Copyright (C) Martin Blanchard 2011 <tinram@gmx.fr>
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software Foundation,
  18  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA
  19  *
  20  */
  21
  22 using GLib;
  23 using Gtk;
  24
  25 namespace Utils {
  26         public const string[] size_units = {
  27                 N_("bytes"),
  28                 N_("Kio"),
  29                 N_("Mio"),
  30                 N_("Gio")
  31         };
  32
  33         public string codec_to_string (string codec) {
  34                 if (codec == "FLAC") {
  35                         return _("FLAC (lossless)");
  36                 } else if (codec == "Vorbis") {
  37                         return _("Vorbis (lossy)");
  38                 }
  39
  40                 return _("n/a");
  41         }
  42
  43         public string basename_from_uri (string uri) {
  44                 string path = null;
  45
  46                 if (uri != null) {
  47
  48                         try {
  49                                 path = Filename.from_uri (uri);
  50                         } catch (Error error) {
  51                                 warning (error.message);
  52
  53                                 return _("n/a");
  54                         }
  55
  56                         return Path.get_basename (path);
  57                 }
  58
  59                 return _("n/a");
  60         }
  61
  62         public string size_to_string (uint64 bytes) {
  63                 float size = 0.0f;
  64                 short i = 0;
  65
  66                 if (bytes > 0) {
  67                         size = (float) bytes;
  68
  69                         while (size > 1000.0f) {
  70                                 size /= 1024.0f;
  71
  72                                 i++;
  73                         }
  74
  75                         size *= 10.0f;
  76                         size = Math.roundf (size);
  77                         size /= 10.0f;
  78
  79                         return size.to_string ("%.01lf") + " " + size_units[i];
  80                 }
  81
  82                 return size.to_string ("%.01lf") + " " + size_units[0];
  83         }
  84
  85         public string duration_to_string (int64 duration) {
  86                 int secs, mins, hours;
  87
  88                 if (duration > 0) {
  89                         /* Computation of secs / mins / hours : */
  90                         secs = (int) (duration % 60);
  91                         duration -= secs;
  92
  93                         mins = (int) ((duration % (60 * 60)) / 60);
  94                         duration -= mins * 60;
  95
  96                         if (duration == 0) {
  97                                 return mins.to_string () + ":" + secs.to_string ("%02d");
  98                         }
  99
 100                         hours = (int) (duration / (60 * 60));
 101
 102                         return hours.to_string () + ":" + mins.to_string ("%02d") + ":" + secs.to_string ("%02d");
 103                 }
 104
 105                 return "0:00";
 106         }
 107
 108         public string channels_to_string (int channels) {
 109                 if (channels > 0) {
 110                         return channels.to_string ();
 111                 }
 112
 113                 return _("n/a");
 114         }
 115
 116         public string sample_rate_to_string (int sample_rate) {
 117                 float rate = 0.0f;
 118                 int hundreds;
 119
 120                 rate = ((float) sample_rate) / 1000.0f;
 121
 122                 if (rate > 0.0f) {
 123                         hundreds = (int) (sample_rate % 1000);
 124
 125                         if ((hundreds % 100) == 0) {
 126                                 return rate.to_string ("%.01lf") + " " + _("kHz");
 127                         }
 128
 129                         if ((hundreds % 10) == 0) {
 130                                 return rate.to_string ("%.02lf") + " " + _("kHz");
 131                         }
 132
 133                         return rate.to_string ("%.03lf") + " " + _("kHz");
 134                 }
 135
 136                 return _("n/a");
 137         }
 138
 139         public string bit_rate_to_string (int bit_rate) {
 140                 int kbytes = 0;
 141
 142                 if (bit_rate > 0) {
 143                         kbytes = (int) (bit_rate / 1000);
 144
 145                         return kbytes.to_string () + " " + _("kbps");
 146                 }
 147
 148                 return _("n/a");
 149         }
 150 }
 151