src/soc/amd/common/block/cpu/noncar/memlayout_psp_verstage.ld

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2
   3 #include <memlayout.h>
   4 #include <soc/psp_transfer.h>
   5 #include <fmap_config.h>
   6 #include <soc/psp_verstage_addr.h>
   7
   8 ENTRY(_psp_vs_start)
   9 SECTIONS
  10 {
  11         SRAM_START(PSP_SRAM_START)
  12         _verstage = .;
  13
  14                 .text : { *(PSP_HEADER_DATA) }
  15                 .text : { *(.text._psp_vs_start) }
  16                 .text : { *(.text.Main) }
  17                 .text : { *(.text*) }
  18                 .rodata : { *(.rodata*) }
  19
  20                 .data : { *(.data*) }
  21                 .data : { *(PSP_FOOTER_DATA) }
  22
  23                 _bss_start = .;
  24                 .bss : { *(.bss*) }
  25                 _bss_end = .;
  26
  27         ALIGN_COUNTER(64)
  28         _everstage = .;
  29
  30         #include "memlayout_transfer_buffer.inc"
  31
  32 #if defined(PSP_VERSTAGE_TEMP_STACK_START)
  33         PSP_VERSTAGE_TEMP_STACK_END = (PSP_VERSTAGE_TEMP_STACK_START + PSP_VERSTAGE_TEMP_STACK_SIZE );
  34 #endif
  35
  36         REGION(stack, PSP_VERSTAGE_STACK_START, PSP_VERSTAGE_STACK_SIZE, 64)
  37         PSP_VERSTAGE_STACK_BASE = _stack;
  38         PSP_VERSTAGE_STACK_END = _estack;
  39         SRAM_END(PSP_SRAM_START + PSP_SRAM_SIZE)
  40 }