configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991, 1993-2009 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.61])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11 dist-xz color-tests parallel-tests])
  36 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  37
  38 AC_PROG_CC_STDC
  39 AM_PROG_CC_C_O
  40 AC_PROG_CPP
  41 AC_PROG_GCC_TRADITIONAL
  42 AC_PROG_RANLIB
  43 AC_PROG_LN_S
  44 gl_EARLY
  45 gl_INIT
  46 coreutils_MACROS
  47
  48 AC_ARG_ENABLE([gcc-warnings],
  49   [AS_HELP_STRING([--enable-gcc-warnings],
  50                   [turn on lots of GCC warnings (for developers)])],
  51   [case $enableval in
  52      yes|no) ;;
  53      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  54    esac
  55    gl_gcc_warnings=$enableval],
  56   [gl_gcc_warnings=no]
  57 )
  58
  59 if test "$gl_gcc_warnings" = yes; then
  60   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  61   AC_SUBST([WERROR_CFLAGS])
  62
  63   nw=
  64   # This, $nw, is the list of warnings we disable.
  65   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
  66   nw="$nw -Waggregate-return"       # anachronistic
  67   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
  68   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
  69   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
  70   nw="$nw -Wtraditional"            # Warns on #elif which we use often
  71   nw="$nw -Wcast-qual"              # Too many warnings for now
  72   nw="$nw -Wconversion"             # Too many warnings for now
  73   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  74   nw="$nw -Wsign-conversion"        # Too many warnings for now
  75   nw="$nw -Wtraditional-conversion" # Too many warnings for now
  76   nw="$nw -Wunreachable-code"       # Too many warnings for now
  77   nw="$nw -Wpadded"                 # Our structs are not padded
  78   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
  79   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
  80   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
  81   nw="$nw -Wvla"                    # warnings in gettext.h
  82   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
  83   nw="$nw -Wswitch-enum"            # Too many warnings for now
  84   nw="$nw -Wswitch-default"         # Too many warnings for now
  85   nw="$nw -Wstack-protector"        # not worth working around
  86   # things I might fix soon:
  87   nw="$nw -Wfloat-equal"            # sort.c, seq.c
  88   nw="$nw -Wmissing-format-attribute" # copy.c
  89   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
  90   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
  91   nw="$nw -Wstrict-overflow"        # expr.c, pr.c, tr.c, factor.c
  92   # ?? -Wstrict-overflow
  93
  94   gl_MANYWARN_ALL_GCC([ws])
  95   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  96   for w in $ws; do
  97     gl_WARN_ADD([$w])
  98   done
  99   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 100   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 101   gl_WARN_ADD([-Wno-pointer-sign])     # Too many warnings for now
 102   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 103
 104   # Offenders in pre-fts remove.c; FIXME: remove upon remove.c rewrite
 105   gl_WARN_ADD([-Wno-jump-misses-init])
 106
 107   # In spite of excluding -Wlogical-op above, it is enabled, as of
 108   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 109   gl_WARN_ADD([-Wno-logical-op])
 110
 111   gl_WARN_ADD([-fdiagnostics-show-option])
 112
 113   AC_SUBST([WARN_CFLAGS])
 114
 115   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 116   AC_DEFINE([_FORTIFY_SOURCE], [2],
 117     [enable compile-time and run-time bounds-checking, and some warnings])
 118   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 119 fi
 120
 121 AC_FUNC_FORK
 122
 123 optional_bin_progs=
 124 AC_CHECK_FUNCS([uname],
 125         gl_ADD_PROG([optional_bin_progs], [uname]))
 126 AC_CHECK_FUNCS([chroot],
 127         gl_ADD_PROG([optional_bin_progs], [chroot]))
 128 AC_CHECK_FUNCS([gethostid],
 129         gl_ADD_PROG([optional_bin_progs], [hostid]))
 130
 131 gl_WINSIZE_IN_PTEM
 132
 133 AC_MSG_CHECKING([whether localtime caches TZ])
 134 AC_CACHE_VAL([utils_cv_localtime_cache],
 135 [if test x$ac_cv_func_tzset = xyes; then
 136 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 137 #if STDC_HEADERS
 138 # include <stdlib.h>
 139 #endif
 140 extern char **environ;
 141 void unset_TZ (void)
 142 {
 143   char **from, **to;
 144   for (to = from = environ; (*to = *from); from++)
 145     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 146       to++;
 147 }
 148 int main()
 149 {
 150   time_t now = time ((time_t *) 0);
 151   int hour_GMT0, hour_unset;
 152   if (putenv ("TZ=GMT0") != 0)
 153     exit (1);
 154   hour_GMT0 = localtime (&now)->tm_hour;
 155   unset_TZ ();
 156   hour_unset = localtime (&now)->tm_hour;
 157   if (putenv ("TZ=PST8") != 0)
 158     exit (1);
 159   if (localtime (&now)->tm_hour == hour_GMT0)
 160     exit (1);
 161   unset_TZ ();
 162   if (localtime (&now)->tm_hour != hour_unset)
 163     exit (1);
 164   exit (0);
 165 }]])],
 166 [utils_cv_localtime_cache=no],
 167 [utils_cv_localtime_cache=yes],
 168 [# If we have tzset, assume the worst when cross-compiling.
 169 utils_cv_localtime_cache=yes])
 170 else
 171         # If we lack tzset, report that localtime does not cache TZ,
 172         # since we can't invalidate the cache if we don't have tzset.
 173         utils_cv_localtime_cache=no
 174 fi])dnl
 175 AC_MSG_RESULT([$utils_cv_localtime_cache])
 176 if test $utils_cv_localtime_cache = yes; then
 177   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 178 fi
 179
 180 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 181 AC_CHECK_FUNCS([initgroups])
 182 if test $ac_cv_func_initgroups = no; then
 183   AC_CHECK_LIB([os], [initgroups])
 184 fi
 185
 186 AC_CHECK_FUNCS([syslog])
 187 if test $ac_cv_func_syslog = no; then
 188   # syslog is not in the default libraries.  See if it's in some other.
 189   for lib in bsd socket inet; do
 190     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 191       LIBS="$LIBS -l$lib"; break])
 192   done
 193 fi
 194
 195 AC_CACHE_CHECK([for 3-argument setpriority function],
 196   [utils_cv_func_setpriority],
 197   [AC_LINK_IFELSE(
 198     [AC_LANG_PROGRAM(
 199        [[#include <sys/time.h>
 200          #include <sys/resource.h>
 201        ]],
 202        [[setpriority (0, 0, 0);]])],
 203     [utils_cv_func_setpriority=yes],
 204     [utils_cv_func_setpriority=no])])
 205 if test $utils_cv_func_setpriority = no; then
 206   AC_CHECK_FUNCS([nice])
 207 fi
 208 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 209 *yes*)
 210   gl_ADD_PROG([optional_bin_progs], [nice])
 211 esac
 212
 213 AC_DEFUN([coreutils_DUMMY_1],
 214 [
 215   AC_REQUIRE([gl_READUTMP])
 216   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 217     gl_ADD_PROG([optional_bin_progs], [who])
 218     gl_ADD_PROG([optional_bin_progs], [users])
 219     gl_ADD_PROG([optional_bin_progs], [pinky])
 220   fi
 221 ])
 222 coreutils_DUMMY_1
 223
 224 AC_MSG_CHECKING([ut_host in struct utmp])
 225 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 226 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 227 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 228   [su_cv_func_ut_host_in_utmp=yes],
 229   [su_cv_func_ut_host_in_utmp=no])])
 230 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 231 if test $su_cv_func_ut_host_in_utmp = yes; then
 232   have_ut_host=1
 233   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 234 fi
 235
 236 if test -z "$have_ut_host"; then
 237   AC_MSG_CHECKING([ut_host in struct utmpx])
 238   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 239   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 240 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 241     [su_cv_func_ut_host_in_utmpx=yes],
 242     [su_cv_func_ut_host_in_utmpx=no])])
 243   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 244   if test $su_cv_func_ut_host_in_utmpx = yes; then
 245     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 246     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 247   fi
 248 fi
 249
 250 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 251
 252 AC_SYS_POSIX_TERMIOS()
 253 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 254
 255 if test $ac_cv_sys_posix_termios = yes; then
 256   gl_ADD_PROG([optional_bin_progs], [stty])
 257
 258   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 259   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 260   [AC_EGREP_CPP([yes], [#include <termios.h>
 261 #ifdef IUCLC
 262 yes
 263 #endif], su_cv_sys_termios_needs_xopen_source=no,
 264    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 265 #include <termios.h>
 266 #ifdef IUCLC
 267 yes
 268 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 269    su_cv_sys_termios_needs_xopen_source=no))])
 270   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 271   test $su_cv_sys_termios_needs_xopen_source = yes &&
 272     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 273
 274   AC_MSG_CHECKING([c_line in struct termios])
 275   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 276   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 277 #define _XOPEN_SOURCE
 278 #endif
 279 #include <sys/types.h>
 280 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 281     [su_cv_sys_c_line_in_termios=yes],
 282     [su_cv_sys_c_line_in_termios=no])])
 283   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 284   test $su_cv_sys_c_line_in_termios = yes \
 285     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 286 fi
 287
 288 # FIXME: note that this macro appears above, too.
 289 # I'm leaving it here for now.  This whole thing needs to be modernized...
 290 gl_WINSIZE_IN_PTEM
 291
 292 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 293
 294 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 295    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 296   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 297   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 298   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 299 #ifdef WINSIZE_IN_PTEM
 300 # include <sys/stream.h>
 301 # include <sys/ptem.h>
 302 #endif
 303 #include <sys/ioctl.h>
 304 #include <sys/tty.h>
 305 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 306     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 307     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 308   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 309
 310   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 311       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 312                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 313 fi
 314
 315 # For src/kill.c.
 316 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 317   [AC_INCLUDES_DEFAULT
 318 #include <signal.h>])
 319
 320 cu_LIB_CHECK
 321 cu_GMP
 322
 323 # Build df only if there's a point to it.
 324 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 325   gl_ADD_PROG([optional_bin_progs], [df])
 326 fi
 327
 328 # Limit stdbuf to ELF systems with GCC
 329 optional_pkglib_progs=
 330 AC_MSG_CHECKING([whether this is an ELF system])
 331 AC_EGREP_CPP([yes], [#if __ELF__
 332 yes
 333 #endif], [elf_sys=yes], [elf_sys=no])
 334 AC_MSG_RESULT([$elf_sys])
 335 if test "$elf_sys" = "yes" && \
 336    test "$GCC" = "yes"; then
 337   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 338   gl_ADD_PROG([optional_pkglib_progs], [libstdbuf.so])
 339 fi
 340
 341 ############################################################################
 342 mk="$srcdir/src/Makefile.am"
 343 # Extract all literal names from the definition of $(EXTRA_PROGRAMS)
 344 # in $mk but don't expand the variable references.
 345 # Append each literal name to $optional_bin_progs.
 346 v=EXTRA_PROGRAMS
 347 for gl_i in `sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 348     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 349     | tr -s '\\015\\012\\\\' '   '`; do
 350   gl_ADD_PROG([optional_bin_progs], $gl_i)
 351 done
 352
 353 # As above, extract literal names from the definition of $(no_install__progs)
 354 # in $mk but don't expand the variable references.
 355 v=no_install__progs
 356 t=`sed -n '/^'$v' =/,/[[^\]]$/p' $mk \
 357     | sed 's/^  *//;/^\$.*/d;/^'$v' =/d' \
 358     | tr -s '\\015\\012\\\\' '   '`
 359 # Remove any trailing space.
 360 no_install_progs_default=`echo "$t"|sed 's/ $//'`
 361
 362 # Unfortunately, due to the way autoconf's AS_HELP_STRING works, the list
 363 # of default-not-installed programs, "arch hostname su", must appear in two
 364 # places: in this file below, and in $mk.  Using "$no_install_progs_default"
 365 # below cannot work.  And we can't substitute the names into $mk because
 366 # automake needs the literals, too.
 367 # The compromise is to ensure that the space-separated list extracted
 368 # above matches the literal 2nd argument below.
 369 c="$srcdir/configure.ac"
 370 re='^g''l_INCLUDE_EXCLUDE_PROG(.* [\[\(.*\)\]])'
 371 t=`sed -n '/'"$re"'/{s/'"$re"'/\1/;s/,/ /gp
 372 }' $c`
 373 case $t in
 374   $no_install_progs_default) ;;
 375   *) AC_MSG_ERROR([[internal error: g'l_INCLUDE_EXCLUDE_PROG's 2nd arg, $t,
 376                    does not match the list of default-not-installed programs
 377                    ($no_install_progs_default) also recorded in $mk]],
 378                    1) ;;
 379 esac
 380
 381 # Given the name of a variable containing a space-separated list of
 382 # install-by-default programs and the actual list do-not-install-by-default
 383 # programs, modify the former variable to reflect any "do-install" and
 384 # "don't-install" requests.
 385 # I.e., add any program name specified via --enable-install-program=..., and
 386 # remove any program name specified via --enable-no-install-program=...
 387 # Note how the second argument below is a literal, with "," separators.
 388 # That is required due to the way the macro works, and since the
 389 # corresponding ./configure option argument is comma-separated on input.
 390 gl_INCLUDE_EXCLUDE_PROG([optional_bin_progs], [arch,hostname,su])
 391
 392 # Set INSTALL_SU if su installation has been requested via
 393 # --enable-install-program=su.
 394 AC_SUBST([INSTALL_SU])
 395 case " $optional_bin_progs " in
 396   *' su '*) INSTALL_SU=yes ;;
 397   *)        INSTALL_SU=no ;;
 398 esac
 399
 400 MAN=`echo "$optional_bin_progs "|sed 's/ /.1 /g;s/ $//'|tr -d '\\015\\012'`
 401
 402 # Change ginstall.1 to "install.h" in $MAN.
 403 MAN=`for m in $MAN; do test $m = ginstall.1 && m=install.1; echo $m; done \
 404   | tr '\015\012' '  '; echo`
 405
 406 # Remove [.1, since writing a portable rule for it in man/Makefile.am
 407 # is not practical.  The sed LHS below uses the autoconf quadrigraph
 408 # representing '['.
 409 MAN=`echo "$MAN"|sed 's/\@<:@\.1//'`
 410
 411 OPTIONAL_BIN_PROGS=`echo "$optional_bin_progs "|sed 's/ /\$(EXEEXT) /g;s/ $//'`
 412 AC_SUBST([OPTIONAL_BIN_PROGS])
 413 OPTIONAL_PKGLIB_PROGS=`echo "$optional_pkglib_progs " | sed 's/ $//'`
 414 AC_SUBST([OPTIONAL_PKGLIB_PROGS])
 415 NO_INSTALL_PROGS_DEFAULT=$no_install_progs_default
 416 AC_SUBST([NO_INSTALL_PROGS_DEFAULT])
 417
 418 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 419
 420 # Arrange to rerun configure whenever the file, src/Makefile.am,
 421 # containing the list of program names changes.
 422 CONFIG_STATUS_DEPENDENCIES='$(top_srcdir)/src/Makefile.am'
 423 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])
 424 ############################################################################
 425
 426 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 427 AM_GNU_GETTEXT_VERSION([0.15])
 428
 429 # For a test of uniq: it uses the $LOCALE_FR envvar.
 430 gt_LOCALE_FR
 431
 432 AC_CONFIG_FILES(
 433   Makefile
 434   doc/Makefile
 435   lib/Makefile
 436   man/Makefile
 437   po/Makefile.in
 438   src/Makefile
 439   tests/Makefile
 440   gnulib-tests/Makefile
 441   )
 442 AC_OUTPUT