arch/arm/vmlinux-armo.lds

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5 OUTPUT_FORMAT("elf32-arm", "elf32-arm", "elf32-arm")
   6 OUTPUT_ARCH(arm)
   7 ENTRY(_start)
   8 SECTIONS
   9 {
  10   _text = .;                    /* Text and read-only data */
  11   .text : {
  12         *(.text)
  13         *(.fixup)
  14         *(.gnu.warning)
  15         } = 0x9090
  16   .text.lock : { *(.text.lock) }        /* out-of-line lock text */
  17   .rodata : { *(.rodata) }
  18   .kstrtab : { *(.kstrtab) }
  19
  20   . = ALIGN(16);                /* Exception table */
  21   __start___ex_table = .;
  22   __ex_table : { *(__ex_table) }
  23   __stop___ex_table = .;
  24
  25   __start___ksymtab = .;        /* Kernel symbol table */
  26   __ksymtab : { *(__ksymtab) }
  27   __stop___ksymtab = .;
  28
  29   _etext = .;                   /* End of text section */
  30
  31   . = ALIGN(8192);
  32   .data : {                     /* Data */
  33         *(.init.task)
  34         *(.data)
  35         CONSTRUCTORS
  36         }
  37
  38   _edata = .;                   /* End of data section */
  39
  40   . = ALIGN(32768);             /* Init code and data */
  41   __init_begin = .;
  42   .text.init : { *(.text.init) }
  43   .data.init : { *(.data.init) }
  44   . = ALIGN(32768);
  45   __init_end = .;
  46
  47   __bss_start = .;              /* BSS */
  48   .bss : {
  49         *(.bss)
  50         }
  51   _end = . ;
  52
  53   /* Stabs debugging sections.  */
  54   .stab 0 : { *(.stab) }
  55   .stabstr 0 : { *(.stabstr) }
  56   .stab.excl 0 : { *(.stab.excl) }
  57   .stab.exclstr 0 : { *(.stab.exclstr) }
  58   .stab.index 0 : { *(.stab.index) }
  59   .stab.indexstr 0 : { *(.stab.indexstr) }
  60   .comment 0 : { *(.comment) }
  61 }