arch/arm/vmlinux-armv.lds.in

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5 OUTPUT_ARCH(arm)
   6 ENTRY(stext)
   7 SECTIONS
   8 {
   9         . = TEXTADDR;
  10         .init : {                       /* Init code and data           */
  11                 __init_begin = .;
  12                         *(.text.init)
  13                 __proc_info_begin = .;
  14                         *(.proc.info)
  15                 __proc_info_end = .;
  16                 __arch_info_begin = .;
  17                         *(.arch.info)
  18                 __arch_info_end = .;
  19                         *(.data.init)
  20                 . = ALIGN(16);
  21                 __setup_start = .;
  22                         *(.setup.init)
  23                 __setup_end = .;
  24                 __initcall_start = .;
  25                         *(.initcall.init)
  26                 __initcall_end = .;
  27                 . = ALIGN(4096);
  28                 __init_end = .;
  29         }
  30
  31         /DISCARD/ : {                   /* Exit code and data           */
  32                 *(.text.exit)
  33                 *(.data.exit)
  34                 *(.exitcall.exit)
  35         }
  36
  37         .text : {                       /* Real text segment            */
  38                 _text = .;              /* Text and read-only data      */
  39                         *(.text)
  40                         *(.fixup)
  41                         *(.gnu.warning)
  42                         *(.text.lock)   /* out-of-line lock text */
  43                         *(.rodata)
  44                         *(.kstrtab)
  45                 . = ALIGN(16);
  46                 __start___ex_table = .; /* Exception table              */
  47                         *(__ex_table)
  48                 __stop___ex_table = .;
  49
  50                 __start___ksymtab = .;  /* Kernel symbol table          */
  51                         *(__ksymtab)
  52                 __stop___ksymtab = .;
  53
  54                 *(.got)                 /* Global offset table          */
  55
  56                 _etext = .;             /* End of text section          */
  57         }
  58
  59         . = ALIGN(8192);
  60
  61         .data : {
  62                 /*
  63                  * first, the init task union, aligned
  64                  * to an 8192 byte boundary.
  65                  */
  66                 *(.init.task)
  67
  68                 /*
  69                  * then the cacheline aligned data
  70                  */
  71                 . = ALIGN(32);
  72                 *(.data.cacheline_aligned)
  73
  74                 /*
  75                  * and the usual data section
  76                  */
  77                 *(.data)
  78                 CONSTRUCTORS
  79
  80                 _edata = .;
  81         }
  82
  83         .bss : {
  84                 __bss_start = .;        /* BSS                          */
  85                 *(.bss)
  86                 *(COMMON)
  87                 _end = . ;
  88         }
  89                                         /* Stabs debugging sections.    */
  90         .stab 0 : { *(.stab) }
  91         .stabstr 0 : { *(.stabstr) }
  92         .stab.excl 0 : { *(.stab.excl) }
  93         .stab.exclstr 0 : { *(.stab.exclstr) }
  94         .stab.index 0 : { *(.stab.index) }
  95         .stab.indexstr 0 : { *(.stab.indexstr) }
  96         .comment 0 : { *(.comment) }
  97 }