arch/arm/vmlinux-armo.lds.in

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5 OUTPUT_ARCH(arm)
   6 ENTRY(stext)
   7 SECTIONS
   8 {
   9         . = TEXTADDR;
  10
  11         .init : {
  12                 _stext = .;
  13                 __init_begin = .;       /* Init code and data           */
  14                         *(.text.init)
  15                 __proc_info_begin = .;
  16                         *(.proc.info)
  17                 __proc_info_end = .;
  18                 __arch_info_begin = .;
  19                         *(.arch.info)
  20                 __arch_info_end = .;
  21                         *(.data.init)
  22                 . = ALIGN(16);
  23                 __setup_start = .;
  24                         *(.setup.init)
  25                 __setup_end = .;
  26                 __initcall_start = .;
  27                         *(.initcall.init)
  28                 __initcall_end = .;
  29                 . = ALIGN(32768);
  30                 __init_end = .;
  31         }
  32
  33         .init.task : {
  34                 *(.init.task)
  35         }
  36
  37         /DISCARD/ : {                   /* Exit code and data           */
  38                 *(.text.exit)
  39                 *(.data.exit)
  40                 *(.exitcall.exit)
  41         }
  42
  43         .text : {
  44                 _text = .;              /* Text and read-only data      */
  45                         *(.text)
  46                         *(.fixup)
  47                         *(.gnu.warning)
  48                         *(.text.lock)   /* out-of-line lock text */
  49                         *(.rodata)
  50                         *(.kstrtab)
  51                 . = ALIGN(16);          /* Exception table              */
  52                 __start___ex_table = .;
  53                         *(__ex_table)
  54                 __stop___ex_table = .;
  55
  56                 __start___ksymtab = .;  /* Kernel symbol table          */
  57                         *(__ksymtab)
  58                 __stop___ksymtab = .;
  59
  60                 *(.got)                 /* Global offset table          */
  61
  62                 _etext = .;             /* End of text section          */
  63         }
  64
  65         .data : {
  66                 /*
  67                  * The cacheline aligned data
  68                  */
  69                 . = ALIGN(32);
  70                 *(.data.cacheline_aligned)
  71
  72                 /*
  73                  * and the usual data section
  74                  */
  75                 *(.data)
  76                 CONSTRUCTORS
  77
  78                 _edata = .;
  79         }
  80
  81
  82         .bss : {
  83                 __bss_start = .;        /* BSS                          */
  84                 *(.bss)
  85                 *(COMMON)
  86                 _end = . ;
  87         }
  88
  89                                         /* Stabs debugging sections.    */
  90         .stab 0 : { *(.stab) }
  91         .stabstr 0 : { *(.stabstr) }
  92         .stab.excl 0 : { *(.stab.excl) }
  93         .stab.exclstr 0 : { *(.stab.exclstr) }
  94         .stab.index 0 : { *(.stab.index) }
  95         .stab.indexstr 0 : { *(.stab.indexstr) }
  96         .comment 0 : { *(.comment) }
  97 }