m4/jm-macros.m4

   1 #serial 109   -*- autoconf -*-
   2
   3 dnl Misc type-related macros for coreutils.
   4
   5 # Copyright (C) 1998, 2000-2009 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # Written by Jim Meyering.
  21
  22 AC_DEFUN([coreutils_MACROS],
  23 [
  24   AM_MISSING_PROG(HELP2MAN, help2man)
  25   AC_SUBST([MAN])
  26
  27   dnl This macro actually runs replacement code.  See isc-posix.m4.
  28   AC_REQUIRE([AC_ISC_POSIX])dnl
  29
  30   gl_CHECK_ALL_TYPES
  31
  32   AC_REQUIRE([gl_CHECK_DECLS])
  33
  34   AC_REQUIRE([gl_PREREQ])
  35
  36   AC_REQUIRE([AC_FUNC_FSEEKO])
  37
  38   # By default, argmatch should fail calling usage (1).
  39   AC_DEFINE([ARGMATCH_DIE], [usage (1)],
  40             [Define to the function xargmatch calls on failures.])
  41   AC_DEFINE([ARGMATCH_DIE_DECL], [void usage (int _e)],
  42             [Define to the declaration of the xargmatch failure function.])
  43
  44   # used by ls
  45   AC_REQUIRE([gl_CLOCK_TIME])
  46   # used by shred
  47   AC_CHECK_FUNCS_ONCE([directio])
  48
  49   # Used by install.c.
  50   coreutils_saved_libs=$LIBS
  51     LIBS="$LIBS $LIB_SELINUX"
  52     AC_CHECK_FUNCS([matchpathcon_init_prefix], [],
  53     [
  54       case "$ac_cv_search_setfilecon:$ac_cv_header_selinux_selinux_h" in
  55         no:*) # SELinux disabled
  56           ;;
  57         *:no) # SELinux disabled
  58           ;;
  59         *)
  60         AC_MSG_WARN([SELinux enabled, but matchpathcon_init_prefix not found])
  61         AC_MSG_WARN([The install utility may run slowly])
  62       esac
  63     ])
  64   LIBS=$coreutils_saved_libs
  65
  66   # Used by sort.c.
  67   AC_CHECK_FUNCS_ONCE([nl_langinfo])
  68
  69   # Used by tail.c.
  70   AC_CHECK_FUNCS([inotify_init],
  71     [AC_DEFINE([HAVE_INOTIFY], [1],
  72      [Define to 1 if you have usable inotify support.])])
  73
  74   AC_CHECK_FUNCS_ONCE( \
  75     endgrent \
  76     endpwent \
  77     fchown \
  78     fchmod \
  79     ftruncate \
  80     iswspace \
  81     mkfifo \
  82     mbrlen \
  83     setgroups \
  84     sethostname \
  85     siginterrupt \
  86     sync \
  87     sysctl \
  88     sysinfo \
  89     tcgetpgrp \
  90   )
  91
  92   # for cp.c
  93   AC_CHECK_FUNCS_ONCE([utimensat])
  94
  95   dnl This can't use AC_REQUIRE; I'm not quite sure why.
  96   cu_PREREQ_STAT_PROG
  97
  98   # for dd.c and shred.c
  99   coreutils_saved_libs=$LIBS
 100     AC_SEARCH_LIBS([fdatasync], [rt posix4],
 101                    [test "$ac_cv_search_fdatasync" = "none required" ||
 102                     LIB_FDATASYNC=$ac_cv_search_fdatasync])
 103     AC_SUBST([LIB_FDATASYNC])
 104     AC_CHECK_FUNCS([fdatasync])
 105   LIBS=$coreutils_saved_libs
 106
 107   # Check whether libcap is usable -- for ls --color support
 108   AC_ARG_ENABLE([libcap],
 109     AC_HELP_STRING([--disable-libcap], [disable libcap support]),
 110     AC_MSG_WARN([libcap support disabled by user]),
 111     [AC_CHECK_LIB([cap], [cap_get_file],
 112       [AC_CHECK_HEADER([sys/capability.h],
 113         [LIB_CAP=-lcap
 114          AC_DEFINE([HAVE_CAP], [1], [libcap usability])],
 115         [AC_MSG_WARN([header sys/capability.h was not found, support for libcap will not be built])]
 116       )],
 117       [AC_MSG_WARN([libcap library was not found or not usable, support for libcap will not be built])])
 118     ])
 119   AC_SUBST([LIB_CAP])
 120
 121   # See if linking `seq' requires -lm.
 122   # It does on nearly every system.  The single exception (so far) is
 123   # BeOS which has all the math functions in the normal runtime library
 124   # and doesn't have a separate math library.
 125
 126   AC_SUBST([SEQ_LIBM])
 127   ac_seq_body='
 128      static double x, y;
 129      x = floor (x);
 130      x = rint (x);
 131      x = modf (x, &y);'
 132   AC_TRY_LINK([#include <math.h>], [$ac_seq_body], ,
 133     [ac_seq_save_LIBS="$LIBS"
 134      LIBS="$LIBS -lm"
 135      AC_TRY_LINK([#include <math.h>], [$ac_seq_body], [SEQ_LIBM=-lm])
 136      LIBS="$ac_seq_save_LIBS"
 137     ])
 138
 139   AC_REQUIRE([AM_LANGINFO_CODESET])
 140 ])
 141
 142 AC_DEFUN([gl_CHECK_ALL_HEADERS],
 143 [
 144   AC_CHECK_HEADERS_ONCE( \
 145     hurd.h \
 146     paths.h \
 147     priv.h \
 148     stropts.h \
 149     sys/ioctl.h \
 150     sys/param.h \
 151     sys/resource.h \
 152     sys/systeminfo.h \
 153     sys/time.h \
 154     sys/wait.h \
 155     syslog.h \
 156     termios.h \
 157   )
 158   AC_CHECK_HEADERS([sys/sysctl.h], [], [],
 159     [AC_INCLUDES_DEFAULT
 160      [#if HAVE_SYS_PARAM_H
 161        #include <sys/param.h>
 162       #endif]])
 163 ])
 164
 165 # This macro must be invoked before any tests that run the compiler.
 166 AC_DEFUN([gl_CHECK_ALL_TYPES],
 167 [
 168   dnl This test must come as early as possible after the compiler configuration
 169   dnl tests, because the choice of the file model can (in principle) affect
 170   dnl whether functions and headers are available, whether they work, etc.
 171   AC_REQUIRE([AC_SYS_LARGEFILE])
 172
 173   dnl This test must precede tests of compiler characteristics like
 174   dnl that for the inline keyword, since it may change the degree to
 175   dnl which the compiler supports such features.
 176   AC_REQUIRE([AM_C_PROTOTYPES])
 177
 178   dnl Checks for typedefs, structures, and compiler characteristics.
 179   AC_REQUIRE([gl_BIGENDIAN])
 180   AC_REQUIRE([AC_C_VOLATILE])
 181   AC_REQUIRE([AC_C_INLINE])
 182   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
 183
 184   AC_REQUIRE([gl_CHECK_ALL_HEADERS])
 185   AC_CHECK_MEMBERS(
 186     [struct stat.st_author],,,
 187     [$ac_includes_default
 188 #include <sys/stat.h>
 189   ])
 190   AC_REQUIRE([AC_STRUCT_ST_BLOCKS])
 191
 192   AC_REQUIRE([AC_TYPE_GETGROUPS])
 193   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 194   AC_REQUIRE([AC_TYPE_MODE_T])
 195   AC_REQUIRE([AC_TYPE_OFF_T])
 196   AC_REQUIRE([AC_TYPE_PID_T])
 197   AC_REQUIRE([AC_TYPE_SIZE_T])
 198   AC_REQUIRE([AC_TYPE_UID_T])
 199   AC_CHECK_TYPE([ino_t], [unsigned long int])
 200
 201   dnl This relies on the fact that Autoconf's implementation of
 202   dnl AC_CHECK_TYPE checks includes unistd.h.
 203   AC_CHECK_TYPE([major_t], [unsigned int])
 204   AC_CHECK_TYPE([minor_t], [unsigned int])
 205
 206   AC_REQUIRE([AC_HEADER_MAJOR])
 207 ])