tests/meson.build

   1 sources = files(
   2   'dconf-mock-dbus.c',
   3   'dconf-mock-gvdb.c',
   4   'dconf-mock-shm.c'
   5 )
   6
   7 libdconf_mock = static_library(
   8   meson.project_name() + '-mock',
   9   sources: sources,
  10   dependencies: glib_dep
  11 )
  12
  13 envs = test_env + [
  14   'G_TEST_SRCDIR=' + meson.current_source_dir(),
  15   'G_TEST_BUILDDIR=' + meson.current_build_dir(),
  16 ]
  17
  18 test_dir = meson.current_source_dir()
  19
  20 dl_dep = cc.find_library('dl', required: false)
  21 m_dep = cc.find_library('m')
  22
  23 unit_tests = [
  24   # [name, sources, c_args, dependencies, link_with]
  25   ['paths', 'paths.c', [], glib_dep, libdconf_common],
  26   ['changeset', 'changeset.c', [], glib_dep, libdconf_common],
  27   ['shm', ['shm.c', 'tmpdir.c'], [], [glib_dep, dl_dep], libdconf_shm],
  28   ['gvdb', 'gvdb.c', '-DSRCDIR="@0@"'.format(test_dir), glib_dep, libgvdb],
  29   ['gdbus-thread', 'dbus.c', '-DDBUS_BACKEND="/gdbus/thread"', gio_unix_dep, libdconf_gdbus_thread],
  30   ['gdbus-filter', 'dbus.c', '-DDBUS_BACKEND="/gdbus/filter"', gio_unix_dep, libdconf_gdbus_filter],
  31   ['engine', 'engine.c', '-DSRCDIR="@0@"'.format(test_dir), [glib_dep, dl_dep, m_dep], [libdconf_engine, libdconf_common, libdconf_mock]],
  32   ['client', 'client.c', '-DSRCDIR="@0@"'.format(test_dir), gio_unix_dep, [libdconf_client, libdconf_engine, libdconf_common, libdconf_mock]]
  33 ]
  34
  35 foreach unit_test: unit_tests
  36   exe = executable(
  37     unit_test[0],
  38     unit_test[1],
  39     c_args: unit_test[2],
  40     dependencies: unit_test[3],
  41     link_with: unit_test[4]
  42   )
  43
  44   test(unit_test[0], exe, is_parallel: false, env: envs)
  45 endforeach