arch/arm/vmlinux-armo.lds.in

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5 OUTPUT_ARCH(arm)
   6 ENTRY(stext)
   7 SECTIONS
   8 {
   9         . = TEXTADDR;
  10
  11         .init : {
  12                 __init_begin = .;       /* Init code and data           */
  13                         *(.text.init)
  14                 __proc_info_begin = .;
  15                         *(.proc.info)
  16                 __proc_info_end = .;
  17                 __arch_info_begin = .;
  18                         *(.arch.info)
  19                 __arch_info_end = .;
  20                         *(.data.init)
  21                 . = ALIGN(16);
  22                 __setup_start = .;
  23                         *(.setup.init)
  24                 __setup_end = .;
  25                 __initcall_start = .;
  26                         *(.initcall.init)
  27                 __initcall_end = .;
  28                 . = ALIGN(32768);
  29                 __init_end = .;
  30         }
  31
  32         .init.task : {
  33                 *(.init.task)
  34         }
  35
  36         /DISCARD/ : {                   /* Exit code and data           */
  37                 *(.text.exit)
  38                 *(.data.exit)
  39                 *(.exitcall.exit)
  40         }
  41
  42         .text : {
  43                 _text = .;              /* Text and read-only data      */
  44                         *(.text)
  45                         *(.fixup)
  46                         *(.gnu.warning)
  47                         *(.text.lock)   /* out-of-line lock text */
  48                         *(.rodata)
  49                         *(.kstrtab)
  50                 . = ALIGN(16);          /* Exception table              */
  51                 __start___ex_table = .;
  52                         *(__ex_table)
  53                 __stop___ex_table = .;
  54
  55                 __start___ksymtab = .;  /* Kernel symbol table          */
  56                         *(__ksymtab)
  57                 __stop___ksymtab = .;
  58
  59                 *(.got)                 /* Global offset table          */
  60
  61                 _etext = .;             /* End of text section          */
  62         }
  63
  64         .data : {
  65                 /*
  66                  * The cacheline aligned data
  67                  */
  68                 . = ALIGN(32);
  69                 *(.data.cacheline_aligned)
  70
  71                 /*
  72                  * and the usual data section
  73                  */
  74                 *(.data)
  75                 CONSTRUCTORS
  76
  77                 _edata = .;
  78         }
  79
  80
  81         .bss : {
  82                 __bss_start = .;        /* BSS                          */
  83                 *(.bss)
  84                 *(COMMON)
  85                 _end = . ;
  86         }
  87
  88                                         /* Stabs debugging sections.    */
  89         .stab 0 : { *(.stab) }
  90         .stabstr 0 : { *(.stabstr) }
  91         .stab.excl 0 : { *(.stab.excl) }
  92         .stab.exclstr 0 : { *(.stab.exclstr) }
  93         .stab.index 0 : { *(.stab.index) }
  94         .stab.indexstr 0 : { *(.stab.indexstr) }
  95         .comment 0 : { *(.comment) }
  96 }