arch/parisc/vmlinux.lds

   1 /* ld script to make hppa Linux kernel */
   2 OUTPUT_FORMAT("elf32-hppa")
   3 OUTPUT_ARCH(hppa)
   4 ENTRY(_stext)
   5 SECTIONS
   6 {
   7
   8 /* right now use 0x10000/0x11000, later when we don't use Console and
   9  * Boot-Device IODC, we will change this to 0x8000 !!!
  10  */
  11
  12   . = 0xc0100000;
  13 /*      . = 0x10000;  */
  14
  15   _text = .;                    /* Text and read-only data */
  16   .text BLOCK(16) : {
  17         *(.text*)
  18         *(.PARISC.unwind)
  19         *(.fixup)
  20         *(.lock.text)           /* out-of-line lock text */
  21         *(.gnu.warning)
  22         } = 0
  23
  24   . = ALIGN(16);
  25   .rodata : { *(.rodata) }
  26   .kstrtab : { *(.kstrtab) }
  27
  28   _etext = .;                   /* End of text section */
  29
  30   .data BLOCK(8192) : {                 /* Data without special */
  31         data_start = .;
  32         *(.data)
  33         }
  34
  35   . = ALIGN(16);                /* Exception table */
  36   __start___ex_table = .;
  37   __ex_table : { *(__ex_table) }
  38   __stop___ex_table = .;
  39
  40   __start___ksymtab = .;        /* Kernel symbol table */
  41   __ksymtab : { *(__ksymtab) }
  42   __stop___ksymtab = .;
  43
  44
  45   . = ALIGN(16384);
  46   __init_begin = .;
  47   .init.text : { *(.init.text) }
  48   .init.data : { *(.init.data) }
  49   . = ALIGN(16);
  50   __setup_start = .;
  51   .setup.init : { *(.setup.init) }
  52   __setup_end = .;
  53   __initcall_start = .;
  54   .initcall.init : { *(.initcall.init) }
  55   __initcall_end = .;
  56   __init_end = .;
  57
  58
  59   init_task BLOCK(16384) : { *(init_task) }  /* The initial task and kernel stack */
  60
  61   _edata = .;                   /* End of data section */
  62
  63
  64   .bss : { *(.bss) *(COMMON) }          /* BSS */
  65
  66
  67   _end = . ;
  68
  69   /* Stabs debugging sections.  */
  70   .stab 0 : { *(.stab) }
  71   .stabstr 0 : { *(.stabstr) }
  72   .stab.excl 0 : { *(.stab.excl) }
  73   .stab.exclstr 0 : { *(.stab.exclstr) }
  74   .stab.index 0 : { *(.stab.index) }
  75   .stab.indexstr 0 : { *(.stab.indexstr) }
  76   .comment 0 : { *(.comment) }
  77   .note 0 : { *(.note) }
  78
  79 }