configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991-2013 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.64])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.2 no-dist-gzip dist-xz color-tests parallel-tests
  36                   subdir-objects])
  37 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  38
  39 dnl POSIXCHECK is worthwhile for maintainers, but adds several seconds
  40 dnl (more than 10% execution time) to ./configure, with no benefit for
  41 dnl most users.  Using it to look for bugs requires:
  42 dnl   GNULIB_POSIXCHECK=1 autoreconf -f
  43 dnl   ./configure
  44 dnl   make
  45 dnl   make -C src clean
  46 dnl   make CFLAGS=-DGNULIB_POSIXCHECK=1
  47 dnl FIXME: Once we figure out how to avoid false positives, we should
  48 dnl have 'make my-distcheck' in dist-check.mk exercise this.
  49 m4_syscmd([test "${GNULIB_POSIXCHECK+set}" = set])
  50 m4_if(m4_sysval, [0], [], [dnl
  51 gl_ASSERT_NO_GNULIB_POSIXCHECK])
  52
  53 AC_PROG_CC_STDC
  54 AM_PROG_CC_C_O
  55 AC_PROG_CPP
  56 AC_PROG_GCC_TRADITIONAL
  57 AC_PROG_RANLIB
  58 AC_PROG_LN_S
  59 gl_EARLY
  60 gl_INIT
  61 coreutils_MACROS
  62
  63 # The test suite needs to know if we have a working perl.
  64 # FIXME: this is suboptimal.  Ideally, we would be able to call gl_PERL
  65 # with an ACTION-IF-NOT-FOUND argument ...
  66 cu_have_perl=yes
  67 case $PERL in *"/missing "*) cu_have_perl=no;; esac
  68 AM_CONDITIONAL([HAVE_PERL], [test $cu_have_perl = yes])
  69
  70 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
  71 # ------------------------------------------------
  72 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
  73 # Otherwise, run RUN-IF-NOT-FOUND.
  74 AC_DEFUN([gl_GCC_VERSION_IFELSE],
  75   [AC_PREPROC_IFELSE(
  76     [AC_LANG_PROGRAM(
  77       [[
  78 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
  79 /* ok */
  80 #else
  81 # error "your version of gcc is older than $1.$2"
  82 #endif
  83       ]]),
  84     ], [$3], [$4])
  85   ]
  86 )
  87
  88 AC_ARG_ENABLE([gcc-warnings],
  89   [AS_HELP_STRING([--enable-gcc-warnings],
  90      [turn on many GCC warnings (for developers; best with GNU make)])],
  91   [case $enableval in
  92      yes|no) ;;
  93      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  94    esac
  95    gl_gcc_warnings=$enableval],
  96   [
  97    # GCC provides fine-grained control over diagnostics which
  98    # is used in gnulib for example to suppress warnings from
  99    # certain sections of code.  So if this is available and
 100    # we're running from a git repo, then auto enable the warnings.
 101    gl_gcc_warnings=no
 102    gl_GCC_VERSION_IFELSE([4], [6],
 103                          [test -d "$srcdir"/.git && gl_gcc_warnings=yes])]
 104 )
 105
 106 if test "$gl_gcc_warnings" = yes; then
 107   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 108   AC_SUBST([WERROR_CFLAGS])
 109
 110   nw=
 111   # This, $nw, is the list of warnings we disable.
 112   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
 113   nw="$nw -Waggregate-return"       # anachronistic
 114   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 115   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 116   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 117   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 118   nw="$nw -Wcast-qual"              # Too many warnings for now
 119   nw="$nw -Wconversion"             # Too many warnings for now
 120   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 121   nw="$nw -Wsign-conversion"        # Too many warnings for now
 122   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 123   nw="$nw -Wunreachable-code"       # Too many warnings for now
 124   nw="$nw -Wpadded"                 # Our structs are not padded
 125   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 126   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 127   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
 128   nw="$nw -Wvla"                    # warnings in gettext.h
 129   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 130   nw="$nw -Wswitch-enum"            # Too many warnings for now
 131   nw="$nw -Wswitch-default"         # Too many warnings for now
 132   nw="$nw -Wstack-protector"        # not worth working around
 133   # things I might fix soon:
 134   nw="$nw -Wfloat-equal"            # sort.c, seq.c
 135   nw="$nw -Wmissing-format-attribute" # copy.c
 136   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
 137   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
 138   nw="$nw -Wsuggest-attribute=format" # warns about copy.c and factor.c
 139
 140   # Using -Wstrict-overflow is a pain, but the alternative is worse.
 141   # For an example, see the code that provoked this report:
 142   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
 143   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
 144
 145   gl_MANYWARN_ALL_GCC([ws])
 146   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 147   for w in $ws; do
 148     gl_WARN_ADD([$w])
 149   done
 150   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 151   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 152   gl_WARN_ADD([-Wsuggest-attribute=const])
 153   gl_WARN_ADD([-Wsuggest-attribute=noreturn])
 154   gl_WARN_ADD([-Wno-format-nonliteral])
 155
 156   # Enable this warning only with gcc-4.7 and newer.  With 4.6.2 20111027,
 157   # it suggests test.c's advance function may be pure, even though it
 158   # increments a global variable.  Oops.
 159   # Normally we'd write code to test for the precise failure, but that
 160   # requires a relatively large input to make gcc exhibit the failure.
 161   gl_GCC_VERSION_IFELSE([4], [7], [gl_WARN_ADD([-Wsuggest-attribute=pure])])
 162
 163   # In spite of excluding -Wlogical-op above, it is enabled, as of
 164   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 165   gl_WARN_ADD([-Wno-logical-op])
 166
 167   # clang is unduly picky about some things.
 168   AC_CACHE_CHECK([whether the compiler is clang], [utils_cv_clang],
 169     [AC_COMPILE_IFELSE(
 170        [AC_LANG_PROGRAM([[
 171             #ifndef __clang__
 172               #error "not clang"
 173             #endif
 174           ]])],
 175        [utils_cv_clang=yes],
 176        [utils_cv_clang=no])])
 177   if test $utils_cv_clang = yes; then
 178     gl_WARN_ADD([-Wno-format-extra-args])
 179     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 180   fi
 181
 182   gl_WARN_ADD([-fdiagnostics-show-option])
 183   gl_WARN_ADD([-funit-at-a-time])
 184
 185   AC_SUBST([WARN_CFLAGS])
 186
 187   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 188   AH_VERBATIM([FORTIFY_SOURCE],
 189   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 190       without upsetting glibc 2.15+. */
 191    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 192    # define _FORTIFY_SOURCE 2
 193    #endif
 194   ])
 195   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 196
 197   # We use a slightly smaller set of warning options for lib/.
 198   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 199   nw=
 200   nw="$nw -Wstrict-overflow"
 201   nw="$nw -Wuninitialized"
 202   nw="$nw -Wunused-macros"
 203   nw="$nw -Wmissing-prototypes"
 204   nw="$nw -Wold-style-definition"
 205   # FIXME: it may be easy to remove this, since it affects only one file:
 206   # the snprintf call at ftoastr.c:132.
 207   nw="$nw -Wdouble-promotion"
 208   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 209   AC_SUBST([GNULIB_WARN_CFLAGS])
 210
 211   # For gnulib-tests, the set is slightly smaller still.
 212   nw=
 213   nw="$nw -Wstrict-prototypes"
 214   # It's not worth being this picky about test programs.
 215   nw="$nw -Wsuggest-attribute=const"
 216   nw="$nw -Wsuggest-attribute=pure"
 217   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 218                          [$GNULIB_WARN_CFLAGS], [$nw])
 219   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 220 fi
 221
 222 AC_FUNC_FORK
 223
 224 optional_bin_progs=
 225 AC_CHECK_FUNCS([chroot],
 226         gl_ADD_PROG([optional_bin_progs], [chroot]))
 227 AC_CHECK_FUNCS([gethostid],
 228         gl_ADD_PROG([optional_bin_progs], [hostid]))
 229
 230 gl_WINSIZE_IN_PTEM
 231
 232 AC_MSG_CHECKING([whether localtime caches TZ])
 233 AC_CACHE_VAL([utils_cv_localtime_cache],
 234 [if test x$ac_cv_func_tzset = xyes; then
 235 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 236 #if STDC_HEADERS
 237 # include <stdlib.h>
 238 #endif
 239 extern char **environ;
 240 void unset_TZ (void)
 241 {
 242   char **from, **to;
 243   for (to = from = environ; (*to = *from); from++)
 244     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 245       to++;
 246 }
 247 int main()
 248 {
 249   time_t now = time ((time_t *) 0);
 250   int hour_GMT0, hour_unset;
 251   if (putenv ("TZ=GMT0") != 0)
 252     return 1;
 253   hour_GMT0 = localtime (&now)->tm_hour;
 254   unset_TZ ();
 255   hour_unset = localtime (&now)->tm_hour;
 256   if (putenv ("TZ=PST8") != 0)
 257     return 1;
 258   if (localtime (&now)->tm_hour == hour_GMT0)
 259     return 1;
 260   unset_TZ ();
 261   if (localtime (&now)->tm_hour != hour_unset)
 262     return 1;
 263   return 0;
 264 }]])],
 265 [utils_cv_localtime_cache=no],
 266 [utils_cv_localtime_cache=yes],
 267 [# If we have tzset, assume the worst when cross-compiling.
 268 utils_cv_localtime_cache=yes])
 269 else
 270         # If we lack tzset, report that localtime does not cache TZ,
 271         # since we can't invalidate the cache if we don't have tzset.
 272         utils_cv_localtime_cache=no
 273 fi])dnl
 274 AC_MSG_RESULT([$utils_cv_localtime_cache])
 275 if test $utils_cv_localtime_cache = yes; then
 276   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 277 fi
 278
 279 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 280 AC_CHECK_FUNCS([initgroups])
 281 if test $ac_cv_func_initgroups = no; then
 282   AC_CHECK_LIB([os], [initgroups])
 283 fi
 284
 285 AC_CHECK_FUNCS([syslog])
 286 if test $ac_cv_func_syslog = no; then
 287   # syslog is not in the default libraries.  See if it's in some other.
 288   for lib in bsd socket inet; do
 289     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 290       LIBS="$LIBS -l$lib"; break])
 291   done
 292 fi
 293
 294 AC_CACHE_CHECK([for 3-argument setpriority function],
 295   [utils_cv_func_setpriority],
 296   [AC_LINK_IFELSE(
 297     [AC_LANG_PROGRAM(
 298        [[#include <sys/time.h>
 299          #include <sys/resource.h>
 300        ]],
 301        [[setpriority (0, 0, 0);]])],
 302     [utils_cv_func_setpriority=yes],
 303     [utils_cv_func_setpriority=no])])
 304 if test $utils_cv_func_setpriority = no; then
 305   AC_CHECK_FUNCS([nice])
 306 fi
 307 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 308 *yes*)
 309   gl_ADD_PROG([optional_bin_progs], [nice])
 310 esac
 311
 312 AC_DEFUN([coreutils_DUMMY_1],
 313 [
 314   AC_REQUIRE([gl_READUTMP])
 315   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 316     gl_ADD_PROG([optional_bin_progs], [who])
 317     gl_ADD_PROG([optional_bin_progs], [users])
 318     gl_ADD_PROG([optional_bin_progs], [pinky])
 319   fi
 320 ])
 321 coreutils_DUMMY_1
 322
 323 AC_MSG_CHECKING([ut_host in struct utmp])
 324 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 325 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 326 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 327   [su_cv_func_ut_host_in_utmp=yes],
 328   [su_cv_func_ut_host_in_utmp=no])])
 329 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 330 if test $su_cv_func_ut_host_in_utmp = yes; then
 331   have_ut_host=1
 332   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 333 fi
 334
 335 if test -z "$have_ut_host"; then
 336   AC_MSG_CHECKING([ut_host in struct utmpx])
 337   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 338   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 339 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 340     [su_cv_func_ut_host_in_utmpx=yes],
 341     [su_cv_func_ut_host_in_utmpx=no])])
 342   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 343   if test $su_cv_func_ut_host_in_utmpx = yes; then
 344     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 345     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 346   fi
 347 fi
 348
 349 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 350
 351 AC_SYS_POSIX_TERMIOS()
 352 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 353
 354 if test $ac_cv_sys_posix_termios = yes; then
 355   gl_ADD_PROG([optional_bin_progs], [stty])
 356
 357   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 358   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 359   [AC_EGREP_CPP([yes], [#include <termios.h>
 360 #ifdef IUCLC
 361 yes
 362 #endif], su_cv_sys_termios_needs_xopen_source=no,
 363    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 364 #include <termios.h>
 365 #ifdef IUCLC
 366 yes
 367 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 368    su_cv_sys_termios_needs_xopen_source=no))])
 369   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 370   test $su_cv_sys_termios_needs_xopen_source = yes &&
 371     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 372
 373   AC_MSG_CHECKING([c_line in struct termios])
 374   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 375   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 376 #define _XOPEN_SOURCE
 377 #endif
 378 #include <sys/types.h>
 379 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 380     [su_cv_sys_c_line_in_termios=yes],
 381     [su_cv_sys_c_line_in_termios=no])])
 382   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 383   test $su_cv_sys_c_line_in_termios = yes \
 384     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 385 fi
 386
 387 # FIXME: note that this macro appears above, too.
 388 # I'm leaving it here for now.  This whole thing needs to be modernized...
 389 gl_WINSIZE_IN_PTEM
 390
 391 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 392
 393 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 394    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 395   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 396   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 397   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 398 #ifdef WINSIZE_IN_PTEM
 399 # include <sys/stream.h>
 400 # include <sys/ptem.h>
 401 #endif
 402 #include <sys/ioctl.h>
 403 #include <sys/tty.h>
 404 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 405     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 406     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 407   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 408
 409   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 410       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 411                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 412 fi
 413
 414 # For src/kill.c.
 415 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 416   [AC_INCLUDES_DEFAULT
 417 #include <signal.h>])
 418
 419 cu_GMP
 420
 421 # Build df only if there's a point to it.
 422 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 423   gl_ADD_PROG([optional_bin_progs], [df])
 424 fi
 425
 426 # Limit stdbuf to ELF systems with GCC
 427 AC_MSG_CHECKING([whether this is an ELF system])
 428 AC_EGREP_CPP([yes], [#if __ELF__
 429 yes
 430 #endif], [elf_sys=yes], [elf_sys=no])
 431 AC_MSG_RESULT([$elf_sys])
 432 if test "$elf_sys" = "yes" && \
 433    test "$GCC" = "yes"; then
 434   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 435 fi
 436
 437 ############################################################################
 438
 439 dnl Autogenerated by the 'gen-lists-of-programs.sh' auxiliary script.
 440 dnl Issue proper calls to the macros gl_INCLUDE_EXCLUDE_PROG and
 441 dnl gl_ADD_PROG (updating $optional_bin_progs), and generate the list
 442 dnl of coreutils programs to be built only upon explicit user request,
 443 dnl saving that list in the $no_install_progs_default shell variable.
 444 m4_include([m4/cu-progs.m4])
 445
 446 # Now that we know which programs will actually be built, determine
 447 # which optional helper progs should be compiled.
 448 case " $optional_bin_progs " in
 449   *' stdbuf '*) pkglibexec_PROGRAMS='src/libstdbuf.so';;
 450   *) pkglibexec_PROGRAMS='';;
 451 esac
 452
 453 man1_MANS=`
 454   for p in $optional_bin_progs; do
 455     # Change "ginstall.1" to "install.1".
 456     test $p = ginstall && p=install
 457     # Ignore the "[" program, since writing a portable make rule to
 458     # generate its manpage is not practical.
 459     dnl Use the autoconf-provided quadrigraph to represent "[",
 460     dnl otherwise we will incur in dreadful quoting issues.
 461     test x$p = x'@<:@' && continue
 462     echo "man/$p.1"
 463   done`
 464
 465 # Not installed by "make install", but must be built when creating
 466 # a distribution tarball.
 467 EXTRA_MANS=`for p in $no_install_progs_default; do echo man/$p.1; done`
 468
 469 # The programs built and installed by "make && make install".
 470 # Since this is AC_SUBST'd, Automake won't be able to perform rewrite
 471 # with $(EXEEXT) appending on it, so we have to do it ourselves -- in
 472 # this case, only for $(bin_PROGRAMS).
 473 bin_PROGRAMS=`
 474   for p in $optional_bin_progs; do echo src/"$p"'$(EXEEXT)'; done`
 475
 476 # Normalize whitespace.
 477 man1_MANS=`echo $man1_MANS`
 478 EXTRA_MANS=`echo $EXTRA_MANS`
 479 bin_PROGRAMS=`echo $bin_PROGRAMS`
 480 pkglibexec_PROGS=`echo $pkglibexec_PROGRAMS`
 481
 482 AC_SUBST([bin_PROGRAMS])        AM_SUBST_NOTMAKE([bin_PROGRAMS])
 483 AC_SUBST([pkglibexec_PROGRAMS]) AM_SUBST_NOTMAKE([pkglibexec_PROGRAMS])
 484 AC_SUBST([man1_MANS])           AM_SUBST_NOTMAKE([man1_MANS])
 485 AC_SUBST([EXTRA_MANS])          AM_SUBST_NOTMAKE([EXTRA_MANS])
 486
 487 AC_SUBST([built_programs], [$optional_bin_progs])
 488
 489 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 490
 491 ############################################################################
 492
 493 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 494 # translatable strings, we must use need-formatstring-macros here.
 495 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 496 AM_GNU_GETTEXT_VERSION([0.18.1])
 497
 498 # For a test of uniq: it uses the $LOCALE_FR envvar.
 499 gt_LOCALE_FR
 500
 501 AC_CONFIG_FILES(
 502   Makefile
 503   po/Makefile.in
 504   gnulib-tests/Makefile
 505   )
 506 AC_OUTPUT