src/soc/intel/broadwell/acpi/ctdp.asl

   1 /*
   2  * This file is part of the coreboot project.
   3  *
   4  *
   5  * This program is free software; you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation; version 2 of the License.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  */
  14
  15 Scope (\_SB.PCI0.MCHC)
  16 {
  17         Mutex (CTCM, 1)         /* CTDP Switch Mutex (sync level 1) */
  18         Name (CTCC, 0)          /* CTDP Current Selection */
  19         Name (CTCN, 0)          /* CTDP Nominal Select */
  20         Name (CTCD, 1)          /* CTDP Down Select */
  21         Name (CTCU, 2)          /* CTDP Up Select */
  22         Name (SPL1, 0)          /* Saved PL1 value */
  23
  24         OperationRegion (MCHB, SystemMemory,
  25                         Add (MCH_BASE_ADDRESS, 0x5000), 0x1000)
  26         Field (MCHB, DWordAcc, Lock, Preserve)
  27         {
  28                 Offset (0x930), /* PACKAGE_POWER_SKU */
  29                 CTDN, 15,       /* CTDP Nominal PL1 */
  30                 Offset (0x938), /* PACKAGE_POWER_SKU_UNIT */
  31                 PUNI, 4,        /* Power Units */
  32                 ,     4,
  33                 EUNI, 5,        /* Energy Units */
  34                 ,     3,
  35                 TUNI, 4,        /* Time Units */
  36                 Offset (0x958), /* PLATFORM_INFO */
  37                 ,     40,
  38                 LFM_, 8,        /* Maximum Efficiency Ratio (LFM) */
  39                 Offset (0x9a0), /* TURBO_POWER_LIMIT1 */
  40                 PL1V, 15,       /* Power Limit 1 Value */
  41                 PL1E, 1,        /* Power Limit 1 Enable */
  42                 PL1C, 1,        /* Power Limit 1 Clamp */
  43                 PL1T, 7,        /* Power Limit 1 Time */
  44                 Offset (0x9a4), /* TURBO_POWER_LIMIT2 */
  45                 PL2V, 15,       /* Power Limit 2 Value */
  46                 PL2E, 1,        /* Power Limit 2 Enable */
  47                 PL2C, 1,        /* Power Limit 2 Clamp */
  48                 PL2T, 7,        /* Power Limit 2 Time */
  49                 Offset (0xf3c), /* CONFIG_TDP_NOMINAL */
  50                 TARN, 8,        /* CTDP Nominal Turbo Activation Ratio */
  51                 Offset (0xf40), /* CONFIG_TDP_LEVEL1 */
  52                 CTDD, 15,       /* CTDP Down PL1 */
  53                 ,     1,
  54                 TARD, 8,        /* CTDP Down Turbo Activation Ratio */
  55                 Offset (0xf48), /* MSR_CONFIG_TDP_LEVEL2 */
  56                 CTDU, 15,       /* CTDP Up PL1 */
  57                 ,     1,
  58                 TARU, 8,        /* CTDP Up Turbo Activation Ratio */
  59                 Offset (0xf50), /* CONFIG_TDP_CONTROL */
  60                 CTCS, 2,        /* CTDP Select */
  61                 Offset (0xf54), /* TURBO_ACTIVATION_RATIO */
  62                 TARS, 8,        /* Turbo Activation Ratio Select */
  63         }
  64
  65         /*
  66          * Search CPU0 _PSS looking for control=arg0 and then
  67          * return previous P-state entry number for new _PPC
  68          *
  69          * Format of _PSS:
  70          *   Name (_PSS, Package () {
  71          *     Package (6) { freq, power, tlat, blat, control, status }
  72          *   }
  73          */
  74         External (\_PR.CP00._PSS)
  75         Method (PSSS, 1, NotSerialized)
  76         {
  77                 Store (One, Local0) /* Start at P1 */
  78                 Store (SizeOf (\_PR.CP00._PSS), Local1)
  79
  80                 While (LLess (Local0, Local1)) {
  81                         /* Store _PSS entry Control value to Local2 */
  82                         ShiftRight (DeRefOf (Index (DeRefOf (Index
  83                               (\_PR.CP00._PSS, Local0)), 4)), 8, Local2)
  84                         If (LEqual (Local2, Arg0)) {
  85                                 Return (Subtract (Local0, 1))
  86                         }
  87                         Increment (Local0)
  88                 }
  89
  90                 Return (0)
  91         }
  92
  93         /* Calculate PL2 based on chip type */
  94         Method (CPL2, 1, NotSerialized)
  95         {
  96                 /* Haswell ULT PL2 = 25W */
  97                 /* FIXME: update for broadwell */
  98                 Return (Multiply (25, 8))
  99         }
 100
 101         /* Set Config TDP Down */
 102         Method (STND, 0, Serialized)
 103         {
 104                 If (Acquire (CTCM, 100)) {
 105                         Return (0)
 106                 }
 107                 If (LEqual (CTCD, CTCC)) {
 108                         Release (CTCM)
 109                         Return (0)
 110                 }
 111
 112                 Store ("Set TDP Down", Debug)
 113
 114                 /* Set CTC */
 115                 Store (CTCD, CTCS)
 116
 117                 /* Set TAR */
 118                 Store (TARD, TARS)
 119
 120                 /* Set PPC limit and notify OS */
 121                 Store (PSSS (TARD), PPCM)
 122                 PPCN ()
 123
 124                 /* Set PL2 */
 125                 Store (CPL2 (CTDD), PL2V)
 126
 127                 /* Set PL1 */
 128                 Store (CTDD, PL1V)
 129
 130                 /* Store the new TDP Down setting */
 131                 Store (CTCD, CTCC)
 132
 133                 Release (CTCM)
 134                 Return (1)
 135         }
 136
 137         /* Set Config TDP Nominal from Down */
 138         Method (STDN, 0, Serialized)
 139         {
 140                 If (Acquire (CTCM, 100)) {
 141                         Return (0)
 142                 }
 143                 If (LEqual (CTCN, CTCC)) {
 144                         Release (CTCM)
 145                         Return (0)
 146                 }
 147
 148                 Store ("Set TDP Nominal", Debug)
 149
 150                 /* Set PL1 */
 151                 Store (CTDN, PL1V)
 152
 153                 /* Set PL2 */
 154                 Store (CPL2 (CTDN), PL2V)
 155
 156                 /* Set PPC limit and notify OS */
 157                 Store (PSSS (TARN), PPCM)
 158                 PPCN ()
 159
 160                 /* Set TAR */
 161                 Store (TARN, TARS)
 162
 163                 /* Set CTC */
 164                 Store (CTCN, CTCS)
 165
 166                 /* Store the new TDP Nominal setting */
 167                 Store (CTCN, CTCC)
 168
 169                 Release (CTCM)
 170                 Return (1)
 171         }
 172
 173         /* Calculate PL1 value based on requested TDP */
 174         Method (TDPP, 1, NotSerialized)
 175         {
 176                 Return (Multiply (ShiftLeft (Subtract (PUNI, 1), 2), Arg0))
 177         }
 178
 179         /* Enable Controllable TDP to limit PL1 to requested value */
 180         Method (CTLE, 1, Serialized)
 181         {
 182                 If (Acquire (CTCM, 100)) {
 183                         Return (0)
 184                 }
 185
 186                 Store ("Enable PL1 Limit", Debug)
 187
 188                 /* Set _PPC to LFM */
 189                 Store (PSSS (LFM_), Local0)
 190                 Add (Local0, 1, PPCM)
 191                 \PPCN ()
 192
 193                 /* Set TAR to LFM-1 */
 194                 Subtract (LFM_, 1, TARS)
 195
 196                 /* Set PL1 to desired value */
 197                 Store (PL1V, SPL1)
 198                 Store (TDPP (Arg0), PL1V)
 199
 200                 /* Set PL1 CLAMP bit */
 201                 Store (One, PL1C)
 202
 203                 Release (CTCM)
 204                 Return (1)
 205         }
 206
 207         /* Disable Controllable TDP */
 208         Method (CTLD, 0, Serialized)
 209         {
 210                 If (Acquire (CTCM, 100)) {
 211                         Return (0)
 212                 }
 213
 214                 Store ("Disable PL1 Limit", Debug)
 215
 216                 /* Clear PL1 CLAMP bit */
 217                 Store (Zero, PL1C)
 218
 219                 /* Set PL1 to normal value */
 220                 Store (SPL1, PL1V)
 221
 222                 /* Set TAR to 0 */
 223                 Store (Zero, TARS)
 224
 225                 /* Set _PPC to 0 */
 226                 Store (Zero, PPCM)
 227                 \PPCN ()
 228
 229                 Release (CTCM)
 230                 Return (1)
 231         }
 232 }