configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991, 1993-2011 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.62])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.1 dist-xz color-tests parallel-tests])
  36 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  37
  38 AC_PROG_CC_STDC
  39 AM_PROG_CC_C_O
  40 AC_PROG_CPP
  41 AC_PROG_GCC_TRADITIONAL
  42 AC_PROG_RANLIB
  43 AC_PROG_LN_S
  44 gl_EARLY
  45 gl_INIT
  46 coreutils_MACROS
  47
  48 AC_ARG_ENABLE([gcc-warnings],
  49   [AS_HELP_STRING([--enable-gcc-warnings],
  50                   [turn on lots of GCC warnings (for developers)])],
  51   [case $enableval in
  52      yes|no) ;;
  53      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  54    esac
  55    gl_gcc_warnings=$enableval],
  56   [gl_gcc_warnings=no]
  57 )
  58
  59 if test "$gl_gcc_warnings" = yes; then
  60   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  61   AC_SUBST([WERROR_CFLAGS])
  62
  63   nw=
  64   # This, $nw, is the list of warnings we disable.
  65   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  66   nw="$nw -Waggregate-return"       # anachronistic
  67   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
  68   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  69   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  70   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  71   nw="$nw -Wcast-qual"              # Too many warnings for now
  72   nw="$nw -Wconversion"             # Too many warnings for now
  73   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  74   nw="$nw -Wsign-conversion"        # Too many warnings for now
  75   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  76   nw="$nw -Wunreachable-code"       # Too many warnings for now
  77   nw="$nw -Wpadded"                 # Our structs are not padded
  78   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  79   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  80   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
  81   nw="$nw -Wvla"                    # warnings in gettext.h
  82   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
  83   nw="$nw -Wswitch-enum"            # Too many warnings for now
  84   nw="$nw -Wswitch-default"         # Too many warnings for now
  85   nw="$nw -Wstack-protector"        # not worth working around
  86   # things I might fix soon:
  87   nw="$nw -Wfloat-equal"            # sort.c, seq.c
  88   nw="$nw -Wmissing-format-attribute" # copy.c
  89   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
  90   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
  91   nw="$nw -Wstrict-overflow"        # expr.c, pr.c, tr.c, factor.c
  92   # ?? -Wstrict-overflow
  93
  94   gl_MANYWARN_ALL_GCC([ws])
  95   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  96   for w in $ws; do
  97     gl_WARN_ADD([$w])
  98   done
  99   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 100   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 101
 102   # In spite of excluding -Wlogical-op above, it is enabled, as of
 103   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 104   gl_WARN_ADD([-Wno-logical-op])
 105
 106   gl_WARN_ADD([-fdiagnostics-show-option])
 107   gl_WARN_ADD([-funit-at-a-time])
 108
 109   AC_SUBST([WARN_CFLAGS])
 110
 111   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 112   AC_DEFINE([_FORTIFY_SOURCE], [2],
 113     [enable compile-time and run-time bounds-checking, and some warnings])
 114   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 115
 116   # We use a slightly smaller set of warning options for lib/.
 117   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 118   nw=
 119   nw="$nw -Wuninitialized"
 120   nw="$nw -Wunused-macros"
 121   nw="$nw -Wmissing-prototypes"
 122   nw="$nw -Wold-style-definition"
 123   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 124   AC_SUBST([GNULIB_WARN_CFLAGS])
 125
 126   # For gnulib-tests, the set is slightly smaller still.
 127   nw=
 128   nw="$nw -Wstrict-prototypes"
 129   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 130                          [$GNULIB_WARN_CFLAGS], [$nw])
 131   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 132 fi
 133
 134 AC_FUNC_FORK
 135
 136 optional_bin_progs=
 137 AC_CHECK_FUNCS([chroot],
 138         gl_ADD_PROG([optional_bin_progs], [chroot]))
 139 AC_CHECK_FUNCS([gethostid],
 140         gl_ADD_PROG([optional_bin_progs], [hostid]))
 141
 142 gl_WINSIZE_IN_PTEM
 143
 144 AC_MSG_CHECKING([whether localtime caches TZ])
 145 AC_CACHE_VAL([utils_cv_localtime_cache],
 146 [if test x$ac_cv_func_tzset = xyes; then
 147 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 148 #if STDC_HEADERS
 149 # include <stdlib.h>
 150 #endif
 151 extern char **environ;
 152 void unset_TZ (void)
 153 {
 154   char **from, **to;
 155   for (to = from = environ; (*to = *from); from++)
 156     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 157       to++;
 158 }
 159 int main()
 160 {
 161   time_t now = time ((time_t *) 0);
 162   int hour_GMT0, hour_unset;
 163   if (putenv ("TZ=GMT0") != 0)
 164     return 1;
 165   hour_GMT0 = localtime (&now)->tm_hour;
 166   unset_TZ ();
 167   hour_unset = localtime (&now)->tm_hour;
 168   if (putenv ("TZ=PST8") != 0)
 169     return 1;
 170   if (localtime (&now)->tm_hour == hour_GMT0)
 171     return 1;
 172   unset_TZ ();
 173   if (localtime (&now)->tm_hour != hour_unset)
 174     return 1;
 175   return 0;
 176 }]])],
 177 [utils_cv_localtime_cache=no],
 178 [utils_cv_localtime_cache=yes],
 179 [# If we have tzset, assume the worst when cross-compiling.
 180 utils_cv_localtime_cache=yes])
 181 else
 182         # If we lack tzset, report that localtime does not cache TZ,
 183         # since we can't invalidate the cache if we don't have tzset.
 184         utils_cv_localtime_cache=no
 185 fi])dnl
 186 AC_MSG_RESULT([$utils_cv_localtime_cache])
 187 if test $utils_cv_localtime_cache = yes; then
 188   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 189 fi
 190
 191 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 192 AC_CHECK_FUNCS([initgroups])
 193 if test $ac_cv_func_initgroups = no; then
 194   AC_CHECK_LIB([os], [initgroups])
 195 fi
 196
 197 AC_CHECK_FUNCS([syslog])
 198 if test $ac_cv_func_syslog = no; then
 199   # syslog is not in the default libraries.  See if it's in some other.
 200   for lib in bsd socket inet; do
 201     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 202       LIBS="$LIBS -l$lib"; break])
 203   done
 204 fi
 205
 206 AC_CACHE_CHECK([for 3-argument setpriority function],
 207   [utils_cv_func_setpriority],
 208   [AC_LINK_IFELSE(
 209     [AC_LANG_PROGRAM(
 210        [[#include <sys/time.h>
 211          #include <sys/resource.h>
 212        ]],
 213        [[setpriority (0, 0, 0);]])],
 214     [utils_cv_func_setpriority=yes],
 215     [utils_cv_func_setpriority=no])])
 216 if test $utils_cv_func_setpriority = no; then
 217   AC_CHECK_FUNCS([nice])
 218 fi
 219 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 220 *yes*)
 221   gl_ADD_PROG([optional_bin_progs], [nice])
 222 esac
 223
 224 AC_DEFUN([coreutils_DUMMY_1],
 225 [
 226   AC_REQUIRE([gl_READUTMP])
 227   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 228     gl_ADD_PROG([optional_bin_progs], [who])
 229     gl_ADD_PROG([optional_bin_progs], [users])
 230     gl_ADD_PROG([optional_bin_progs], [pinky])
 231   fi
 232 ])
 233 coreutils_DUMMY_1
 234
 235 AC_MSG_CHECKING([ut_host in struct utmp])
 236 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 237 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 238 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 239   [su_cv_func_ut_host_in_utmp=yes],
 240   [su_cv_func_ut_host_in_utmp=no])])
 241 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 242 if test $su_cv_func_ut_host_in_utmp = yes; then
 243   have_ut_host=1
 244   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 245 fi
 246
 247 if test -z "$have_ut_host"; then
 248   AC_MSG_CHECKING([ut_host in struct utmpx])
 249   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 250   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 251 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 252     [su_cv_func_ut_host_in_utmpx=yes],
 253     [su_cv_func_ut_host_in_utmpx=no])])
 254   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 255   if test $su_cv_func_ut_host_in_utmpx = yes; then
 256     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 257     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 258   fi
 259 fi
 260
 261 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 262
 263 AC_SYS_POSIX_TERMIOS()
 264 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 265
 266 if test $ac_cv_sys_posix_termios = yes; then
 267   gl_ADD_PROG([optional_bin_progs], [stty])
 268
 269   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 270   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 271   [AC_EGREP_CPP([yes], [#include <termios.h>
 272 #ifdef IUCLC
 273 yes
 274 #endif], su_cv_sys_termios_needs_xopen_source=no,
 275    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 276 #include <termios.h>
 277 #ifdef IUCLC
 278 yes
 279 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 280    su_cv_sys_termios_needs_xopen_source=no))])
 281   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 282   test $su_cv_sys_termios_needs_xopen_source = yes &&
 283     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 284
 285   AC_MSG_CHECKING([c_line in struct termios])
 286   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 287   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 288 #define _XOPEN_SOURCE
 289 #endif
 290 #include <sys/types.h>
 291 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 292     [su_cv_sys_c_line_in_termios=yes],
 293     [su_cv_sys_c_line_in_termios=no])])
 294   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 295   test $su_cv_sys_c_line_in_termios = yes \
 296     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 297 fi
 298
 299 # FIXME: note that this macro appears above, too.
 300 # I'm leaving it here for now.  This whole thing needs to be modernized...
 301 gl_WINSIZE_IN_PTEM
 302
 303 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 304
 305 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 306    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 307   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 308   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 309   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 310 #ifdef WINSIZE_IN_PTEM
 311 # include <sys/stream.h>
 312 # include <sys/ptem.h>
 313 #endif
 314 #include <sys/ioctl.h>
 315 #include <sys/tty.h>
 316 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 317     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 318     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 319   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 320
 321   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 322       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 323                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 324 fi
 325
 326 # For src/kill.c.
 327 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 328   [AC_INCLUDES_DEFAULT
 329 #include <signal.h>])
 330
 331 cu_LIB_CHECK
 332 cu_GMP
 333
 334 # Build df only if there's a point to it.
 335 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 336   gl_ADD_PROG([optional_bin_progs], [df])
 337 fi
 338
 339 # Limit stdbuf to ELF systems with GCC
 340 AC_MSG_CHECKING([whether this is an ELF system])
 341 AC_EGREP_CPP([yes], [#if __ELF__
 342 yes
 343 #endif], [elf_sys=yes], [elf_sys=no])
 344 AC_MSG_RESULT([$elf_sys])
 345 if test "$elf_sys" = "yes" && \
 346    test "$GCC" = "yes"; then
 347   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 348 fi
 349
 350 ############################################################################
 351 mk="$srcdir/src/Makefile.am"
 352 # Extract all literal names from the definition of $(EXTRA_PROGRAMS)
 353 # in $mk but don't expand the variable references.
 354 # Append each literal name to $optional_bin_progs.
 355 v=EXTRA_PROGRAMS
 356 for gl_i in `sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 357     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 358     | tr -s '\\015\\012\\\\' '   '`; do
 359   gl_ADD_PROG([optional_bin_progs], $gl_i)
 360 done
 361
 362 # As above, extract literal names from the definition of $(no_install__progs)
 363 # in $mk but don't expand the variable references.
 364 v=no_install__progs
 365 t=`sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 366     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 367     | tr -s '\\015\\012\\\\' '   '`
 368 # Remove any trailing space.
 369 no_install_progs_default=`echo "$t"|sed 's/ $//'`
 370
 371 # Unfortunately, due to the way autoconf's AS_HELP_STRING works, the list
 372 # of default-not-installed programs, "arch hostname su", must appear in two
 373 # places: in this file below, and in $mk.  Using "$no_install_progs_default"
 374 # below cannot work.  And we can't substitute the names into $mk because
 375 # automake needs the literals, too.
 376 # The compromise is to ensure that the space-separated list extracted
 377 # above matches the literal 2nd argument below.
 378 c="$srcdir/configure.ac"
 379 re='^g''l_INCLUDE_EXCLUDE_PROG(.* [\[\(.*\)\]])'
 380 t=`sed -n '/'"$re"'/{s/'"$re"'/\1/;s/,/ /gp
 381 }' $c`
 382 case $t in
 383   $no_install_progs_default) ;;
 384   *) AC_MSG_ERROR([[internal error: g'l_INCLUDE_EXCLUDE_PROG's 2nd arg, $t,
 385                    does not match the list of default-not-installed programs
 386                    ($no_install_progs_default) also recorded in $mk]],
 387                    1) ;;
 388 esac
 389
 390 # Given the name of a variable containing a space-separated list of
 391 # install-by-default programs and the actual list do-not-install-by-default
 392 # programs, modify the former variable to reflect any "do-install" and
 393 # "don't-install" requests.
 394 # I.e., add any program name specified via --enable-install-program=..., and
 395 # remove any program name specified via --enable-no-install-program=...
 396 # Note how the second argument below is a literal, with "," separators.
 397 # That is required due to the way the macro works, and since the
 398 # corresponding ./configure option argument is comma-separated on input.
 399 gl_INCLUDE_EXCLUDE_PROG([optional_bin_progs], [arch,hostname,su])
 400
 401 # Now that we know which programs will actually be built up, figure out
 402 # which optional helper progs should be compiled.
 403 optional_pkglib_progs=
 404 case " $optional_bin_progs " in
 405   *' stdbuf '*) gl_ADD_PROG([optional_pkglib_progs], [libstdbuf.so]) ;;
 406 esac
 407
 408 # Set INSTALL_SU if su installation has been requested via
 409 # --enable-install-program=su.
 410 AC_SUBST([INSTALL_SU])
 411 case " $optional_bin_progs " in
 412   *' su '*) INSTALL_SU=yes ;;
 413   *)        INSTALL_SU=no ;;
 414 esac
 415
 416 MAN=`echo "$optional_bin_progs "|sed 's/ /.1 /g;s/ $//'|tr -d '\\015\\012'`
 417
 418 # Change ginstall.1 to "install.h" in $MAN.
 419 MAN=`for m in $MAN; do test $m = ginstall.1 && m=install.1; echo $m; done \
 420   | tr '\015\012' '  '; echo`
 421
 422 # Remove [.1, since writing a portable rule for it in man/Makefile.am
 423 # is not practical.  The sed LHS below uses the autoconf quadrigraph
 424 # representing '['.
 425 MAN=`echo "$MAN"|sed 's/\@<:@\.1//'`
 426
 427 OPTIONAL_BIN_PROGS=`echo "$optional_bin_progs "|sed 's/ /\$(EXEEXT) /g;s/ $//'`
 428 AC_SUBST([OPTIONAL_BIN_PROGS])
 429 OPTIONAL_PKGLIB_PROGS=`echo "$optional_pkglib_progs " | sed 's/ $//'`
 430 AC_SUBST([OPTIONAL_PKGLIB_PROGS])
 431 NO_INSTALL_PROGS_DEFAULT=$no_install_progs_default
 432 AC_SUBST([NO_INSTALL_PROGS_DEFAULT])
 433
 434 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 435
 436 # Arrange to rerun configure whenever the file, src/Makefile.am,
 437 # containing the list of program names changes.
 438 CONFIG_STATUS_DEPENDENCIES='$(top_srcdir)/src/Makefile.am'
 439 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])
 440 ############################################################################
 441
 442 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 443 # translatable strings, we must use need-formatstring-macros here.
 444 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 445 AM_GNU_GETTEXT_VERSION([0.17])
 446
 447 # For a test of uniq: it uses the $LOCALE_FR envvar.
 448 gt_LOCALE_FR
 449
 450 AC_CONFIG_FILES(
 451   Makefile
 452   doc/Makefile
 453   lib/Makefile
 454   man/Makefile
 455   po/Makefile.in
 456   src/Makefile
 457   tests/Makefile
 458   gnulib-tests/Makefile
 459   )
 460 AC_OUTPUT