arch/ppc/lib/checksum.S

   1 /*
   2  * This file contains assembly-language implementations
   3  * of IP-style 1's complement checksum routines.
   4  *
   5  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   6  *
   7  *  This program is free software; you can redistribute it and/or
   8  *  modify it under the terms of the GNU General Public License
   9  *  as published by the Free Software Foundation; either version
  10  *  2 of the License, or (at your option) any later version.
  11  *
  12  * Severely hacked about by Paul Mackerras (paulus@cs.anu.edu.au).
  13  */
  14
  15 #include <linux/sys.h>
  16 #include <asm/processor.h>
  17 #include <asm/errno.h>
  18 #include "../kernel/ppc_asm.tmpl"
  19
  20         .text
  21
  22 /*
  23  * ip_fast_csum(buf, len) -- Optimized for IP header
  24  * len is in words and is always >= 5.
  25  */
  26 _GLOBAL(ip_fast_csum)
  27         cmpi    0,r4,0
  28         beq     10f
  29         lwz     r0,0(r3)
  30         lwzu    r5,4(r3)
  31         addi    r4,r4,-2
  32         addc    r0,r0,r5
  33         mtctr   r4
  34 1:      lwzu    r4,4(r3)
  35         adde    r0,r0,r4
  36         bdnz    1b
  37         addze   r0,r0           /* add in final carry */
  38         rlwinm  r3,r0,16,0,31   /* fold two halves together */
  39         add     r3,r0,r3
  40         not     r3,r3
  41         srwi    r3,r3,16
  42         blr
  43 10:     li      r3,0
  44         blr
  45
  46 /*
  47  * Compute checksum of TCP or UDP pseudo-header:
  48  *   csum_tcpudp_magic(saddr, daddr, len, proto, sum)
  49  */
  50 _GLOBAL(csum_tcpudp_magic)
  51         rlwimi  r5,r6,16,0,15   /* put proto in upper half of len */
  52         addc    r0,r3,r4        /* add 4 32-bit words together */
  53         adde    r0,r0,r5
  54         adde    r0,r0,r7
  55         addze   r0,r0           /* add in final carry */
  56         rlwinm  r3,r0,16,0,31   /* fold two halves together */
  57         add     r3,r0,r3
  58         not     r3,r3
  59         srwi    r3,r3,16
  60         blr
  61
  62 /*
  63  * computes the checksum of a memory block at buff, length len,
  64  * and adds in "sum" (32-bit)
  65  *
  66  * csum_partial(buff, len, sum)
  67  */
  68 _GLOBAL(csum_partial)
  69         addic   r0,r5,0
  70         subi    r3,r3,4
  71         srwi.   r6,r4,2
  72         beq     3f              /* if we're doing < 4 bytes */
  73         andi.   r5,r3,2         /* Align buffer to longword boundary */
  74         beq+    1f
  75         lhz     r5,4(r3)        /* do 2 bytes to get aligned */
  76         addi    r3,r3,2
  77         subi    r4,r4,2
  78         addc    r0,r0,r5
  79         srwi.   r6,r4,2         /* # words to do */
  80         beq     3f
  81 1:      mtctr   r6
  82 2:      lwzu    r5,4(r3)        /* the bdnz has zero overhead, so it should */
  83         adde    r0,r0,r5        /* be unnecessary to unroll this loop */
  84         bdnz    2b
  85         andi.   r4,r4,3
  86 3:      cmpi    0,r4,2
  87         blt+    4f
  88         lhz     r5,4(r3)
  89         addi    r3,r3,2
  90         subi    r4,r4,2
  91         adde    r0,r0,r5
  92 4:      cmpi    0,r4,1
  93         bne+    5f
  94         lbz     r5,4(r3)
  95         slwi    r5,r5,8         /* Upper byte of word */
  96         adde    r0,r0,r5
  97 5:      addze   r3,r0           /* add in final carry */
  98         blr
  99
 100 /*
 101  * Computes the checksum of a memory block at src, length len,
 102  * and adds in "sum" (32-bit), while copying the block to dst.
 103  * If an access exception occurs on src or dst, it stores -EFAULT
 104  * to *src_err or *dst_err respectively, and (for an error on
 105  * src) zeroes the rest of dst.
 106  *
 107  * csum_partial_copy_generic(src, dst, len, sum, src_err, dst_err)
 108  */
 109 _GLOBAL(csum_partial_copy_generic)
 110         addic   r0,r6,0
 111         subi    r3,r3,4
 112         subi    r4,r4,4
 113         srwi.   r6,r5,2
 114         beq     3f              /* if we're doing < 4 bytes */
 115         andi.   r9,r4,2         /* Align dst to longword boundary */
 116         beq+    1f
 117 81:     lhz     r6,4(r3)        /* do 2 bytes to get aligned */
 118         addi    r3,r3,2
 119         subi    r5,r5,2
 120 91:     sth     r6,4(r4)
 121         addi    r4,r4,2
 122         addc    r0,r0,r6
 123         srwi.   r6,r5,2         /* # words to do */
 124         beq     3f
 125 1:      mtctr   r6
 126 82:     lwzu    r6,4(r3)        /* the bdnz has zero overhead, so it should */
 127 92:     stwu    r6,4(r4)        /* be unnecessary to unroll this loop */
 128         adde    r0,r0,r6
 129         bdnz    82b
 130         andi.   r5,r5,3
 131 3:      cmpi    0,r5,2
 132         blt+    4f
 133 83:     lhz     r6,4(r3)
 134         addi    r3,r3,2
 135         subi    r5,r5,2
 136 93:     sth     r6,4(r4)
 137         addi    r4,r4,2
 138         adde    r0,r0,r6
 139 4:      cmpi    0,r5,1
 140         bne+    5f
 141 84:     lbz     r6,4(r3)
 142 94:     stb     r6,4(r4)
 143         slwi    r6,r6,8         /* Upper byte of word */
 144         adde    r0,r0,r6
 145 5:      addze   r3,r0           /* add in final carry */
 146         blr
 147
 148 /* These shouldn't go in the fixup section, since that would
 149    cause the ex_table addresses to get out of order. */
 150
 151 src_error_1:
 152         li      r6,0
 153         subi    r5,r5,2
 154 95:     sth     r6,4(r4)
 155         addi    r4,r4,2
 156         srwi.   r6,r5,2
 157         beq     3f
 158         mtctr   r6
 159 src_error_2:
 160         li      r6,0
 161 96:     stwu    r6,4(r4)
 162         bdnz    96b
 163 3:      andi.   r5,r5,3
 164         beq     src_error
 165 src_error_3:
 166         li      r6,0
 167         mtctr   r5
 168         addi    r4,r4,3
 169 97:     stbu    r6,1(r4)
 170         bdnz    97b
 171 src_error:
 172         cmpi    0,r7,0
 173         beq     1f
 174         li      r6,-EFAULT
 175         stw     r6,0(r7)
 176 1:      addze   r3,r0
 177         blr
 178
 179 dst_error:
 180         cmpi    0,r8,0
 181         beq     1f
 182         li      r6,-EFAULT
 183         stw     r6,0(r8)
 184 1:      addze   r3,r0
 185         blr
 186
 187 .section __ex_table,"a"
 188         .long   81b,src_error_1
 189         .long   91b,dst_error
 190         .long   82b,src_error_2
 191         .long   92b,dst_error
 192         .long   83b,src_error_3
 193         .long   93b,dst_error
 194         .long   84b,src_error_3
 195         .long   94b,dst_error
 196         .long   95b,dst_error
 197         .long   96b,dst_error
 198         .long   97b,dst_error