src/mainboard/kontron/ktqm77/acpi/thermal.asl

   1 /*
   2  * This file is part of the coreboot project.
   3  *
   4  *
   5  * This program is free software; you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation; version 2 of the License.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  */
  14
  15 // Thermal Zone
  16
  17 External (\PPKG, MethodObj)
  18
  19 #define HAVE_THERMALZONE
  20 Scope (\_TZ)
  21 {
  22         ThermalZone (THRM)
  23         {
  24                 Name (_TC1, 0x02)
  25                 Name (_TC2, 0x05)
  26
  27                 // Thermal zone polling frequency: 10 seconds
  28                 Name (_TZP, 100)
  29
  30                 // Thermal sampling period for passive cooling: 2 seconds
  31                 Name (_TSP, 20)
  32
  33                 // Convert from Degrees C to 1/10 Kelvin for ACPI
  34                 Method (CTOK, 1) {
  35                         // 10th of Degrees C
  36                         Multiply (Arg0, 10, Local0)
  37
  38                         // Convert to Kelvin
  39                         Add (Local0, 2732, Local0)
  40
  41                         Return (Local0)
  42                 }
  43
  44                 // Threshold for OS to shutdown
  45                 Method (_CRT, 0, Serialized)
  46                 {
  47                         Return (CTOK (\TCRT))
  48                 }
  49
  50                 // Threshold for passive cooling
  51                 Method (_PSV, 0, Serialized)
  52                 {
  53                         Return (CTOK (\TPSV))
  54                 }
  55
  56                 // Processors used for passive cooling
  57                 Method (_PSL, 0, Serialized)
  58                 {
  59                         Return (\PPKG ())
  60                 }
  61
  62                 Method (_TMP, 0, Serialized)
  63                 {
  64                         // Return CPU Temperature from EC
  65                         Return (\_SB.PCI0.LPCB.EC0.PM1.CTK ())
  66                 }
  67
  68 // The EC does all fan control. There is no Active Cooling Fan control (_ACx).
  69         }
  70 }