configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991-2016 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.69])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.2 no-dist-gzip dist-xz color-tests parallel-tests
  36                   subdir-objects])
  37 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  38
  39 dnl POSIXCHECK is worthwhile for maintainers, but adds several seconds
  40 dnl (more than 10% execution time) to ./configure, with no benefit for
  41 dnl most users.  Using it to look for bugs requires:
  42 dnl   GNULIB_POSIXCHECK=1 autoreconf -f
  43 dnl   ./configure
  44 dnl   make
  45 dnl   make -C src clean
  46 dnl   make CFLAGS=-DGNULIB_POSIXCHECK=1
  47 dnl FIXME: Once we figure out how to avoid false positives, we should
  48 dnl have 'make my-distcheck' in dist-check.mk exercise this.
  49 m4_syscmd([test "${GNULIB_POSIXCHECK+set}" = set])
  50 m4_if(m4_sysval, [0], [], [dnl
  51 gl_ASSERT_NO_GNULIB_POSIXCHECK])
  52
  53 AC_PROG_CC_STDC
  54 AM_PROG_CC_C_O
  55 AC_PROG_CPP
  56 AC_PROG_GCC_TRADITIONAL
  57 AC_PROG_RANLIB
  58 AC_PROG_LN_S
  59 gl_EARLY
  60 gl_INIT
  61 coreutils_MACROS
  62
  63 # The test suite needs to know if we have a working perl.
  64 # FIXME: this is suboptimal.  Ideally, we would be able to call gl_PERL
  65 # with an ACTION-IF-NOT-FOUND argument ...
  66 cu_have_perl=yes
  67 case $PERL in *"/missing "*) cu_have_perl=no;; esac
  68 AM_CONDITIONAL([HAVE_PERL], [test $cu_have_perl = yes])
  69
  70 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
  71 # ------------------------------------------------
  72 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
  73 # Otherwise, run RUN-IF-NOT-FOUND.
  74 AC_DEFUN([gl_GCC_VERSION_IFELSE],
  75   [AC_PREPROC_IFELSE(
  76     [AC_LANG_PROGRAM(
  77       [[
  78 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
  79 /* ok */
  80 #else
  81 # error "your version of gcc is older than $1.$2"
  82 #endif
  83       ]]),
  84     ], [$3], [$4])
  85   ]
  86 )
  87
  88 AC_ARG_ENABLE([gcc-warnings],
  89   [AS_HELP_STRING([--enable-gcc-warnings],
  90      [turn on many GCC warnings (for developers; best with GNU make)])],
  91   [case $enableval in
  92      yes|no) ;;
  93      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  94    esac
  95    gl_gcc_warnings=$enableval],
  96   [
  97    # GCC provides fine-grained control over diagnostics which
  98    # is used in gnulib for example to suppress warnings from
  99    # certain sections of code.  So if this is available and
 100    # we're running from a git repo, then auto enable the warnings.
 101    gl_gcc_warnings=no
 102    gl_GCC_VERSION_IFELSE([4], [6],
 103                          [test -d "$srcdir"/.git \
 104                           && ! test -f "$srcdir"/.tarball-version \
 105                           && gl_gcc_warnings=yes])]
 106 )
 107
 108 if test "$gl_gcc_warnings" = yes; then
 109   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 110   AC_SUBST([WERROR_CFLAGS])
 111
 112   nw=
 113   # This, $nw, is the list of warnings we disable.
 114   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
 115   nw="$nw -Waggregate-return"       # anachronistic
 116   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 117   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 118   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 119   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 120   nw="$nw -Wcast-qual"              # Too many warnings for now
 121   nw="$nw -Wconversion"             # Too many warnings for now
 122   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 123   nw="$nw -Wsign-conversion"        # Too many warnings for now
 124   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 125   nw="$nw -Wunreachable-code"       # Too many warnings for now
 126   nw="$nw -Wpadded"                 # Our structs are not padded
 127   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 128   nw="$nw -Wlogical-op"             # Too many warnings until GCC 4.8.0
 129   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
 130   nw="$nw -Wvla"                    # warnings in gettext.h
 131   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 132   nw="$nw -Wswitch-enum"            # Too many warnings for now
 133   nw="$nw -Wswitch-default"         # Too many warnings for now
 134   nw="$nw -Wstack-protector"        # not worth working around
 135   nw="$nw -Wtype-limits"            # False alarms for portable code
 136   # things I might fix soon:
 137   nw="$nw -Wfloat-equal"            # sort.c, seq.c
 138   nw="$nw -Wmissing-format-attribute" # copy.c
 139   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
 140   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
 141   nw="$nw -Wsuggest-attribute=format" # warns about copy.c and factor.c
 142
 143   # Using -Wstrict-overflow is a pain, but the alternative is worse.
 144   # For an example, see the code that provoked this report:
 145   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
 146   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
 147
 148   gl_MANYWARN_ALL_GCC([ws])
 149   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 150   for w in $ws; do
 151     gl_WARN_ADD([$w])
 152   done
 153   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 154   gl_WARN_ADD([-Wno-type-limits])      # False alarms for portable code
 155   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 156   gl_WARN_ADD([-Wno-format-nonliteral])
 157
 158   # Enable this warning only with gcc-4.8 and newer.  Before that
 159   # bounds checking as done in truncate.c was incorrectly flagged.
 160   # See: https://gcc.gnu.org/bugzilla/show_bug.cgi?id=43772
 161   gl_GCC_VERSION_IFELSE([4], [8], [gl_WARN_ADD([-Wlogical-op])])
 162
 163   # clang is unduly picky about some things.
 164   AC_CACHE_CHECK([whether the compiler is clang], [utils_cv_clang],
 165     [AC_COMPILE_IFELSE(
 166        [AC_LANG_PROGRAM([[
 167             #ifndef __clang__
 168               #error "not clang"
 169             #endif
 170           ]])],
 171        [utils_cv_clang=yes],
 172        [utils_cv_clang=no])])
 173   if test $utils_cv_clang = yes; then
 174     gl_WARN_ADD([-Wno-format-extra-args])
 175     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 176   fi
 177
 178   gl_WARN_ADD([-fdiagnostics-show-option])
 179   gl_WARN_ADD([-funit-at-a-time])
 180
 181   AC_SUBST([WARN_CFLAGS])
 182
 183   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 184   AH_VERBATIM([FORTIFY_SOURCE],
 185   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 186       without upsetting glibc 2.15+. */
 187    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 188    # define _FORTIFY_SOURCE 2
 189    #endif
 190   ])
 191   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 192
 193   # We use a slightly smaller set of warning options for lib/.
 194   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 195   nw=
 196   nw="$nw -Wstrict-overflow"
 197   nw="$nw -Wuninitialized"
 198   nw="$nw -Wunused-macros"
 199   nw="$nw -Wmissing-prototypes"
 200   nw="$nw -Wold-style-definition"
 201   # FIXME: it may be easy to remove this, since it affects only one file:
 202   # the snprintf call at ftoastr.c:132.
 203   nw="$nw -Wdouble-promotion"
 204   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 205   AC_SUBST([GNULIB_WARN_CFLAGS])
 206
 207   # For gnulib-tests, the set is slightly smaller still.
 208   nw=
 209   nw="$nw -Wstrict-prototypes"
 210   # It's not worth being this picky about test programs.
 211   nw="$nw -Wsuggest-attribute=const"
 212   nw="$nw -Wsuggest-attribute=pure"
 213   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 214                          [$GNULIB_WARN_CFLAGS], [$nw])
 215   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 216 fi
 217
 218 AC_ARG_ENABLE([single-binary],
 219   [AS_HELP_STRING([--enable-single-binary=[shebangs|symlinks]],
 220      [Compile all the tools in a single binary, reducing the overall size.
 221       When compiled this way, shebangs (default when enabled) or symlinks are
 222       installed for each tool that points to the single binary.])],
 223   [gl_single_binary=no ;
 224    case $enableval in
 225      yes) gl_single_binary=shebangs ;;
 226      no|shebangs|symlinks) gl_single_binary=$enableval ;;
 227      *)      AC_MSG_ERROR([bad value $enableval for single-binary option.
 228                            Options are: symlinks, shebangs, no.]) ;;
 229    esac],
 230   [gl_single_binary=no]
 231 )
 232 AC_ARG_ENABLE([single-binary-exceptions],
 233   [AS_HELP_STRING([--enable-single-binary-exceptions=PROG_LIST],
 234      [When used with --enable-single-binary, exclude the PROG_LIST from
 235       it, so these programs are compiled as separated files
 236       (comma-separated, default none))])],
 237   [gl_single_binary_exceptions=$enableval],
 238   [gl_single_binary_exceptions=]
 239 )
 240 if test "$gl_single_binary" = 'symlinks'; then
 241   if ! test "`echo ls | sed \"$program_transform_name\"`" = 'ls'; then
 242     AC_MSG_ERROR([program name transformations are not currently supported
 243                   with --enable-single-binary=symlinks.])
 244   fi
 245 fi
 246 AM_CONDITIONAL([SINGLE_BINARY], [test "$gl_single_binary" != no])
 247
 248 AC_FUNC_FORK
 249
 250 optional_bin_progs=
 251 AC_CHECK_FUNCS([chroot],
 252         gl_ADD_PROG([optional_bin_progs], [chroot]))
 253 AC_CHECK_FUNCS([gethostid],
 254         gl_ADD_PROG([optional_bin_progs], [hostid]))
 255
 256 gl_WINSIZE_IN_PTEM
 257
 258 AC_MSG_CHECKING([whether localtime caches TZ])
 259 AC_CACHE_VAL([utils_cv_localtime_cache],
 260 [if test x$ac_cv_func_tzset = xyes; then
 261 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 262 #if STDC_HEADERS
 263 # include <stdlib.h>
 264 #endif
 265 extern char **environ;
 266 void unset_TZ (void)
 267 {
 268   char **from, **to;
 269   for (to = from = environ; (*to = *from); from++)
 270     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 271       to++;
 272 }
 273 int main()
 274 {
 275   time_t now = time ((time_t *) 0);
 276   int hour_GMT0, hour_unset;
 277   if (putenv ("TZ=GMT0") != 0)
 278     return 1;
 279   hour_GMT0 = localtime (&now)->tm_hour;
 280   unset_TZ ();
 281   hour_unset = localtime (&now)->tm_hour;
 282   if (putenv ("TZ=PST8") != 0)
 283     return 1;
 284   if (localtime (&now)->tm_hour == hour_GMT0)
 285     return 1;
 286   unset_TZ ();
 287   if (localtime (&now)->tm_hour != hour_unset)
 288     return 1;
 289   return 0;
 290 }]])],
 291 [utils_cv_localtime_cache=no],
 292 [utils_cv_localtime_cache=yes],
 293 [# If we have tzset, assume the worst when cross-compiling.
 294 utils_cv_localtime_cache=yes])
 295 else
 296         # If we lack tzset, report that localtime does not cache TZ,
 297         # since we can't invalidate the cache if we don't have tzset.
 298         utils_cv_localtime_cache=no
 299 fi])dnl
 300 AC_MSG_RESULT([$utils_cv_localtime_cache])
 301 if test $utils_cv_localtime_cache = yes; then
 302   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 303 fi
 304
 305 # Assume that if getattrat exists, it's compatible with Solaris 11.
 306 AC_CHECK_FUNCS([getattrat])
 307 if test $ac_cv_func_getattrat = yes; then
 308   LIB_NVPAIR=-lnvpair
 309   AC_SUBST([LIB_NVPAIR])
 310 fi
 311
 312 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 313 AC_CHECK_FUNCS([initgroups])
 314 if test $ac_cv_func_initgroups = no; then
 315   AC_CHECK_LIB([os], [initgroups])
 316 fi
 317
 318 AC_CHECK_FUNCS([syslog])
 319 if test $ac_cv_func_syslog = no; then
 320   # syslog is not in the default libraries.  See if it's in some other.
 321   for lib in bsd socket inet; do
 322     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 323       LIBS="$LIBS -l$lib"; break])
 324   done
 325 fi
 326
 327 AC_CACHE_CHECK([for 3-argument setpriority function],
 328   [utils_cv_func_setpriority],
 329   [AC_LINK_IFELSE(
 330     [AC_LANG_PROGRAM(
 331        [[#include <sys/time.h>
 332          #include <sys/resource.h>
 333        ]],
 334        [[setpriority (0, 0, 0);]])],
 335     [utils_cv_func_setpriority=yes],
 336     [utils_cv_func_setpriority=no])])
 337 if test $utils_cv_func_setpriority = no; then
 338   AC_CHECK_FUNCS([nice])
 339 fi
 340 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 341 *yes*)
 342   gl_ADD_PROG([optional_bin_progs], [nice])
 343 esac
 344
 345 AC_DEFUN([coreutils_DUMMY_1],
 346 [
 347   AC_REQUIRE([gl_READUTMP])
 348   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 349     gl_ADD_PROG([optional_bin_progs], [who])
 350     gl_ADD_PROG([optional_bin_progs], [users])
 351     gl_ADD_PROG([optional_bin_progs], [pinky])
 352   fi
 353 ])
 354 coreutils_DUMMY_1
 355
 356 AC_MSG_CHECKING([ut_host in struct utmp])
 357 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 358 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 359                                    #include <utmp.h>
 360                                    struct utmp ut;
 361                                    int s = sizeof ut.ut_host;]])],
 362   [su_cv_func_ut_host_in_utmp=yes],
 363   [su_cv_func_ut_host_in_utmp=no])])
 364 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 365 if test $su_cv_func_ut_host_in_utmp = yes; then
 366   have_ut_host=1
 367   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 368 fi
 369
 370 if test -z "$have_ut_host"; then
 371   AC_MSG_CHECKING([ut_host in struct utmpx])
 372   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 373   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 374                                      #include <utmpx.h>
 375                                      struct utmpx ut;
 376                                      int s = sizeof ut.ut_host;]])],
 377     [su_cv_func_ut_host_in_utmpx=yes],
 378     [su_cv_func_ut_host_in_utmpx=no])])
 379   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 380   if test $su_cv_func_ut_host_in_utmpx = yes; then
 381     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 382     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 383   fi
 384 fi
 385
 386 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 387
 388 AC_SYS_POSIX_TERMIOS()
 389 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 390
 391 if test $ac_cv_sys_posix_termios = yes; then
 392   gl_ADD_PROG([optional_bin_progs], [stty])
 393
 394   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 395   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 396   [AC_EGREP_CPP([yes], [#include <termios.h>
 397 #ifdef IUCLC
 398 yes
 399 #endif], su_cv_sys_termios_needs_xopen_source=no,
 400    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 401 #include <termios.h>
 402 #ifdef IUCLC
 403 yes
 404 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 405    su_cv_sys_termios_needs_xopen_source=no))])
 406   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 407   test $su_cv_sys_termios_needs_xopen_source = yes &&
 408     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 409
 410   AC_MSG_CHECKING([c_line in struct termios])
 411   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 412   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 413                                       #define _XOPEN_SOURCE
 414                                      #endif
 415                                      #include <sys/types.h>
 416                                      #include <termios.h>
 417                                      struct termios t;
 418                                      int s = sizeof t.c_line;]])],
 419     [su_cv_sys_c_line_in_termios=yes],
 420     [su_cv_sys_c_line_in_termios=no])])
 421   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 422   test $su_cv_sys_c_line_in_termios = yes \
 423     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 424 fi
 425
 426 # FIXME: note that this macro appears above, too.
 427 # I'm leaving it here for now.  This whole thing needs to be modernized...
 428 gl_WINSIZE_IN_PTEM
 429
 430 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 431
 432 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 433    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 434   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 435   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 436   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 437 #ifdef WINSIZE_IN_PTEM
 438 # include <sys/stream.h>
 439 # include <sys/ptem.h>
 440 #endif
 441 #include <sys/ioctl.h>
 442 #include <sys/tty.h>
 443 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 444     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 445     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 446   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 447
 448   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 449       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 450                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 451 fi
 452
 453 # For src/kill.c.
 454 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 455   [AC_INCLUDES_DEFAULT
 456 #include <signal.h>])
 457
 458 cu_GMP
 459
 460 # Build df only if there's a point to it.
 461 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 462   gl_ADD_PROG([optional_bin_progs], [df])
 463 fi
 464
 465 # Build stdbuf only if supported
 466 ac_save_CFLAGS=$CFLAGS
 467 ac_save_LDFLAGS=$LDFLAGS
 468 # Detect warnings about ignored "constructor" attributes.
 469 gl_WARN_ADD([-Werror], [CFLAGS])
 470 gl_WARN_ADD([-errwarn], [CFLAGS])
 471 # Put this message here, after gl_WARN_ADD's chatter.
 472 AC_MSG_CHECKING([whether this system supports stdbuf])
 473 CFLAGS="-fPIC $CFLAGS"
 474 LDFLAGS="-shared $LDFLAGS"
 475 stdbuf_supported=no
 476 # Note we only LINK here rather than RUN to support cross compilation
 477 AC_LINK_IFELSE(
 478   [AC_LANG_PROGRAM([[
 479     static int stdbuf = 0;
 480
 481     void __attribute__ ((constructor))
 482     stdbuf_init (void)
 483     {
 484       stdbuf = 1;
 485     }]],[[
 486     if (stdbuf != 1)
 487       return 1;]])
 488   ],
 489   [stdbuf_supported=yes])
 490 AC_MSG_RESULT([$stdbuf_supported])
 491 if test "$stdbuf_supported" = "yes" && test -z "$EXEEXT"; then
 492   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 493 fi
 494 CFLAGS=$ac_save_CFLAGS
 495 LDFLAGS=$ac_save_LDFLAGS
 496
 497 ############################################################################
 498
 499 dnl Autogenerated by the 'gen-lists-of-programs.sh' auxiliary script.
 500 dnl Issue proper calls to the macros gl_INCLUDE_EXCLUDE_PROG and
 501 dnl gl_ADD_PROG (updating $optional_bin_progs), and generate the list
 502 dnl of coreutils programs to be built only upon explicit user request,
 503 dnl saving that list in the $no_install_progs_default shell variable.
 504 m4_include([m4/cu-progs.m4])
 505
 506 # Now that we know which programs will actually be built, determine
 507 # which optional helper progs should be compiled.
 508 # Note it adding to pkglibexec_PROGRAMS, $(transform) in src/local.mk
 509 # may need to be updated accordingly.
 510 case " $optional_bin_progs " in
 511   *' stdbuf '*) pkglibexec_PROGRAMS='src/libstdbuf.so';;
 512   *) pkglibexec_PROGRAMS='';;
 513 esac
 514
 515 man1_MANS=`
 516   for p in $optional_bin_progs; do
 517     # Change "ginstall.1" to "install.1".
 518     test $p = ginstall && p=install
 519     # Ignore the "[" program, since writing a portable make rule to
 520     # generate its manpage is not practical.
 521     dnl Use the autoconf-provided quadrigraph to represent "[",
 522     dnl otherwise we will incur in dreadful quoting issues.
 523     test x$p = x'@<:@' && continue
 524     echo "man/$p.1"
 525   done`
 526
 527 # Not installed by "make install", but must be built when creating
 528 # a distribution tarball.
 529 EXTRA_MANS=`for p in $no_install_progs_default $gl_no_install_prog; do
 530               echo man/$p.1
 531             done`
 532
 533 # Replace all the programs by the single binary and symlinks if specified.
 534 single_binary_progs=
 535 single_binary_libs=
 536 single_binary_deps=
 537 single_binary_install_type=
 538 if test "$gl_single_binary" != no; then
 539   man1_MANS="$man1_MANS man/coreutils.1"
 540   # Convert the list to a space separated list
 541   gl_single_binary_exceptions=`echo $gl_single_binary_exceptions | tr ',' ' '`
 542
 543   single_binary_progs=`echo $optional_bin_progs`
 544   optional_bin_progs="coreutils"
 545   for prog in $gl_single_binary_exceptions; do
 546     # Fail if requested to exclude a program than was not part of coreutils.
 547     case " $single_binary_progs " in
 548       *" $prog "*)
 549         gl_REMOVE_PROG([single_binary_progs], [$prog]) ;
 550         gl_ADD_PROG([optional_bin_progs], [$prog]) ;;
 551       *) AC_MSG_ERROR(['$prog' is not being compiled.]) ;;
 552     esac
 553   done
 554
 555   # single_binary_libs holds the list of libs required by the selected
 556   # programs, such as for example -lrt.
 557   single_binary_libs=`
 558     for p in $single_binary_progs; do
 559       # Convert '[' to '_'
 560       test x"$p" = x'@<:@' && p='_'
 561       printf '$(src_libsinglebin_%s_a_ldadd) ' "$p"
 562     done`
 563   # single_binary_deps holds the list of libsinglebin_*.a files that have the
 564   # compiled code of each selected program in a "library" format.
 565   single_binary_deps=`
 566     for p in $single_binary_progs; do
 567       # Convert '[' to '_'
 568       test x"$p" = x'@<:@' && p='_'
 569       printf 'src/libsinglebin_%s.a ' "$p"
 570     done`
 571   single_binary_install_type="$gl_single_binary"
 572 fi
 573 AC_SUBST([single_binary_progs], [$single_binary_progs])
 574 AC_SUBST([single_binary_libs], [$single_binary_libs])
 575 AC_SUBST([single_binary_deps], [$single_binary_deps])
 576 AC_SUBST([single_binary_install_type], [$single_binary_install_type])
 577
 578
 579 # The programs built and installed by "make && make install".
 580 # Since this is AC_SUBST'd, Automake won't be able to perform rewrite
 581 # with $(EXEEXT) appending on it, so we have to do it ourselves -- in
 582 # this case, only for $(bin_PROGRAMS).
 583 bin_PROGRAMS=`
 584   for p in $optional_bin_progs; do echo src/"$p"'$(EXEEXT)'; done`
 585
 586 # Normalize whitespace.
 587 man1_MANS=`echo $man1_MANS`
 588 EXTRA_MANS=`echo $EXTRA_MANS`
 589 bin_PROGRAMS=`echo $bin_PROGRAMS`
 590 pkglibexec_PROGS=`echo $pkglibexec_PROGRAMS`
 591
 592 AC_SUBST([bin_PROGRAMS])        AM_SUBST_NOTMAKE([bin_PROGRAMS])
 593 AC_SUBST([pkglibexec_PROGRAMS]) AM_SUBST_NOTMAKE([pkglibexec_PROGRAMS])
 594 AC_SUBST([man1_MANS])           AM_SUBST_NOTMAKE([man1_MANS])
 595 AC_SUBST([EXTRA_MANS])          AM_SUBST_NOTMAKE([EXTRA_MANS])
 596
 597 AC_SUBST([built_programs], [$optional_bin_progs])
 598
 599 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 600
 601 ############################################################################
 602
 603 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 604 # translatable strings, we must use need-formatstring-macros here.
 605 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 606 AM_GNU_GETTEXT_VERSION([0.19.2])
 607
 608 # For a test of uniq: it uses the $LOCALE_FR envvar.
 609 gt_LOCALE_FR
 610
 611 AC_CONFIG_FILES(
 612   Makefile
 613   po/Makefile.in
 614   gnulib-tests/Makefile
 615   )
 616 AC_OUTPUT