m4/gnome-doc-utils.m4

   1 dnl Do not call GNOME_DOC_DEFINES directly.  It is split out from
   2 dnl GNOME_DOC_INIT to allow gnome-doc-utils to bootstrap off itself.
   3 AC_DEFUN([GNOME_DOC_DEFINES],
   4 [
   5 AC_ARG_WITH([help-dir],
   6   AC_HELP_STRING([--with-help-dir=DIR], [path to help docs]),,
   7   [with_help_dir='${datadir}/gnome/help'])
   8 HELP_DIR="$with_help_dir"
   9 AC_SUBST(HELP_DIR)
  10
  11 AC_ARG_WITH([omf-dir],
  12   AC_HELP_STRING([--with-omf-dir=DIR], [path to OMF files]),,
  13   [with_omf_dir='${datadir}/omf'])
  14 OMF_DIR="$with_omf_dir"
  15 AC_SUBST(OMF_DIR)
  16
  17 AC_ARG_WITH([help-formats],
  18   AC_HELP_STRING([--with-help-formats=FORMATS], [list of formats]),,
  19   [with_help_formats=''])
  20 DOC_USER_FORMATS="$with_help_formats"
  21 AC_SUBST(DOC_USER_FORMATS)
  22
  23 AC_ARG_ENABLE([scrollkeeper],
  24         [AC_HELP_STRING([--disable-scrollkeeper],
  25                         [do not make updates to the scrollkeeper database])],,
  26         enable_scrollkeeper=yes)
  27 AM_CONDITIONAL([ENABLE_SK],[test "$gdu_cv_have_gdu" = "yes" -a "$enable_scrollkeeper" = "yes"])
  28
  29 dnl disable scrollkeeper automatically for distcheck
  30 DISTCHECK_CONFIGURE_FLAGS="--disable-scrollkeeper $DISTCHECK_CONFIGURE_FLAGS"
  31 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
  32
  33 AM_CONDITIONAL([HAVE_GNOME_DOC_UTILS],[test "$gdu_cv_have_gdu" = "yes"])
  34 ])
  35
  36 # GNOME_DOC_INIT ([MINIMUM-VERSION],[ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
  37 #
  38 AC_DEFUN([GNOME_DOC_INIT],
  39 [AC_REQUIRE([AC_PROG_LN_S])dnl
  40
  41 if test -z "$AM_DEFAULT_VERBOSITY"; then
  42   AM_DEFAULT_VERBOSITY=1
  43 fi
  44 AC_SUBST([AM_DEFAULT_VERBOSITY])
  45
  46 ifelse([$1],,[gdu_cv_version_required=0.3.2],[gdu_cv_version_required=$1])
  47
  48 AC_MSG_CHECKING([gnome-doc-utils >= $gdu_cv_version_required])
  49 PKG_CHECK_EXISTS([gnome-doc-utils >= $gdu_cv_version_required],
  50         [gdu_cv_have_gdu=yes],[gdu_cv_have_gdu=no])
  51
  52 if test "$gdu_cv_have_gdu" = "yes"; then
  53         AC_MSG_RESULT([yes])
  54         ifelse([$2],,[:],[$2])
  55 else
  56         AC_MSG_RESULT([no])
  57         ifelse([$3],,[AC_MSG_ERROR([gnome-doc-utils >= $gdu_cv_version_required not found])],[$3])
  58 fi
  59
  60 GNOME_DOC_DEFINES
  61 ])