baseboards/basic-sid.exp

   1 # find_sid -- find a usable SID simulator.
   2 # This proc is local to this file and is used to locate a SID to use.
   3 # Search the build tree, then $PATH.
   4 #
   5 # Written by Ben Elliston (bje@redhat.com).
   6
   7 proc find_sid { target_alias } {
   8     global env
   9     global tool_root_dir
  10
  11     set try [lookfor_file ${tool_root_dir} sid/bsp/${target_alias}-sid]
  12     if { $try != "" } {
  13         set sid_build [lookfor_file ${tool_root_dir} sid/main/dynamic/sid]
  14         if { $sid_build != "" } { set env(SID) $sid_build }
  15         return $try
  16     }
  17
  18     # In this case, the bsp script must be available on the PATH.
  19     # Just hope for the best!
  20     return ${target_alias}-sid
  21 }
  22
  23 # find_sid_conf -- find a usable pre-generated SID config file.
  24
  25 proc find_sid_conf { config } {
  26     global env
  27     global srcdir
  28
  29     set try [lookfor_file ${srcdir} sid/bsp/pregen/${config}.conf]
  30     if { $try == "" } then { return ${config}.conf } else { return $try }
  31 }
  32
  33 # find_rawsid -- find a usable SID simulator.
  34 # This proc is local to this file and is used to locate a SID to use.
  35 # Search the build tree, then $PATH.
  36
  37 proc find_rawsid { } {
  38     global env
  39     global tool_root_dir
  40     global srcdir
  41
  42     set try [lookfor_file ${tool_root_dir} sid/main/dynamic/sid]
  43     if { $try == "" } {
  44         set try "sid"
  45     } else {
  46         # testing build tree
  47         set env(SID_LIBRARY_PATH) [join [glob "${tool_root_dir}/sid/component/*" "$srcdir/sid/component/*"] ":"]
  48         # srcdir=/..../sid/component/testsuite
  49         set tcl_library "$srcdir/tcl/library"
  50         global host_os
  51         switch -glob $host_os {
  52           {cygwin*} { set tcl_library [exec cygpath -w $tcl_library] }
  53         }
  54         set env(TCL_LIBRARY) $tcl_library
  55     }
  56
  57     return $try
  58 }