arch/arm/vmlinux-armv.lds.in

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5 OUTPUT_ARCH(arm)
   6 ENTRY(stext)
   7 SECTIONS
   8 {
   9         . = TEXTADDR;
  10         .init : {                       /* Init code and data           */
  11                 _stext = .;
  12                 __init_begin = .;
  13                         *(.text.init)
  14                 __proc_info_begin = .;
  15                         *(.proc.info)
  16                 __proc_info_end = .;
  17                 __arch_info_begin = .;
  18                         *(.arch.info)
  19                 __arch_info_end = .;
  20                         *(.data.init)
  21                 . = ALIGN(16);
  22                 __setup_start = .;
  23                         *(.setup.init)
  24                 __setup_end = .;
  25                 __initcall_start = .;
  26                         *(.initcall.init)
  27                 __initcall_end = .;
  28                 . = ALIGN(4096);
  29                 __init_end = .;
  30         }
  31
  32         /DISCARD/ : {                   /* Exit code and data           */
  33                 *(.text.exit)
  34                 *(.data.exit)
  35                 *(.exitcall.exit)
  36         }
  37
  38         .text : {                       /* Real text segment            */
  39                 _text = .;              /* Text and read-only data      */
  40                         *(.text)
  41                         *(.fixup)
  42                         *(.gnu.warning)
  43                         *(.text.lock)   /* out-of-line lock text */
  44                         *(.rodata)
  45                         *(.kstrtab)
  46                 . = ALIGN(16);
  47                 __start___ex_table = .; /* Exception table              */
  48                         *(__ex_table)
  49                 __stop___ex_table = .;
  50
  51                 __start___ksymtab = .;  /* Kernel symbol table          */
  52                         *(__ksymtab)
  53                 __stop___ksymtab = .;
  54
  55                 *(.got)                 /* Global offset table          */
  56
  57                 _etext = .;             /* End of text section          */
  58         }
  59
  60         . = ALIGN(8192);
  61
  62         .data : {
  63                 /*
  64                  * first, the init task union, aligned
  65                  * to an 8192 byte boundary.
  66                  */
  67                 *(.init.task)
  68
  69                 /*
  70                  * then the cacheline aligned data
  71                  */
  72                 . = ALIGN(32);
  73                 *(.data.cacheline_aligned)
  74
  75                 /*
  76                  * and the usual data section
  77                  */
  78                 *(.data)
  79                 CONSTRUCTORS
  80
  81                 _edata = .;
  82         }
  83
  84         .bss : {
  85                 __bss_start = .;        /* BSS                          */
  86                 *(.bss)
  87                 *(COMMON)
  88                 _end = . ;
  89         }
  90                                         /* Stabs debugging sections.    */
  91         .stab 0 : { *(.stab) }
  92         .stabstr 0 : { *(.stabstr) }
  93         .stab.excl 0 : { *(.stab.excl) }
  94         .stab.exclstr 0 : { *(.stab.exclstr) }
  95         .stab.index 0 : { *(.stab.index) }
  96         .stab.indexstr 0 : { *(.stab.indexstr) }
  97         .comment 0 : { *(.comment) }
  98 }