arch/arm/vmlinux-armo.lds.in

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5 OUTPUT_ARCH(arm)
   6 ENTRY(stext)
   7 SECTIONS
   8 {
   9         . = TEXTADDR;
  10
  11         .init : {
  12                 __init_begin = .;       /* Init code and data           */
  13                         *(.text.init)
  14                 __proc_info_begin = .;
  15                         *(.proc.info)
  16                 __proc_info_end = .;
  17                 __arch_info_begin = .;
  18                         *(.arch.info)
  19                 __arch_info_end = .;
  20                         *(.data.init)
  21                 . = ALIGN(16);
  22                 __setup_start = .;
  23                         *(.setup.init)
  24                 __setup_end = .;
  25                 __initcall_start = .;
  26                         *(.initcall.init)
  27                 __initcall_end = .;
  28                 . = ALIGN(32768);
  29                 __init_end = .;
  30         }
  31
  32         .init.task : {
  33                 *(.init.task)
  34         }
  35
  36         /DISCARD/ : {                   /* Exit code and data           */
  37                 *(.text.exit)
  38                 *(.data.exit)
  39         }
  40
  41         .text : {
  42                 _text = .;              /* Text and read-only data      */
  43                         *(.text)
  44                         *(.fixup)
  45                         *(.gnu.warning)
  46                         *(.text.lock)   /* out-of-line lock text */
  47                         *(.rodata)
  48                         *(.kstrtab)
  49                 . = ALIGN(16);          /* Exception table              */
  50                 __start___ex_table = .;
  51                         *(__ex_table)
  52                 __stop___ex_table = .;
  53
  54                 __start___ksymtab = .;  /* Kernel symbol table          */
  55                         *(__ksymtab)
  56                 __stop___ksymtab = .;
  57
  58                 *(.got)                 /* Global offset table          */
  59
  60                 _etext = .;             /* End of text section          */
  61         }
  62
  63         .data : {
  64                 /*
  65                  * The cacheline aligned data
  66                  */
  67                 . = ALIGN(32);
  68                 *(.data.cacheline_aligned)
  69
  70                 /*
  71                  * and the usual data section
  72                  */
  73                 *(.data)
  74                 CONSTRUCTORS
  75
  76                 _edata = .;
  77         }
  78
  79
  80         .bss : {
  81                   __bss_start = .;      /* BSS                          */
  82                 *(.bss)
  83                   _end = . ;
  84         }
  85
  86                                         /* Stabs debugging sections.    */
  87         .stab 0 : { *(.stab) }
  88         .stabstr 0 : { *(.stabstr) }
  89         .stab.excl 0 : { *(.stab.excl) }
  90         .stab.exclstr 0 : { *(.stab.exclstr) }
  91         .stab.index 0 : { *(.stab.index) }
  92         .stab.indexstr 0 : { *(.stab.indexstr) }
  93         .comment 0 : { *(.comment) }
  94 }