contrib/emacs/git.el

   1 ;;; git.el --- A user interface for git
   2
   3 ;; Copyright (C) 2005, 2006, 2007 Alexandre Julliard <julliard@winehq.org>
   4
   5 ;; Version: 1.0
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License as
   9 ;; published by the Free Software Foundation; either version 2 of
  10 ;; the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be
  13 ;; useful, but WITHOUT ANY WARRANTY; without even the implied
  14 ;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15 ;; PURPOSE.  See the GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public
  18 ;; License along with this program; if not, write to the Free
  19 ;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20 ;; MA 02111-1307 USA
  21
  22 ;;; Commentary:
  23
  24 ;; This file contains an interface for the git version control
  25 ;; system. It provides easy access to the most frequently used git
  26 ;; commands. The user interface is as far as possible identical to
  27 ;; that of the PCL-CVS mode.
  28 ;;
  29 ;; To install: put this file on the load-path and place the following
  30 ;; in your .emacs file:
  31 ;;
  32 ;;    (require 'git)
  33 ;;
  34 ;; To start: `M-x git-status'
  35 ;;
  36 ;; TODO
  37 ;;  - portability to XEmacs
  38 ;;  - better handling of subprocess errors
  39 ;;  - diff against other branch
  40 ;;  - renaming files from the status buffer
  41 ;;  - creating tags
  42 ;;  - fetch/pull
  43 ;;  - switching branches
  44 ;;  - revlist browser
  45 ;;  - git-show-branch browser
  46 ;;  - menus
  47 ;;
  48
  49 (eval-when-compile (require 'cl))
  50 (require 'ewoc)
  51 (require 'log-edit)
  52
  53
  54 ;;;; Customizations
  55 ;;;; ------------------------------------------------------------
  56
  57 (defgroup git nil
  58   "A user interface for the git versioning system."
  59   :group 'tools)
  60
  61 (defcustom git-committer-name nil
  62   "User name to use for commits.
  63 The default is to fall back to the repository config,
  64 then to `add-log-full-name' and then to `user-full-name'."
  65   :group 'git
  66   :type '(choice (const :tag "Default" nil)
  67                  (string :tag "Name")))
  68
  69 (defcustom git-committer-email nil
  70   "Email address to use for commits.
  71 The default is to fall back to the git repository config,
  72 then to `add-log-mailing-address' and then to `user-mail-address'."
  73   :group 'git
  74   :type '(choice (const :tag "Default" nil)
  75                  (string :tag "Email")))
  76
  77 (defcustom git-commits-coding-system nil
  78   "Default coding system for the log message of git commits."
  79   :group 'git
  80   :type '(choice (const :tag "From repository config" nil)
  81                  (coding-system)))
  82
  83 (defcustom git-append-signed-off-by nil
  84   "Whether to append a Signed-off-by line to the commit message before editing."
  85   :group 'git
  86   :type 'boolean)
  87
  88 (defcustom git-reuse-status-buffer t
  89   "Whether `git-status' should try to reuse an existing buffer
  90 if there is already one that displays the same directory."
  91   :group 'git
  92   :type 'boolean)
  93
  94 (defcustom git-per-dir-ignore-file ".gitignore"
  95   "Name of the per-directory ignore file."
  96   :group 'git
  97   :type 'string)
  98
  99 (defcustom git-show-uptodate nil
 100   "Whether to display up-to-date files."
 101   :group 'git
 102   :type 'boolean)
 103
 104 (defcustom git-show-ignored nil
 105   "Whether to display ignored files."
 106   :group 'git
 107   :type 'boolean)
 108
 109 (defcustom git-show-unknown t
 110   "Whether to display unknown files."
 111   :group 'git
 112   :type 'boolean)
 113
 114
 115 (defface git-status-face
 116   '((((class color) (background light)) (:foreground "purple"))
 117     (((class color) (background dark)) (:foreground "salmon")))
 118   "Git mode face used to highlight added and modified files."
 119   :group 'git)
 120
 121 (defface git-unmerged-face
 122   '((((class color) (background light)) (:foreground "red" :bold t))
 123     (((class color) (background dark)) (:foreground "red" :bold t)))
 124   "Git mode face used to highlight unmerged files."
 125   :group 'git)
 126
 127 (defface git-unknown-face
 128   '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 129     (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 130   "Git mode face used to highlight unknown files."
 131   :group 'git)
 132
 133 (defface git-uptodate-face
 134   '((((class color) (background light)) (:foreground "grey60"))
 135     (((class color) (background dark)) (:foreground "grey40")))
 136   "Git mode face used to highlight up-to-date files."
 137   :group 'git)
 138
 139 (defface git-ignored-face
 140   '((((class color) (background light)) (:foreground "grey60"))
 141     (((class color) (background dark)) (:foreground "grey40")))
 142   "Git mode face used to highlight ignored files."
 143   :group 'git)
 144
 145 (defface git-mark-face
 146   '((((class color) (background light)) (:foreground "red" :bold t))
 147     (((class color) (background dark)) (:foreground "tomato" :bold t)))
 148   "Git mode face used for the file marks."
 149   :group 'git)
 150
 151 (defface git-header-face
 152   '((((class color) (background light)) (:foreground "blue"))
 153     (((class color) (background dark)) (:foreground "blue")))
 154   "Git mode face used for commit headers."
 155   :group 'git)
 156
 157 (defface git-separator-face
 158   '((((class color) (background light)) (:foreground "brown"))
 159     (((class color) (background dark)) (:foreground "brown")))
 160   "Git mode face used for commit separator."
 161   :group 'git)
 162
 163 (defface git-permission-face
 164   '((((class color) (background light)) (:foreground "green" :bold t))
 165     (((class color) (background dark)) (:foreground "green" :bold t)))
 166   "Git mode face used for permission changes."
 167   :group 'git)
 168
 169
 170 ;;;; Utilities
 171 ;;;; ------------------------------------------------------------
 172
 173 (defconst git-log-msg-separator "--- log message follows this line ---")
 174
 175 (defvar git-log-edit-font-lock-keywords
 176   `(("^\\(Author:\\|Date:\\|Parent:\\|Signed-off-by:\\)\\(.*\\)$"
 177      (1 font-lock-keyword-face)
 178      (2 font-lock-function-name-face))
 179     (,(concat "^\\(" (regexp-quote git-log-msg-separator) "\\)$")
 180      (1 font-lock-comment-face))))
 181
 182 (defun git-get-env-strings (env)
 183   "Build a list of NAME=VALUE strings from a list of environment strings."
 184   (mapcar (lambda (entry) (concat (car entry) "=" (cdr entry))) env))
 185
 186 (defun git-call-process-env (buffer env &rest args)
 187   "Wrapper for call-process that sets environment strings."
 188   (if env
 189       (apply #'call-process "env" nil buffer nil
 190              (append (git-get-env-strings env) (list "git") args))
 191     (apply #'call-process "git" nil buffer nil args)))
 192
 193 (defun git-call-process-env-string (env &rest args)
 194   "Wrapper for call-process that sets environment strings,
 195 and returns the process output as a string."
 196   (with-temp-buffer
 197     (and (eq 0 (apply #' git-call-process-env t env args))
 198          (buffer-string))))
 199
 200 (defun git-run-process-region (buffer start end program args)
 201   "Run a git process with a buffer region as input."
 202   (let ((output-buffer (current-buffer))
 203         (dir default-directory))
 204     (with-current-buffer buffer
 205       (cd dir)
 206       (apply #'call-process-region start end program
 207              nil (list output-buffer nil) nil args))))
 208
 209 (defun git-run-command-buffer (buffer-name &rest args)
 210   "Run a git command, sending the output to a buffer named BUFFER-NAME."
 211   (let ((dir default-directory)
 212         (buffer (get-buffer-create buffer-name)))
 213     (message "Running git %s..." (car args))
 214     (with-current-buffer buffer
 215       (let ((default-directory dir)
 216             (buffer-read-only nil))
 217         (erase-buffer)
 218         (apply #'git-call-process-env buffer nil args)))
 219     (message "Running git %s...done" (car args))
 220     buffer))
 221
 222 (defun git-run-command-region (buffer start end env &rest args)
 223   "Run a git command with specified buffer region as input."
 224   (unless (eq 0 (if env
 225                     (git-run-process-region
 226                      buffer start end "env"
 227                      (append (git-get-env-strings env) (list "git") args))
 228                   (git-run-process-region
 229                    buffer start end "git" args)))
 230     (error "Failed to run \"git %s\":\n%s" (mapconcat (lambda (x) x) args " ") (buffer-string))))
 231
 232 (defun git-run-hook (hook env &rest args)
 233   "Run a git hook and display its output if any."
 234   (let ((dir default-directory)
 235         (hook-name (expand-file-name (concat ".git/hooks/" hook))))
 236     (or (not (file-executable-p hook-name))
 237         (let (status (buffer (get-buffer-create "*Git Hook Output*")))
 238           (with-current-buffer buffer
 239             (erase-buffer)
 240             (cd dir)
 241             (setq status
 242                   (if env
 243                       (apply #'call-process "env" nil (list buffer t) nil
 244                              (append (git-get-env-strings env) (list hook-name) args))
 245                     (apply #'call-process hook-name nil (list buffer t) nil args))))
 246           (display-message-or-buffer buffer)
 247           (eq 0 status)))))
 248
 249 (defun git-get-string-sha1 (string)
 250   "Read a SHA1 from the specified string."
 251   (and string
 252        (string-match "[0-9a-f]\\{40\\}" string)
 253        (match-string 0 string)))
 254
 255 (defun git-get-committer-name ()
 256   "Return the name to use as GIT_COMMITTER_NAME."
 257   ; copied from log-edit
 258   (or git-committer-name
 259       (git-config "user.name")
 260       (and (boundp 'add-log-full-name) add-log-full-name)
 261       (and (fboundp 'user-full-name) (user-full-name))
 262       (and (boundp 'user-full-name) user-full-name)))
 263
 264 (defun git-get-committer-email ()
 265   "Return the email address to use as GIT_COMMITTER_EMAIL."
 266   ; copied from log-edit
 267   (or git-committer-email
 268       (git-config "user.email")
 269       (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 270       (and (fboundp 'user-mail-address) (user-mail-address))
 271       (and (boundp 'user-mail-address) user-mail-address)))
 272
 273 (defun git-get-commits-coding-system ()
 274   "Return the coding system to use for commits."
 275   (let ((repo-config (git-config "i18n.commitencoding")))
 276     (or git-commits-coding-system
 277         (and repo-config
 278              (fboundp 'locale-charset-to-coding-system)
 279              (locale-charset-to-coding-system repo-config))
 280       'utf-8)))
 281
 282 (defun git-get-logoutput-coding-system ()
 283   "Return the coding system used for git-log output."
 284   (let ((repo-config (or (git-config "i18n.logoutputencoding")
 285                          (git-config "i18n.commitencoding"))))
 286     (or git-commits-coding-system
 287         (and repo-config
 288              (fboundp 'locale-charset-to-coding-system)
 289              (locale-charset-to-coding-system repo-config))
 290       'utf-8)))
 291
 292 (defun git-escape-file-name (name)
 293   "Escape a file name if necessary."
 294   (if (string-match "[\n\t\"\\]" name)
 295       (concat "\""
 296               (mapconcat (lambda (c)
 297                    (case c
 298                      (?\n "\\n")
 299                      (?\t "\\t")
 300                      (?\\ "\\\\")
 301                      (?\" "\\\"")
 302                      (t (char-to-string c))))
 303                  name "")
 304               "\"")
 305     name))
 306
 307 (defun git-success-message (text files)
 308   "Print a success message after having handled FILES."
 309   (let ((n (length files)))
 310     (if (equal n 1)
 311         (message "%s %s" text (car files))
 312       (message "%s %d files" text n))))
 313
 314 (defun git-get-top-dir (dir)
 315   "Retrieve the top-level directory of a git tree."
 316   (let ((cdup (with-output-to-string
 317                 (with-current-buffer standard-output
 318                   (cd dir)
 319                   (unless (eq 0 (call-process "git" nil t nil "rev-parse" "--show-cdup"))
 320                     (error "cannot find top-level git tree for %s." dir))))))
 321     (expand-file-name (concat (file-name-as-directory dir)
 322                               (car (split-string cdup "\n"))))))
 323
 324 ;stolen from pcl-cvs
 325 (defun git-append-to-ignore (file)
 326   "Add a file name to the ignore file in its directory."
 327   (let* ((fullname (expand-file-name file))
 328          (dir (file-name-directory fullname))
 329          (name (file-name-nondirectory fullname))
 330          (ignore-name (expand-file-name git-per-dir-ignore-file dir))
 331          (created (not (file-exists-p ignore-name))))
 332   (save-window-excursion
 333     (set-buffer (find-file-noselect ignore-name))
 334     (goto-char (point-max))
 335     (unless (zerop (current-column)) (insert "\n"))
 336     (insert "/" name "\n")
 337     (sort-lines nil (point-min) (point-max))
 338     (save-buffer))
 339   (when created
 340     (git-call-process-env nil nil "update-index" "--add" "--" (file-relative-name ignore-name)))
 341   (git-update-status-files (list (file-relative-name ignore-name)) 'unknown)))
 342
 343 ; propertize definition for XEmacs, stolen from erc-compat
 344 (eval-when-compile
 345   (unless (fboundp 'propertize)
 346     (defun propertize (string &rest props)
 347       (let ((string (copy-sequence string)))
 348         (while props
 349           (put-text-property 0 (length string) (nth 0 props) (nth 1 props) string)
 350           (setq props (cddr props)))
 351         string))))
 352
 353 ;;;; Wrappers for basic git commands
 354 ;;;; ------------------------------------------------------------
 355
 356 (defun git-rev-parse (rev)
 357   "Parse a revision name and return its SHA1."
 358   (git-get-string-sha1
 359    (git-call-process-env-string nil "rev-parse" rev)))
 360
 361 (defun git-config (key)
 362   "Retrieve the value associated to KEY in the git repository config file."
 363   (let ((str (git-call-process-env-string nil "config" key)))
 364     (and str (car (split-string str "\n")))))
 365
 366 (defun git-symbolic-ref (ref)
 367   "Wrapper for the git-symbolic-ref command."
 368   (let ((str (git-call-process-env-string nil "symbolic-ref" ref)))
 369     (and str (car (split-string str "\n")))))
 370
 371 (defun git-update-ref (ref newval &optional oldval reason)
 372   "Update a reference by calling git-update-ref."
 373   (let ((args (and oldval (list oldval))))
 374     (push newval args)
 375     (push ref args)
 376     (when reason
 377      (push reason args)
 378      (push "-m" args))
 379     (eq 0 (apply #'git-call-process-env nil nil "update-ref" args))))
 380
 381 (defun git-read-tree (tree &optional index-file)
 382   "Read a tree into the index file."
 383   (apply #'git-call-process-env nil
 384          (if index-file `(("GIT_INDEX_FILE" . ,index-file)) nil)
 385          "read-tree" (if tree (list tree))))
 386
 387 (defun git-write-tree (&optional index-file)
 388   "Call git-write-tree and return the resulting tree SHA1 as a string."
 389   (git-get-string-sha1
 390    (git-call-process-env-string (and index-file `(("GIT_INDEX_FILE" . ,index-file))) "write-tree")))
 391
 392 (defun git-commit-tree (buffer tree head)
 393   "Call git-commit-tree with buffer as input and return the resulting commit SHA1."
 394   (let ((author-name (git-get-committer-name))
 395         (author-email (git-get-committer-email))
 396         (subject "commit (initial): ")
 397         author-date log-start log-end args coding-system-for-write)
 398     (when head
 399       (setq subject "commit: ")
 400       (push "-p" args)
 401       (push head args))
 402     (with-current-buffer buffer
 403       (goto-char (point-min))
 404       (if
 405           (setq log-start (re-search-forward (concat "^" (regexp-quote git-log-msg-separator) "\n") nil t))
 406           (save-restriction
 407             (narrow-to-region (point-min) log-start)
 408             (goto-char (point-min))
 409             (when (re-search-forward "^Author: +\\(.*?\\) *<\\(.*\\)> *$" nil t)
 410               (setq author-name (match-string 1)
 411                     author-email (match-string 2)))
 412             (goto-char (point-min))
 413             (when (re-search-forward "^Date: +\\(.*\\)$" nil t)
 414               (setq author-date (match-string 1)))
 415             (goto-char (point-min))
 416             (while (re-search-forward "^Parent: +\\([0-9a-f]+\\)" nil t)
 417               (unless (string-equal head (match-string 1))
 418                 (setq subject "commit (merge): ")
 419                 (push "-p" args)
 420                 (push (match-string 1) args))))
 421         (setq log-start (point-min)))
 422       (setq log-end (point-max))
 423       (goto-char log-start)
 424       (when (re-search-forward ".*$" nil t)
 425         (setq subject (concat subject (match-string 0))))
 426       (setq coding-system-for-write buffer-file-coding-system))
 427     (let ((commit
 428            (git-get-string-sha1
 429             (with-output-to-string
 430               (with-current-buffer standard-output
 431                 (let ((env `(("GIT_AUTHOR_NAME" . ,author-name)
 432                              ("GIT_AUTHOR_EMAIL" . ,author-email)
 433                              ("GIT_COMMITTER_NAME" . ,(git-get-committer-name))
 434                              ("GIT_COMMITTER_EMAIL" . ,(git-get-committer-email)))))
 435                   (when author-date (push `("GIT_AUTHOR_DATE" . ,author-date) env))
 436                   (apply #'git-run-command-region
 437                          buffer log-start log-end env
 438                          "commit-tree" tree (nreverse args))))))))
 439       (and (git-update-ref "HEAD" commit head subject)
 440            commit))))
 441
 442 (defun git-empty-db-p ()
 443   "Check if the git db is empty (no commit done yet)."
 444   (not (eq 0 (call-process "git" nil nil nil "rev-parse" "--verify" "HEAD"))))
 445
 446 (defun git-get-merge-heads ()
 447   "Retrieve the merge heads from the MERGE_HEAD file if present."
 448   (let (heads)
 449     (when (file-readable-p ".git/MERGE_HEAD")
 450       (with-temp-buffer
 451         (insert-file-contents ".git/MERGE_HEAD" nil nil nil t)
 452         (goto-char (point-min))
 453         (while (re-search-forward "[0-9a-f]\\{40\\}" nil t)
 454           (push (match-string 0) heads))))
 455     (nreverse heads)))
 456
 457 (defun git-get-commit-description (commit)
 458   "Get a one-line description of COMMIT."
 459   (let ((coding-system-for-read (git-get-logoutput-coding-system)))
 460     (let ((descr (git-call-process-env-string nil "log" "--max-count=1" "--pretty=oneline" commit)))
 461       (if (and descr (string-match "\\`\\([0-9a-f]\\{40\\}\\) *\\(.*\\)$" descr))
 462           (concat (substring (match-string 1 descr) 0 10) " - " (match-string 2 descr))
 463         descr))))
 464
 465 ;;;; File info structure
 466 ;;;; ------------------------------------------------------------
 467
 468 ; fileinfo structure stolen from pcl-cvs
 469 (defstruct (git-fileinfo
 470             (:copier nil)
 471             (:constructor git-create-fileinfo (state name &optional old-perm new-perm rename-state orig-name marked))
 472             (:conc-name git-fileinfo->))
 473   marked              ;; t/nil
 474   state               ;; current state
 475   name                ;; file name
 476   old-perm new-perm   ;; permission flags
 477   rename-state        ;; rename or copy state
 478   orig-name           ;; original name for renames or copies
 479   needs-refresh)      ;; whether file needs to be refreshed
 480
 481 (defvar git-status nil)
 482
 483 (defun git-clear-status (status)
 484   "Remove everything from the status list."
 485   (ewoc-filter status (lambda (info) nil)))
 486
 487 (defun git-set-fileinfo-state (info state)
 488   "Set the state of a file info."
 489   (unless (eq (git-fileinfo->state info) state)
 490     (setf (git-fileinfo->state info) state
 491           (git-fileinfo->old-perm info) 0
 492           (git-fileinfo->new-perm info) 0
 493           (git-fileinfo->rename-state info) nil
 494           (git-fileinfo->orig-name info) nil
 495           (git-fileinfo->needs-refresh info) t)))
 496
 497 (defun git-status-filenames-map (status func files &rest args)
 498   "Apply FUNC to the status files names in the FILES list."
 499   (when files
 500     (setq files (sort files #'string-lessp))
 501     (let ((file (pop files))
 502           (node (ewoc-nth status 0)))
 503       (while (and file node)
 504         (let ((info (ewoc-data node)))
 505           (if (string-lessp (git-fileinfo->name info) file)
 506               (setq node (ewoc-next status node))
 507             (if (string-equal (git-fileinfo->name info) file)
 508                 (apply func info args))
 509             (setq file (pop files))))))))
 510
 511 (defun git-set-filenames-state (status files state)
 512   "Set the state of a list of named files."
 513   (when files
 514     (git-status-filenames-map status #'git-set-fileinfo-state files state)
 515     (unless state  ;; delete files whose state has been set to nil
 516       (ewoc-filter status (lambda (info) (git-fileinfo->state info))))))
 517
 518 (defun git-state-code (code)
 519   "Convert from a string to a added/deleted/modified state."
 520   (case (string-to-char code)
 521     (?M 'modified)
 522     (?? 'unknown)
 523     (?A 'added)
 524     (?D 'deleted)
 525     (?U 'unmerged)
 526     (t nil)))
 527
 528 (defun git-status-code-as-string (code)
 529   "Format a git status code as string."
 530   (case code
 531     ('modified (propertize "Modified" 'face 'git-status-face))
 532     ('unknown  (propertize "Unknown " 'face 'git-unknown-face))
 533     ('added    (propertize "Added   " 'face 'git-status-face))
 534     ('deleted  (propertize "Deleted " 'face 'git-status-face))
 535     ('unmerged (propertize "Unmerged" 'face 'git-unmerged-face))
 536     ('uptodate (propertize "Uptodate" 'face 'git-uptodate-face))
 537     ('ignored  (propertize "Ignored " 'face 'git-ignored-face))
 538     (t "?       ")))
 539
 540 (defun git-rename-as-string (info)
 541   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 542   (let ((state (git-fileinfo->rename-state info)))
 543     (if state
 544         (propertize
 545          (concat "   ("
 546                  (if (eq state 'copy) "copied from "
 547                    (if (eq (git-fileinfo->state info) 'added) "renamed from "
 548                      "renamed to "))
 549                  (git-escape-file-name (git-fileinfo->orig-name info))
 550                  ")") 'face 'git-status-face)
 551       "")))
 552
 553 (defun git-permissions-as-string (old-perm new-perm)
 554   "Format a permission change as string."
 555   (propertize
 556    (if (or (not old-perm)
 557            (not new-perm)
 558            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 559        "  "
 560      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 561   'face 'git-permission-face))
 562
 563 (defun git-fileinfo-prettyprint (info)
 564   "Pretty-printer for the git-fileinfo structure."
 565   (insert (concat "   " (if (git-fileinfo->marked info) (propertize "*" 'face 'git-mark-face) " ")
 566                   " " (git-status-code-as-string (git-fileinfo->state info))
 567                   " " (git-permissions-as-string (git-fileinfo->old-perm info) (git-fileinfo->new-perm info))
 568                   "  " (git-escape-file-name (git-fileinfo->name info))
 569                   (git-rename-as-string info))))
 570
 571 (defun git-insert-info-list (status infolist)
 572   "Insert a list of file infos in the status buffer, replacing existing ones if any."
 573   (setq infolist (sort infolist
 574                        (lambda (info1 info2)
 575                          (string-lessp (git-fileinfo->name info1)
 576                                        (git-fileinfo->name info2)))))
 577   (let ((info (pop infolist))
 578         (node (ewoc-nth status 0)))
 579     (while info
 580       (setf (git-fileinfo->needs-refresh info) t)
 581       (cond ((not node)
 582              (ewoc-enter-last status info)
 583              (setq info (pop infolist)))
 584             ((string-lessp (git-fileinfo->name (ewoc-data node))
 585                            (git-fileinfo->name info))
 586              (setq node (ewoc-next status node)))
 587             ((string-equal (git-fileinfo->name (ewoc-data node))
 588                            (git-fileinfo->name info))
 589               ;; preserve the marked flag
 590               (setf (git-fileinfo->marked info) (git-fileinfo->marked (ewoc-data node)))
 591               (setf (ewoc-data node) info)
 592               (setq info (pop infolist)))
 593             (t
 594              (ewoc-enter-before status node info)
 595              (setq info (pop infolist)))))))
 596
 597 (defun git-run-diff-index (status files)
 598   "Run git-diff-index on FILES and parse the results into STATUS.
 599 Return the list of files that haven't been handled."
 600   (let (infolist)
 601     (with-temp-buffer
 602       (apply #'git-call-process-env t nil "diff-index" "-z" "-M" "HEAD" "--" files)
 603       (goto-char (point-min))
 604       (while (re-search-forward
 605               ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMU]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 606               nil t 1)
 607         (let ((old-perm (string-to-number (match-string 1) 8))
 608               (new-perm (string-to-number (match-string 2) 8))
 609               (state (or (match-string 4) (match-string 6)))
 610               (name (or (match-string 5) (match-string 7)))
 611               (new-name (match-string 8)))
 612           (if new-name  ; copy or rename
 613               (if (eq ?C (string-to-char state))
 614                   (push (git-create-fileinfo 'added new-name old-perm new-perm 'copy name) infolist)
 615                 (push (git-create-fileinfo 'deleted name 0 0 'rename new-name) infolist)
 616                 (push (git-create-fileinfo 'added new-name old-perm new-perm 'rename name) infolist))
 617             (push (git-create-fileinfo (git-state-code state) name old-perm new-perm) infolist))
 618           (setq files (delete name files))
 619           (when new-name (setq files (delete new-name files))))))
 620     (git-insert-info-list status infolist)
 621     files))
 622
 623 (defun git-find-status-file (status file)
 624   "Find a given file in the status ewoc and return its node."
 625   (let ((node (ewoc-nth status 0)))
 626     (while (and node (not (string= file (git-fileinfo->name (ewoc-data node)))))
 627       (setq node (ewoc-next status node)))
 628     node))
 629
 630 (defun git-run-ls-files (status files default-state &rest options)
 631   "Run git-ls-files on FILES and parse the results into STATUS.
 632 Return the list of files that haven't been handled."
 633   (let (infolist)
 634     (with-temp-buffer
 635       (apply #'git-call-process-env t nil "ls-files" "-z" (append options (list "--") files))
 636       (goto-char (point-min))
 637       (while (re-search-forward "\\([^\0]*\\)\0" nil t 1)
 638         (let ((name (match-string 1)))
 639           (push (git-create-fileinfo default-state name) infolist)
 640           (setq files (delete name files)))))
 641     (git-insert-info-list status infolist)
 642     files))
 643
 644 (defun git-run-ls-unmerged (status files)
 645   "Run git-ls-files -u on FILES and parse the results into STATUS."
 646   (with-temp-buffer
 647     (apply #'git-call-process-env t nil "ls-files" "-z" "-u" "--" files)
 648     (goto-char (point-min))
 649     (let (unmerged-files)
 650       (while (re-search-forward "[0-7]\\{6\\} [0-9a-f]\\{40\\} [123]\t\\([^\0]+\\)\0" nil t)
 651         (push (match-string 1) unmerged-files))
 652       (git-set-filenames-state status unmerged-files 'unmerged))))
 653
 654 (defun git-get-exclude-files ()
 655   "Get the list of exclude files to pass to git-ls-files."
 656   (let (files
 657         (config (git-config "core.excludesfile")))
 658     (when (file-readable-p ".git/info/exclude")
 659       (push ".git/info/exclude" files))
 660     (when (and config (file-readable-p config))
 661       (push config files))
 662     files))
 663
 664 (defun git-run-ls-files-with-excludes (status files default-state &rest options)
 665   "Run git-ls-files on FILES with appropriate --exclude-from options."
 666   (let ((exclude-files (git-get-exclude-files)))
 667     (apply #'git-run-ls-files status files default-state
 668            (concat "--exclude-per-directory=" git-per-dir-ignore-file)
 669            (append options (mapcar (lambda (f) (concat "--exclude-from=" f)) exclude-files)))))
 670
 671 (defun git-update-status-files (files &optional default-state)
 672   "Update the status of FILES from the index."
 673   (unless git-status (error "Not in git-status buffer."))
 674   (unless files
 675     (when git-show-uptodate (git-run-ls-files git-status nil 'uptodate "-c")))
 676   (let* ((remaining-files
 677           (if (git-empty-db-p) ; we need some special handling for an empty db
 678               (git-run-ls-files git-status files 'added "-c")
 679             (git-run-diff-index git-status files))))
 680     (git-run-ls-unmerged git-status files)
 681     (when (or remaining-files (and git-show-unknown (not files)))
 682       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'unknown "-o")))
 683     (when (or remaining-files (and git-show-ignored (not files)))
 684       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'ignored "-o" "-i")))
 685     (git-set-filenames-state git-status remaining-files default-state)
 686     (git-refresh-files)
 687     (git-refresh-ewoc-hf git-status)))
 688
 689 (defun git-marked-files ()
 690   "Return a list of all marked files, or if none a list containing just the file at cursor position."
 691   (unless git-status (error "Not in git-status buffer."))
 692   (or (ewoc-collect git-status (lambda (info) (git-fileinfo->marked info)))
 693       (list (ewoc-data (ewoc-locate git-status)))))
 694
 695 (defun git-marked-files-state (&rest states)
 696   "Return marked files that are in the specified states."
 697   (let ((files (git-marked-files))
 698         result)
 699     (dolist (info files)
 700       (when (memq (git-fileinfo->state info) states)
 701         (push info result)))
 702     result))
 703
 704 (defun git-refresh-files ()
 705   "Refresh all files that need it and clear the needs-refresh flag."
 706   (unless git-status (error "Not in git-status buffer."))
 707   (ewoc-map
 708    (lambda (info)
 709      (let ((refresh (git-fileinfo->needs-refresh info)))
 710        (setf (git-fileinfo->needs-refresh info) nil)
 711        refresh))
 712    git-status)
 713   ; move back to goal column
 714   (when goal-column (move-to-column goal-column)))
 715
 716 (defun git-refresh-ewoc-hf (status)
 717   "Refresh the ewoc header and footer."
 718   (let ((branch (git-symbolic-ref "HEAD"))
 719         (head (if (git-empty-db-p) "Nothing committed yet"
 720                 (git-get-commit-description "HEAD")))
 721         (merge-heads (git-get-merge-heads)))
 722     (ewoc-set-hf status
 723                  (format "Directory:  %s\nBranch:     %s\nHead:       %s%s\n"
 724                          default-directory
 725                          (if branch
 726                              (if (string-match "^refs/heads/" branch)
 727                                  (substring branch (match-end 0))
 728                                branch)
 729                            "none (detached HEAD)")
 730                          head
 731                          (if merge-heads
 732                              (concat "\nMerging:    "
 733                                      (mapconcat (lambda (str) (git-get-commit-description str)) merge-heads "\n            "))
 734                            ""))
 735                  (if (ewoc-nth status 0) "" "    No changes."))))
 736
 737 (defun git-get-filenames (files)
 738   (mapcar (lambda (info) (git-fileinfo->name info)) files))
 739
 740 (defun git-update-index (index-file files)
 741   "Run git-update-index on a list of files."
 742   (let ((env (and index-file `(("GIT_INDEX_FILE" . ,index-file))))
 743         added deleted modified)
 744     (dolist (info files)
 745       (case (git-fileinfo->state info)
 746         ('added (push info added))
 747         ('deleted (push info deleted))
 748         ('modified (push info modified))))
 749     (when added
 750       (apply #'git-call-process-env nil env "update-index" "--add" "--" (git-get-filenames added)))
 751     (when deleted
 752       (apply #'git-call-process-env nil env "update-index" "--remove" "--" (git-get-filenames deleted)))
 753     (when modified
 754       (apply #'git-call-process-env nil env "update-index" "--" (git-get-filenames modified)))))
 755
 756 (defun git-run-pre-commit-hook ()
 757   "Run the pre-commit hook if any."
 758   (unless git-status (error "Not in git-status buffer."))
 759   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
 760     (or (not files)
 761         (not (file-executable-p ".git/hooks/pre-commit"))
 762         (let ((index-file (make-temp-file "gitidx")))
 763           (unwind-protect
 764             (let ((head-tree (unless (git-empty-db-p) (git-rev-parse "HEAD^{tree}"))))
 765               (git-read-tree head-tree index-file)
 766               (git-update-index index-file files)
 767               (git-run-hook "pre-commit" `(("GIT_INDEX_FILE" . ,index-file))))
 768           (delete-file index-file))))))
 769
 770 (defun git-do-commit ()
 771   "Perform the actual commit using the current buffer as log message."
 772   (interactive)
 773   (let ((buffer (current-buffer))
 774         (index-file (make-temp-file "gitidx")))
 775     (with-current-buffer log-edit-parent-buffer
 776       (if (git-marked-files-state 'unmerged)
 777           (message "You cannot commit unmerged files, resolve them first.")
 778         (unwind-protect
 779             (let ((files (git-marked-files-state 'added 'deleted 'modified))
 780                   head head-tree)
 781               (unless (git-empty-db-p)
 782                 (setq head (git-rev-parse "HEAD")
 783                       head-tree (git-rev-parse "HEAD^{tree}")))
 784               (if files
 785                   (progn
 786                     (message "Running git commit...")
 787                     (git-read-tree head-tree index-file)
 788                     (git-update-index nil files)         ;update both the default index
 789                     (git-update-index index-file files)  ;and the temporary one
 790                     (let ((tree (git-write-tree index-file)))
 791                       (if (or (not (string-equal tree head-tree))
 792                               (yes-or-no-p "The tree was not modified, do you really want to perform an empty commit? "))
 793                           (let ((commit (git-commit-tree buffer tree head)))
 794                             (condition-case nil (delete-file ".git/MERGE_HEAD") (error nil))
 795                             (condition-case nil (delete-file ".git/MERGE_MSG") (error nil))
 796                             (with-current-buffer buffer (erase-buffer))
 797                             (dolist (info files) (git-set-fileinfo-state info 'uptodate))
 798                             (git-call-process-env nil nil "rerere")
 799                             (git-refresh-files)
 800                             (git-refresh-ewoc-hf git-status)
 801                             (message "Committed %s." commit)
 802                             (git-run-hook "post-commit" nil))
 803                         (message "Commit aborted."))))
 804                 (message "No files to commit.")))
 805           (delete-file index-file))))))
 806
 807
 808 ;;;; Interactive functions
 809 ;;;; ------------------------------------------------------------
 810
 811 (defun git-mark-file ()
 812   "Mark the file that the cursor is on and move to the next one."
 813   (interactive)
 814   (unless git-status (error "Not in git-status buffer."))
 815   (let* ((pos (ewoc-locate git-status))
 816          (info (ewoc-data pos)))
 817     (setf (git-fileinfo->marked info) t)
 818     (ewoc-invalidate git-status pos)
 819     (ewoc-goto-next git-status 1)))
 820
 821 (defun git-unmark-file ()
 822   "Unmark the file that the cursor is on and move to the next one."
 823   (interactive)
 824   (unless git-status (error "Not in git-status buffer."))
 825   (let* ((pos (ewoc-locate git-status))
 826          (info (ewoc-data pos)))
 827     (setf (git-fileinfo->marked info) nil)
 828     (ewoc-invalidate git-status pos)
 829     (ewoc-goto-next git-status 1)))
 830
 831 (defun git-unmark-file-up ()
 832   "Unmark the file that the cursor is on and move to the previous one."
 833   (interactive)
 834   (unless git-status (error "Not in git-status buffer."))
 835   (let* ((pos (ewoc-locate git-status))
 836          (info (ewoc-data pos)))
 837     (setf (git-fileinfo->marked info) nil)
 838     (ewoc-invalidate git-status pos)
 839     (ewoc-goto-prev git-status 1)))
 840
 841 (defun git-mark-all ()
 842   "Mark all files."
 843   (interactive)
 844   (unless git-status (error "Not in git-status buffer."))
 845   (ewoc-map (lambda (info) (unless (git-fileinfo->marked info)
 846                              (setf (git-fileinfo->marked info) t))) git-status)
 847   ; move back to goal column after invalidate
 848   (when goal-column (move-to-column goal-column)))
 849
 850 (defun git-unmark-all ()
 851   "Unmark all files."
 852   (interactive)
 853   (unless git-status (error "Not in git-status buffer."))
 854   (ewoc-map (lambda (info) (when (git-fileinfo->marked info)
 855                              (setf (git-fileinfo->marked info) nil)
 856                              t)) git-status)
 857   ; move back to goal column after invalidate
 858   (when goal-column (move-to-column goal-column)))
 859
 860 (defun git-toggle-all-marks ()
 861   "Toggle all file marks."
 862   (interactive)
 863   (unless git-status (error "Not in git-status buffer."))
 864   (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) (not (git-fileinfo->marked info))) t) git-status)
 865   ; move back to goal column after invalidate
 866   (when goal-column (move-to-column goal-column)))
 867
 868 (defun git-next-file (&optional n)
 869   "Move the selection down N files."
 870   (interactive "p")
 871   (unless git-status (error "Not in git-status buffer."))
 872   (ewoc-goto-next git-status n))
 873
 874 (defun git-prev-file (&optional n)
 875   "Move the selection up N files."
 876   (interactive "p")
 877   (unless git-status (error "Not in git-status buffer."))
 878   (ewoc-goto-prev git-status n))
 879
 880 (defun git-next-unmerged-file (&optional n)
 881   "Move the selection down N unmerged files."
 882   (interactive "p")
 883   (unless git-status (error "Not in git-status buffer."))
 884   (let* ((last (ewoc-locate git-status))
 885          (node (ewoc-next git-status last)))
 886     (while (and node (> n 0))
 887       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 888         (setq n (1- n))
 889         (setq last node))
 890       (setq node (ewoc-next git-status node)))
 891     (ewoc-goto-node git-status last)))
 892
 893 (defun git-prev-unmerged-file (&optional n)
 894   "Move the selection up N unmerged files."
 895   (interactive "p")
 896   (unless git-status (error "Not in git-status buffer."))
 897   (let* ((last (ewoc-locate git-status))
 898          (node (ewoc-prev git-status last)))
 899     (while (and node (> n 0))
 900       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 901         (setq n (1- n))
 902         (setq last node))
 903       (setq node (ewoc-prev git-status node)))
 904     (ewoc-goto-node git-status last)))
 905
 906 (defun git-add-file ()
 907   "Add marked file(s) to the index cache."
 908   (interactive)
 909   (let ((files (git-get-filenames (git-marked-files-state 'unknown 'ignored))))
 910     (unless files
 911       (push (file-relative-name (read-file-name "File to add: " nil nil t)) files))
 912     (apply #'git-call-process-env nil nil "update-index" "--add" "--" files)
 913     (git-update-status-files files 'uptodate)
 914     (git-success-message "Added" files)))
 915
 916 (defun git-ignore-file ()
 917   "Add marked file(s) to the ignore list."
 918   (interactive)
 919   (let ((files (git-get-filenames (git-marked-files-state 'unknown))))
 920     (unless files
 921       (push (file-relative-name (read-file-name "File to ignore: " nil nil t)) files))
 922     (dolist (f files) (git-append-to-ignore f))
 923     (git-update-status-files files 'ignored)
 924     (git-success-message "Ignored" files)))
 925
 926 (defun git-remove-file ()
 927   "Remove the marked file(s)."
 928   (interactive)
 929   (let ((files (git-get-filenames (git-marked-files-state 'added 'modified 'unknown 'uptodate 'ignored))))
 930     (unless files
 931       (push (file-relative-name (read-file-name "File to remove: " nil nil t)) files))
 932     (if (yes-or-no-p
 933          (format "Remove %d file%s? " (length files) (if (> (length files) 1) "s" "")))
 934         (progn
 935           (dolist (name files)
 936             (when (file-exists-p name) (delete-file name)))
 937           (apply #'git-call-process-env nil nil "update-index" "--remove" "--" files)
 938           (git-update-status-files files nil)
 939           (git-success-message "Removed" files))
 940       (message "Aborting"))))
 941
 942 (defun git-revert-file ()
 943   "Revert changes to the marked file(s)."
 944   (interactive)
 945   (let ((files (git-marked-files))
 946         added modified)
 947     (when (and files
 948                (yes-or-no-p
 949                 (format "Revert %d file%s? " (length files) (if (> (length files) 1) "s" ""))))
 950       (dolist (info files)
 951         (case (git-fileinfo->state info)
 952           ('added (push (git-fileinfo->name info) added))
 953           ('deleted (push (git-fileinfo->name info) modified))
 954           ('unmerged (push (git-fileinfo->name info) modified))
 955           ('modified (push (git-fileinfo->name info) modified))))
 956       (when added
 957         (apply #'git-call-process-env nil nil "update-index" "--force-remove" "--" added))
 958       (when modified
 959         (apply #'git-call-process-env nil nil "checkout" "HEAD" modified))
 960       (git-update-status-files (append added modified) 'uptodate)
 961       (git-success-message "Reverted" (git-get-filenames files)))))
 962
 963 (defun git-resolve-file ()
 964   "Resolve conflicts in marked file(s)."
 965   (interactive)
 966   (let ((files (git-get-filenames (git-marked-files-state 'unmerged))))
 967     (when files
 968       (apply #'git-call-process-env nil nil "update-index" "--" files)
 969       (git-update-status-files files 'uptodate)
 970       (git-success-message "Resolved" files))))
 971
 972 (defun git-remove-handled ()
 973   "Remove handled files from the status list."
 974   (interactive)
 975   (ewoc-filter git-status
 976                (lambda (info)
 977                  (case (git-fileinfo->state info)
 978                    ('ignored git-show-ignored)
 979                    ('uptodate git-show-uptodate)
 980                    ('unknown git-show-unknown)
 981                    (t t))))
 982   (unless (ewoc-nth git-status 0)  ; refresh header if list is empty
 983     (git-refresh-ewoc-hf git-status)))
 984
 985 (defun git-toggle-show-uptodate ()
 986   "Toogle the option for showing up-to-date files."
 987   (interactive)
 988   (if (setq git-show-uptodate (not git-show-uptodate))
 989       (git-refresh-status)
 990     (git-remove-handled)))
 991
 992 (defun git-toggle-show-ignored ()
 993   "Toogle the option for showing ignored files."
 994   (interactive)
 995   (if (setq git-show-ignored (not git-show-ignored))
 996       (progn
 997         (message "Inserting ignored files...")
 998         (git-run-ls-files-with-excludes git-status nil 'ignored "-o" "-i")
 999         (git-refresh-files)
1000         (git-refresh-ewoc-hf git-status)
1001         (message "Inserting ignored files...done"))
1002     (git-remove-handled)))
1003
1004 (defun git-toggle-show-unknown ()
1005   "Toogle the option for showing unknown files."
1006   (interactive)
1007   (if (setq git-show-unknown (not git-show-unknown))
1008       (progn
1009         (message "Inserting unknown files...")
1010         (git-run-ls-files-with-excludes git-status nil 'unknown "-o")
1011         (git-refresh-files)
1012         (git-refresh-ewoc-hf git-status)
1013         (message "Inserting unknown files...done"))
1014     (git-remove-handled)))
1015
1016 (defun git-setup-diff-buffer (buffer)
1017   "Setup a buffer for displaying a diff."
1018   (let ((dir default-directory))
1019     (with-current-buffer buffer
1020       (diff-mode)
1021       (goto-char (point-min))
1022       (setq default-directory dir)
1023       (setq buffer-read-only t)))
1024   (display-buffer buffer)
1025   (shrink-window-if-larger-than-buffer))
1026
1027 (defun git-diff-file ()
1028   "Diff the marked file(s) against HEAD."
1029   (interactive)
1030   (let ((files (git-marked-files)))
1031     (git-setup-diff-buffer
1032      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M" "HEAD" "--" (git-get-filenames files)))))
1033
1034 (defun git-diff-file-merge-head (arg)
1035   "Diff the marked file(s) against the first merge head (or the nth one with a numeric prefix)."
1036   (interactive "p")
1037   (let ((files (git-marked-files))
1038         (merge-heads (git-get-merge-heads)))
1039     (unless merge-heads (error "No merge in progress"))
1040     (git-setup-diff-buffer
1041      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M"
1042             (or (nth (1- arg) merge-heads) "HEAD") "--" (git-get-filenames files)))))
1043
1044 (defun git-diff-unmerged-file (stage)
1045   "Diff the marked unmerged file(s) against the specified stage."
1046   (let ((files (git-marked-files)))
1047     (git-setup-diff-buffer
1048      (apply #'git-run-command-buffer "*git-diff*" "diff-files" "-p" stage "--" (git-get-filenames files)))))
1049
1050 (defun git-diff-file-base ()
1051   "Diff the marked unmerged file(s) against the common base file."
1052   (interactive)
1053   (git-diff-unmerged-file "-1"))
1054
1055 (defun git-diff-file-mine ()
1056   "Diff the marked unmerged file(s) against my pre-merge version."
1057   (interactive)
1058   (git-diff-unmerged-file "-2"))
1059
1060 (defun git-diff-file-other ()
1061   "Diff the marked unmerged file(s) against the other's pre-merge version."
1062   (interactive)
1063   (git-diff-unmerged-file "-3"))
1064
1065 (defun git-diff-file-combined ()
1066   "Do a combined diff of the marked unmerged file(s)."
1067   (interactive)
1068   (git-diff-unmerged-file "-c"))
1069
1070 (defun git-diff-file-idiff ()
1071   "Perform an interactive diff on the current file."
1072   (interactive)
1073   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
1074     (unless (eq 1 (length files))
1075       (error "Cannot perform an interactive diff on multiple files."))
1076     (let* ((filename (car (git-get-filenames files)))
1077            (buff1 (find-file-noselect filename))
1078            (buff2 (git-run-command-buffer (concat filename ".~HEAD~") "cat-file" "blob" (concat "HEAD:" filename))))
1079       (ediff-buffers buff1 buff2))))
1080
1081 (defun git-log-file ()
1082   "Display a log of changes to the marked file(s)."
1083   (interactive)
1084   (let* ((files (git-marked-files))
1085          (coding-system-for-read git-commits-coding-system)
1086          (buffer (apply #'git-run-command-buffer "*git-log*" "rev-list" "--pretty" "HEAD" "--" (git-get-filenames files))))
1087     (with-current-buffer buffer
1088       ; (git-log-mode)  FIXME: implement log mode
1089       (goto-char (point-min))
1090       (setq buffer-read-only t))
1091     (display-buffer buffer)))
1092
1093 (defun git-log-edit-files ()
1094   "Return a list of marked files for use in the log-edit buffer."
1095   (with-current-buffer log-edit-parent-buffer
1096     (git-get-filenames (git-marked-files-state 'added 'deleted 'modified))))
1097
1098 (defun git-append-sign-off (name email)
1099   "Append a Signed-off-by entry to the current buffer, avoiding duplicates."
1100   (let ((sign-off (format "Signed-off-by: %s <%s>" name email))
1101         (case-fold-search t))
1102     (goto-char (point-min))
1103     (unless (re-search-forward (concat "^" (regexp-quote sign-off)) nil t)
1104       (goto-char (point-min))
1105       (unless (re-search-forward "^Signed-off-by: " nil t)
1106         (setq sign-off (concat "\n" sign-off)))
1107       (goto-char (point-max))
1108       (insert sign-off "\n"))))
1109
1110 (defun git-setup-log-buffer (buffer &optional author-name author-email subject date msg)
1111   "Setup the log buffer for a commit."
1112   (unless git-status (error "Not in git-status buffer."))
1113   (let ((merge-heads (git-get-merge-heads))
1114         (dir default-directory)
1115         (committer-name (git-get-committer-name))
1116         (committer-email (git-get-committer-email))
1117         (sign-off git-append-signed-off-by))
1118     (with-current-buffer buffer
1119       (cd dir)
1120       (erase-buffer)
1121       (insert
1122        (propertize
1123         (format "Author: %s <%s>\n%s%s"
1124                 (or author-name committer-name)
1125                 (or author-email committer-email)
1126                 (if date (format "Date: %s\n" date) "")
1127                 (if merge-heads
1128                     (format "Parent: %s\n%s\n"
1129                             (git-rev-parse "HEAD")
1130                             (mapconcat (lambda (str) (concat "Parent: " str)) merge-heads "\n"))
1131                   ""))
1132         'face 'git-header-face)
1133        (propertize git-log-msg-separator 'face 'git-separator-face)
1134        "\n")
1135       (when subject (insert subject "\n\n"))
1136       (cond (msg (insert msg "\n"))
1137             ((file-readable-p ".dotest/msg")
1138              (insert-file-contents ".dotest/msg"))
1139             ((file-readable-p ".git/MERGE_MSG")
1140              (insert-file-contents ".git/MERGE_MSG")))
1141       ; delete empty lines at end
1142       (goto-char (point-min))
1143       (when (re-search-forward "\n+\\'" nil t)
1144         (replace-match "\n" t t))
1145       (when sign-off (git-append-sign-off committer-name committer-email)))))
1146
1147 (defun git-commit-file ()
1148   "Commit the marked file(s), asking for a commit message."
1149   (interactive)
1150   (unless git-status (error "Not in git-status buffer."))
1151   (when (git-run-pre-commit-hook)
1152     (let ((buffer (get-buffer-create "*git-commit*"))
1153           (coding-system (git-get-commits-coding-system))
1154           author-name author-email subject date)
1155       (when (eq 0 (buffer-size buffer))
1156         (when (file-readable-p ".dotest/info")
1157           (with-temp-buffer
1158             (insert-file-contents ".dotest/info")
1159             (goto-char (point-min))
1160             (when (re-search-forward "^Author: \\(.*\\)\nEmail: \\(.*\\)$" nil t)
1161               (setq author-name (match-string 1))
1162               (setq author-email (match-string 2)))
1163             (goto-char (point-min))
1164             (when (re-search-forward "^Subject: \\(.*\\)$" nil t)
1165               (setq subject (match-string 1)))
1166             (goto-char (point-min))
1167             (when (re-search-forward "^Date: \\(.*\\)$" nil t)
1168               (setq date (match-string 1)))))
1169         (git-setup-log-buffer buffer author-name author-email subject date))
1170       (log-edit #'git-do-commit nil #'git-log-edit-files buffer)
1171       (setq font-lock-keywords (font-lock-compile-keywords git-log-edit-font-lock-keywords))
1172       (setq buffer-file-coding-system coding-system)
1173       (re-search-forward (regexp-quote (concat git-log-msg-separator "\n")) nil t))))
1174
1175 (defun git-find-file ()
1176   "Visit the current file in its own buffer."
1177   (interactive)
1178   (unless git-status (error "Not in git-status buffer."))
1179   (let ((info (ewoc-data (ewoc-locate git-status))))
1180     (find-file (git-fileinfo->name info))
1181     (when (eq 'unmerged (git-fileinfo->state info))
1182       (smerge-mode 1))))
1183
1184 (defun git-find-file-other-window ()
1185   "Visit the current file in its own buffer in another window."
1186   (interactive)
1187   (unless git-status (error "Not in git-status buffer."))
1188   (let ((info (ewoc-data (ewoc-locate git-status))))
1189     (find-file-other-window (git-fileinfo->name info))
1190     (when (eq 'unmerged (git-fileinfo->state info))
1191       (smerge-mode))))
1192
1193 (defun git-find-file-imerge ()
1194   "Visit the current file in interactive merge mode."
1195   (interactive)
1196   (unless git-status (error "Not in git-status buffer."))
1197   (let ((info (ewoc-data (ewoc-locate git-status))))
1198     (find-file (git-fileinfo->name info))
1199     (smerge-ediff)))
1200
1201 (defun git-view-file ()
1202   "View the current file in its own buffer."
1203   (interactive)
1204   (unless git-status (error "Not in git-status buffer."))
1205   (let ((info (ewoc-data (ewoc-locate git-status))))
1206     (view-file (git-fileinfo->name info))))
1207
1208 (defun git-refresh-status ()
1209   "Refresh the git status buffer."
1210   (interactive)
1211   (let* ((status git-status)
1212          (pos (ewoc-locate status))
1213          (marked-files (git-get-filenames (ewoc-collect status (lambda (info) (git-fileinfo->marked info)))))
1214          (cur-name (and pos (git-fileinfo->name (ewoc-data pos)))))
1215     (unless status (error "Not in git-status buffer."))
1216     (message "Refreshing git status...")
1217     (git-call-process-env nil nil "update-index" "--refresh")
1218     (git-clear-status status)
1219     (git-update-status-files nil)
1220     ; restore file marks
1221     (when marked-files
1222       (git-status-filenames-map status
1223                                 (lambda (info)
1224                                         (setf (git-fileinfo->marked info) t)
1225                                         (setf (git-fileinfo->needs-refresh info) t))
1226                                 marked-files)
1227       (git-refresh-files))
1228     ; move point to the current file name if any
1229     (message "Refreshing git status...done")
1230     (let ((node (and cur-name (git-find-status-file status cur-name))))
1231       (when node (ewoc-goto-node status node)))))
1232
1233 (defun git-status-quit ()
1234   "Quit git-status mode."
1235   (interactive)
1236   (bury-buffer))
1237
1238 ;;;; Major Mode
1239 ;;;; ------------------------------------------------------------
1240
1241 (defvar git-status-mode-hook nil
1242   "Run after `git-status-mode' is setup.")
1243
1244 (defvar git-status-mode-map nil
1245   "Keymap for git major mode.")
1246
1247 (defvar git-status nil
1248   "List of all files managed by the git-status mode.")
1249
1250 (unless git-status-mode-map
1251   (let ((map (make-keymap))
1252         (diff-map (make-sparse-keymap))
1253         (toggle-map (make-sparse-keymap)))
1254     (suppress-keymap map)
1255     (define-key map "?"   'git-help)
1256     (define-key map "h"   'git-help)
1257     (define-key map " "   'git-next-file)
1258     (define-key map "a"   'git-add-file)
1259     (define-key map "c"   'git-commit-file)
1260     (define-key map "d"    diff-map)
1261     (define-key map "="   'git-diff-file)
1262     (define-key map "f"   'git-find-file)
1263     (define-key map "\r"  'git-find-file)
1264     (define-key map "g"   'git-refresh-status)
1265     (define-key map "i"   'git-ignore-file)
1266     (define-key map "l"   'git-log-file)
1267     (define-key map "m"   'git-mark-file)
1268     (define-key map "M"   'git-mark-all)
1269     (define-key map "n"   'git-next-file)
1270     (define-key map "N"   'git-next-unmerged-file)
1271     (define-key map "o"   'git-find-file-other-window)
1272     (define-key map "p"   'git-prev-file)
1273     (define-key map "P"   'git-prev-unmerged-file)
1274     (define-key map "q"   'git-status-quit)
1275     (define-key map "r"   'git-remove-file)
1276     (define-key map "R"   'git-resolve-file)
1277     (define-key map "t"    toggle-map)
1278     (define-key map "T"   'git-toggle-all-marks)
1279     (define-key map "u"   'git-unmark-file)
1280     (define-key map "U"   'git-revert-file)
1281     (define-key map "v"   'git-view-file)
1282     (define-key map "x"   'git-remove-handled)
1283     (define-key map "\C-?" 'git-unmark-file-up)
1284     (define-key map "\M-\C-?" 'git-unmark-all)
1285     ; the diff submap
1286     (define-key diff-map "b" 'git-diff-file-base)
1287     (define-key diff-map "c" 'git-diff-file-combined)
1288     (define-key diff-map "=" 'git-diff-file)
1289     (define-key diff-map "e" 'git-diff-file-idiff)
1290     (define-key diff-map "E" 'git-find-file-imerge)
1291     (define-key diff-map "h" 'git-diff-file-merge-head)
1292     (define-key diff-map "m" 'git-diff-file-mine)
1293     (define-key diff-map "o" 'git-diff-file-other)
1294     ; the toggle submap
1295     (define-key toggle-map "u" 'git-toggle-show-uptodate)
1296     (define-key toggle-map "i" 'git-toggle-show-ignored)
1297     (define-key toggle-map "k" 'git-toggle-show-unknown)
1298     (define-key toggle-map "m" 'git-toggle-all-marks)
1299     (setq git-status-mode-map map)))
1300
1301 ;; git mode should only run in the *git status* buffer
1302 (put 'git-status-mode 'mode-class 'special)
1303
1304 (defun git-status-mode ()
1305   "Major mode for interacting with Git.
1306 Commands:
1307 \\{git-status-mode-map}"
1308   (kill-all-local-variables)
1309   (buffer-disable-undo)
1310   (setq mode-name "git status"
1311         major-mode 'git-status-mode
1312         goal-column 17
1313         buffer-read-only t)
1314   (use-local-map git-status-mode-map)
1315   (let ((buffer-read-only nil))
1316     (erase-buffer)
1317   (let ((status (ewoc-create 'git-fileinfo-prettyprint "" "")))
1318     (set (make-local-variable 'git-status) status))
1319   (set (make-local-variable 'list-buffers-directory) default-directory)
1320   (make-local-variable 'git-show-uptodate)
1321   (make-local-variable 'git-show-ignored)
1322   (make-local-variable 'git-show-unknown)
1323   (run-hooks 'git-status-mode-hook)))
1324
1325 (defun git-find-status-buffer (dir)
1326   "Find the git status buffer handling a specified directory."
1327   (let ((list (buffer-list))
1328         (fulldir (expand-file-name dir))
1329         found)
1330     (while (and list (not found))
1331       (let ((buffer (car list)))
1332         (with-current-buffer buffer
1333           (when (and list-buffers-directory
1334                      (string-equal fulldir (expand-file-name list-buffers-directory))
1335                      (string-match "\\*git-status\\*$" (buffer-name buffer)))
1336             (setq found buffer))))
1337       (setq list (cdr list)))
1338     found))
1339
1340 (defun git-status (dir)
1341   "Entry point into git-status mode."
1342   (interactive "DSelect directory: ")
1343   (setq dir (git-get-top-dir dir))
1344   (if (file-directory-p (concat (file-name-as-directory dir) ".git"))
1345       (let ((buffer (or (and git-reuse-status-buffer (git-find-status-buffer dir))
1346                         (create-file-buffer (expand-file-name "*git-status*" dir)))))
1347         (switch-to-buffer buffer)
1348         (cd dir)
1349         (git-status-mode)
1350         (git-refresh-status)
1351         (goto-char (point-min))
1352         (add-hook 'after-save-hook 'git-update-saved-file))
1353     (message "%s is not a git working tree." dir)))
1354
1355 (defun git-update-saved-file ()
1356   "Update the corresponding git-status buffer when a file is saved.
1357 Meant to be used in `after-save-hook'."
1358   (let* ((file (expand-file-name buffer-file-name))
1359          (dir (condition-case nil (git-get-top-dir (file-name-directory file)) (error nil)))
1360          (buffer (and dir (git-find-status-buffer dir))))
1361     (when buffer
1362       (with-current-buffer buffer
1363         (let ((filename (file-relative-name file dir)))
1364           ; skip files located inside the .git directory
1365           (unless (string-match "^\\.git/" filename)
1366             (git-call-process-env nil nil "add" "--refresh" "--" filename)
1367             (git-update-status-files (list filename) 'uptodate)))))))
1368
1369 (defun git-help ()
1370   "Display help for Git mode."
1371   (interactive)
1372   (describe-function 'git-status-mode))
1373
1374 (provide 'git)
1375 ;;; git.el ends here