configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991, 1993-2009 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.61])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11 dist-xz color-tests parallel-tests])
  36 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  37
  38 AC_PROG_CC_STDC
  39 AM_PROG_CC_C_O
  40 AC_PROG_CPP
  41 AC_PROG_GCC_TRADITIONAL
  42 AC_PROG_RANLIB
  43 AC_PROG_LN_S
  44 gl_EARLY
  45 gl_INIT
  46 coreutils_MACROS
  47
  48 AC_ARG_ENABLE([gcc-warnings],
  49   [AS_HELP_STRING([--enable-gcc-warnings],
  50                   [turn on lots of GCC warnings (for developers)])],
  51   [case $enableval in
  52      yes|no) ;;
  53      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  54    esac
  55    gl_gcc_warnings=$enableval],
  56   [gl_gcc_warnings=no]
  57 )
  58
  59 if test "$gl_gcc_warnings" = yes; then
  60   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  61   AC_SUBST([WERROR_CFLAGS])
  62
  63   nw=
  64   # This, $nw, is the list of warnings we disable.
  65   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  66   nw="$nw -Waggregate-return"       # anachronistic
  67   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
  68   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  69   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  70   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  71   nw="$nw -Wcast-qual"              # Too many warnings for now
  72   nw="$nw -Wconversion"             # Too many warnings for now
  73   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  74   nw="$nw -Wsign-conversion"        # Too many warnings for now
  75   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  76   nw="$nw -Wunreachable-code"       # Too many warnings for now
  77   nw="$nw -Wpadded"                 # Our structs are not padded
  78   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  79   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  80   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
  81   nw="$nw -Wvla"                    # warnings in gettext.h
  82   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
  83   nw="$nw -Wswitch-enum"            # Too many warnings for now
  84   nw="$nw -Wswitch-default"         # Too many warnings for now
  85   nw="$nw -Wstack-protector"        # not worth working around
  86   # things I might fix soon:
  87   nw="$nw -Wfloat-equal"            # sort.c, seq.c
  88   nw="$nw -Wmissing-format-attribute" # copy.c
  89   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
  90   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
  91   nw="$nw -Wstrict-overflow"        # expr.c, pr.c, tr.c, factor.c
  92   # ?? -Wstrict-overflow
  93
  94   gl_MANYWARN_ALL_GCC([ws])
  95   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  96   for w in $ws; do
  97     gl_WARN_ADD([$w])
  98   done
  99   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 100   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 101   gl_WARN_ADD([-Wno-pointer-sign])     # Too many warnings for now
 102   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 103
 104   # In spite of excluding -Wlogical-op above, it is enabled, as of
 105   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 106   gl_WARN_ADD([-Wno-logical-op])
 107
 108   gl_WARN_ADD([-fdiagnostics-show-option])
 109
 110   AC_SUBST([WARN_CFLAGS])
 111
 112   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 113   AC_DEFINE([_FORTIFY_SOURCE], [2],
 114     [enable compile-time and run-time bounds-checking, and some warnings])
 115   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 116 fi
 117
 118 AC_FUNC_FORK
 119
 120 optional_bin_progs=
 121 AC_CHECK_FUNCS([uname],
 122         gl_ADD_PROG([optional_bin_progs], [uname]))
 123 AC_CHECK_FUNCS([chroot],
 124         gl_ADD_PROG([optional_bin_progs], [chroot]))
 125 AC_CHECK_FUNCS([gethostid],
 126         gl_ADD_PROG([optional_bin_progs], [hostid]))
 127
 128 gl_WINSIZE_IN_PTEM
 129
 130 AC_MSG_CHECKING([whether localtime caches TZ])
 131 AC_CACHE_VAL([utils_cv_localtime_cache],
 132 [if test x$ac_cv_func_tzset = xyes; then
 133 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 134 #if STDC_HEADERS
 135 # include <stdlib.h>
 136 #endif
 137 extern char **environ;
 138 void unset_TZ (void)
 139 {
 140   char **from, **to;
 141   for (to = from = environ; (*to = *from); from++)
 142     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 143       to++;
 144 }
 145 int main()
 146 {
 147   time_t now = time ((time_t *) 0);
 148   int hour_GMT0, hour_unset;
 149   if (putenv ("TZ=GMT0") != 0)
 150     exit (1);
 151   hour_GMT0 = localtime (&now)->tm_hour;
 152   unset_TZ ();
 153   hour_unset = localtime (&now)->tm_hour;
 154   if (putenv ("TZ=PST8") != 0)
 155     exit (1);
 156   if (localtime (&now)->tm_hour == hour_GMT0)
 157     exit (1);
 158   unset_TZ ();
 159   if (localtime (&now)->tm_hour != hour_unset)
 160     exit (1);
 161   exit (0);
 162 }]])],
 163 [utils_cv_localtime_cache=no],
 164 [utils_cv_localtime_cache=yes],
 165 [# If we have tzset, assume the worst when cross-compiling.
 166 utils_cv_localtime_cache=yes])
 167 else
 168         # If we lack tzset, report that localtime does not cache TZ,
 169         # since we can't invalidate the cache if we don't have tzset.
 170         utils_cv_localtime_cache=no
 171 fi])dnl
 172 AC_MSG_RESULT([$utils_cv_localtime_cache])
 173 if test $utils_cv_localtime_cache = yes; then
 174   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 175 fi
 176
 177 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 178 AC_CHECK_FUNCS([initgroups])
 179 if test $ac_cv_func_initgroups = no; then
 180   AC_CHECK_LIB([os], [initgroups])
 181 fi
 182
 183 AC_CHECK_FUNCS([syslog])
 184 if test $ac_cv_func_syslog = no; then
 185   # syslog is not in the default libraries.  See if it's in some other.
 186   for lib in bsd socket inet; do
 187     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 188       LIBS="$LIBS -l$lib"; break])
 189   done
 190 fi
 191
 192 AC_CACHE_CHECK([for 3-argument setpriority function],
 193   [utils_cv_func_setpriority],
 194   [AC_LINK_IFELSE(
 195     [AC_LANG_PROGRAM(
 196        [[#include <sys/time.h>
 197          #include <sys/resource.h>
 198        ]],
 199        [[setpriority (0, 0, 0);]])],
 200     [utils_cv_func_setpriority=yes],
 201     [utils_cv_func_setpriority=no])])
 202 if test $utils_cv_func_setpriority = no; then
 203   AC_CHECK_FUNCS([nice])
 204 fi
 205 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 206 *yes*)
 207   gl_ADD_PROG([optional_bin_progs], [nice])
 208 esac
 209
 210 AC_DEFUN([coreutils_DUMMY_1],
 211 [
 212   AC_REQUIRE([gl_READUTMP])
 213   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 214     gl_ADD_PROG([optional_bin_progs], [who])
 215     gl_ADD_PROG([optional_bin_progs], [users])
 216     gl_ADD_PROG([optional_bin_progs], [pinky])
 217   fi
 218 ])
 219 coreutils_DUMMY_1
 220
 221 AC_MSG_CHECKING([ut_host in struct utmp])
 222 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 223 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 224 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 225   [su_cv_func_ut_host_in_utmp=yes],
 226   [su_cv_func_ut_host_in_utmp=no])])
 227 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 228 if test $su_cv_func_ut_host_in_utmp = yes; then
 229   have_ut_host=1
 230   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 231 fi
 232
 233 if test -z "$have_ut_host"; then
 234   AC_MSG_CHECKING([ut_host in struct utmpx])
 235   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 236   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 237 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 238     [su_cv_func_ut_host_in_utmpx=yes],
 239     [su_cv_func_ut_host_in_utmpx=no])])
 240   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 241   if test $su_cv_func_ut_host_in_utmpx = yes; then
 242     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 243     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 244   fi
 245 fi
 246
 247 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 248
 249 AC_SYS_POSIX_TERMIOS()
 250 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 251
 252 if test $ac_cv_sys_posix_termios = yes; then
 253   gl_ADD_PROG([optional_bin_progs], [stty])
 254
 255   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 256   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 257   [AC_EGREP_CPP([yes], [#include <termios.h>
 258 #ifdef IUCLC
 259 yes
 260 #endif], su_cv_sys_termios_needs_xopen_source=no,
 261    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 262 #include <termios.h>
 263 #ifdef IUCLC
 264 yes
 265 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 266    su_cv_sys_termios_needs_xopen_source=no))])
 267   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 268   test $su_cv_sys_termios_needs_xopen_source = yes &&
 269     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 270
 271   AC_MSG_CHECKING([c_line in struct termios])
 272   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 273   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 274 #define _XOPEN_SOURCE
 275 #endif
 276 #include <sys/types.h>
 277 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 278     [su_cv_sys_c_line_in_termios=yes],
 279     [su_cv_sys_c_line_in_termios=no])])
 280   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 281   test $su_cv_sys_c_line_in_termios = yes \
 282     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 283 fi
 284
 285 # FIXME: note that this macro appears above, too.
 286 # I'm leaving it here for now.  This whole thing needs to be modernized...
 287 gl_WINSIZE_IN_PTEM
 288
 289 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 290
 291 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 292    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 293   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 294   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 295   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 296 #ifdef WINSIZE_IN_PTEM
 297 # include <sys/stream.h>
 298 # include <sys/ptem.h>
 299 #endif
 300 #include <sys/ioctl.h>
 301 #include <sys/tty.h>
 302 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 303     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 304     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 305   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 306
 307   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 308       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 309                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 310 fi
 311
 312 # For src/kill.c.
 313 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 314   [AC_INCLUDES_DEFAULT
 315 #include <signal.h>])
 316
 317 cu_LIB_CHECK
 318 cu_GMP
 319
 320 # Build df only if there's a point to it.
 321 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 322   gl_ADD_PROG([optional_bin_progs], [df])
 323 fi
 324
 325 # Limit stdbuf to ELF systems with GCC
 326 optional_pkglib_progs=
 327 AC_MSG_CHECKING([whether this is an ELF system])
 328 AC_EGREP_CPP([yes], [#if __ELF__
 329 yes
 330 #endif], [elf_sys=yes], [elf_sys=no])
 331 AC_MSG_RESULT([$elf_sys])
 332 if test "$elf_sys" = "yes" && \
 333    test "$GCC" = "yes"; then
 334   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 335   gl_ADD_PROG([optional_pkglib_progs], [libstdbuf.so])
 336 fi
 337
 338 ############################################################################
 339 mk="$srcdir/src/Makefile.am"
 340 # Extract all literal names from the definition of $(EXTRA_PROGRAMS)
 341 # in $mk but don't expand the variable references.
 342 # Append each literal name to $optional_bin_progs.
 343 v=EXTRA_PROGRAMS
 344 for gl_i in `sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 345     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 346     | tr -s '\\015\\012\\\\' '   '`; do
 347   gl_ADD_PROG([optional_bin_progs], $gl_i)
 348 done
 349
 350 # As above, extract literal names from the definition of $(no_install__progs)
 351 # in $mk but don't expand the variable references.
 352 v=no_install__progs
 353 t=`sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 354     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 355     | tr -s '\\015\\012\\\\' '   '`
 356 # Remove any trailing space.
 357 no_install_progs_default=`echo "$t"|sed 's/ $//'`
 358
 359 # Unfortunately, due to the way autoconf's AS_HELP_STRING works, the list
 360 # of default-not-installed programs, "arch hostname su", must appear in two
 361 # places: in this file below, and in $mk.  Using "$no_install_progs_default"
 362 # below cannot work.  And we can't substitute the names into $mk because
 363 # automake needs the literals, too.
 364 # The compromise is to ensure that the space-separated list extracted
 365 # above matches the literal 2nd argument below.
 366 c="$srcdir/configure.ac"
 367 re='^g''l_INCLUDE_EXCLUDE_PROG(.* [\[\(.*\)\]])'
 368 t=`sed -n '/'"$re"'/{s/'"$re"'/\1/;s/,/ /gp
 369 }' $c`
 370 case $t in
 371   $no_install_progs_default) ;;
 372   *) AC_MSG_ERROR([[internal error: g'l_INCLUDE_EXCLUDE_PROG's 2nd arg, $t,
 373                    does not match the list of default-not-installed programs
 374                    ($no_install_progs_default) also recorded in $mk]],
 375                    1) ;;
 376 esac
 377
 378 # Given the name of a variable containing a space-separated list of
 379 # install-by-default programs and the actual list do-not-install-by-default
 380 # programs, modify the former variable to reflect any "do-install" and
 381 # "don't-install" requests.
 382 # I.e., add any program name specified via --enable-install-program=..., and
 383 # remove any program name specified via --enable-no-install-program=...
 384 # Note how the second argument below is a literal, with "," separators.
 385 # That is required due to the way the macro works, and since the
 386 # corresponding ./configure option argument is comma-separated on input.
 387 gl_INCLUDE_EXCLUDE_PROG([optional_bin_progs], [arch,hostname,su])
 388
 389 # Set INSTALL_SU if su installation has been requested via
 390 # --enable-install-program=su.
 391 AC_SUBST([INSTALL_SU])
 392 case " $optional_bin_progs " in
 393   *' su '*) INSTALL_SU=yes ;;
 394   *)        INSTALL_SU=no ;;
 395 esac
 396
 397 MAN=`echo "$optional_bin_progs "|sed 's/ /.1 /g;s/ $//'|tr -d '\\015\\012'`
 398
 399 # Change ginstall.1 to "install.h" in $MAN.
 400 MAN=`for m in $MAN; do test $m = ginstall.1 && m=install.1; echo $m; done \
 401   | tr '\015\012' '  '; echo`
 402
 403 # Remove [.1, since writing a portable rule for it in man/Makefile.am
 404 # is not practical.  The sed LHS below uses the autoconf quadrigraph
 405 # representing '['.
 406 MAN=`echo "$MAN"|sed 's/\@<:@\.1//'`
 407
 408 OPTIONAL_BIN_PROGS=`echo "$optional_bin_progs "|sed 's/ /\$(EXEEXT) /g;s/ $//'`
 409 AC_SUBST([OPTIONAL_BIN_PROGS])
 410 OPTIONAL_PKGLIB_PROGS=`echo "$optional_pkglib_progs " | sed 's/ $//'`
 411 AC_SUBST([OPTIONAL_PKGLIB_PROGS])
 412 NO_INSTALL_PROGS_DEFAULT=$no_install_progs_default
 413 AC_SUBST([NO_INSTALL_PROGS_DEFAULT])
 414
 415 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 416
 417 # Arrange to rerun configure whenever the file, src/Makefile.am,
 418 # containing the list of program names changes.
 419 CONFIG_STATUS_DEPENDENCIES='$(top_srcdir)/src/Makefile.am'
 420 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])
 421 ############################################################################
 422
 423 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 424 AM_GNU_GETTEXT_VERSION([0.15])
 425
 426 # For a test of uniq: it uses the $LOCALE_FR envvar.
 427 gt_LOCALE_FR
 428
 429 AC_CONFIG_FILES(
 430   Makefile
 431   doc/Makefile
 432   lib/Makefile
 433   man/Makefile
 434   po/Makefile.in
 435   src/Makefile
 436   tests/Makefile
 437   gnulib-tests/Makefile
 438   )
 439 AC_OUTPUT