arch/mips64/ld.script.elf64

   1 OUTPUT_ARCH(mips)
   2 ENTRY(kernel_entry)
   3 SECTIONS
   4 {
   5   /* Read-only sections, merged into text segment: */
   6   /* . = 0xc000000000000000; */
   7
   8   /* This is the value for an Origin kernel, taken from an IRIX kernel.  */
   9   /* . = 0xc00000000001c000; */
  10
  11   /* Set the vaddr for the text segment to a value
  12         >= 0xa800 0000 0001 9000 if no symmon is going to configured
  13         >= 0xa800 0000 0030 0000 otherwise  */
  14
  15   /* . = 0xa800000000300000; */
  16   /* . = 0xa800000000300000; */
  17   . = 0xffffffff80300000;
  18   .text : {
  19     *(.text)
  20     *(.rodata)
  21     *(.rodata1)
  22     /* .gnu.warning sections are handled specially by elf32.em.  */
  23     *(.gnu.warning)
  24   } = 0
  25   .kstrtab : { *(.kstrtab) }
  26
  27   . = ALIGN(16);                /* Exception table */
  28   __start___ex_table = .;
  29   __ex_table : { *(__ex_table) }
  30   __stop___ex_table = .;
  31
  32   __start___dbe_table = .;      /* Exception table for data bus errors */
  33   __dbe_table : { *(__dbe_table) }
  34   __stop___dbe_table = .;
  35
  36   _etext = .;
  37
  38   . = ALIGN(16384);
  39   .data.init_task : { *(.data.init_task) }
  40
  41   /* Startup code */
  42   . = ALIGN(4096);
  43   __init_begin = .;
  44   .text.init : { *(.text.init) }
  45   .data.init : { *(.data.init) }
  46   . = ALIGN(16);
  47   __setup_start = .;
  48   .setup.init : { *(.setup.init) }
  49   __setup_end = .;
  50   __initcall_start = .;
  51   .initcall.init : { *(.initcall.init) }
  52   __initcall_end = .;
  53   . = ALIGN(4096);      /* Align double page for init_task_union */
  54   __init_end = .;
  55
  56   . = ALIGN(4096);
  57   .data.page_aligned : { *(.data.idt) }
  58
  59   . = ALIGN(32);
  60   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  61
  62   .fini      : { *(.fini)    } =0
  63   .reginfo : { *(.reginfo) }
  64   /* Adjust the address for the data segment.  We want to adjust up to
  65      the same address within the page on the next page up.  It would
  66      be more correct to do this:
  67        . = .;
  68      The current expression does not correctly handle the case of a
  69      text segment ending precisely at the end of a page; it causes the
  70      data segment to skip a page.  The above expression does not have
  71      this problem, but it will currently (2/95) cause BFD to allocate
  72      a single segment, combining both text and data, for this case.
  73      This will prevent the text segment from being shared among
  74      multiple executions of the program; I think that is more
  75      important than losing a page of the virtual address space (note
  76      that no actual memory is lost; the page which is skipped can not
  77      be referenced).  */
  78   . = .;
  79   .data    :
  80   {
  81     _fdata = . ;
  82     *(.data)
  83     CONSTRUCTORS
  84   }
  85   .data1   : { *(.data1) }
  86   .lit8 : { *(.lit8) }
  87   .lit4 : { *(.lit4) }
  88   .ctors         : { *(.ctors)   }
  89   .dtors         : { *(.dtors)   }
  90   .got           : { *(.got.plt) *(.got) }
  91   .dynamic       : { *(.dynamic) }
  92   /* We want the small data sections together, so single-instruction offsets
  93      can access them all, and initialized data all before uninitialized, so
  94      we can shorten the on-disk segment size.  */
  95   .sdata     : { *(.sdata) }
  96   _edata  =  .;
  97
  98   .sbss      : { *(.sbss) *(.scommon) }
  99   .bss       :
 100   {
 101    *(.dynbss)
 102    *(.bss)
 103    *(COMMON)
 104   _end = . ;
 105   }
 106
 107   /* Sections to be discarded */
 108   /DISCARD/ :
 109   {
 110         *(.text.exit)
 111         *(.data.exit)
 112         *(.exitcall.exit)
 113   }
 114
 115   /* These are needed for ELF backends which have not yet been
 116      converted to the new style linker.  */
 117   .stab 0 : { *(.stab) }
 118   .stabstr 0 : { *(.stabstr) }
 119   /* DWARF debug sections.
 120      Symbols in the .debug DWARF section are relative to the beginning of the
 121      section so we begin .debug at 0.  It's not clear yet what needs to happen
 122      for the others.   */
 123   .debug          0 : { *(.debug) }
 124   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 125   .debug_aranges  0 : { *(.debug_aranges) }
 126   .debug_pubnames 0 : { *(.debug_pubnames) }
 127   .debug_sfnames  0 : { *(.debug_sfnames) }
 128   .line           0 : { *(.line) }
 129   /* These must appear regardless of  .  */
 130   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
 131   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
 132 }