scripts/kernel-doc

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 use warnings;
   5 use strict;
   6
   7 ## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
   8 ## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
   9 ## Copyright (C) 2001  Simon Huggins                             ##
  10 ## Copyright (C) 2005-2012  Randy Dunlap                         ##
  11 ## Copyright (C) 2012  Dan Luedtke                               ##
  12 ##                                                               ##
  13 ## #define enhancements by Armin Kuster <akuster@mvista.com>     ##
  14 ## Copyright (c) 2000 MontaVista Software, Inc.                  ##
  15 ##                                                               ##
  16 ## This software falls under the GNU General Public License.     ##
  17 ## Please read the COPYING file for more information             ##
  18
  19 # 18/01/2001 -  Cleanups
  20 #               Functions prototyped as foo(void) same as foo()
  21 #               Stop eval'ing where we don't need to.
  22 # -- huggie@earth.li
  23
  24 # 27/06/2001 -  Allowed whitespace after initial "/**" and
  25 #               allowed comments before function declarations.
  26 # -- Christian Kreibich <ck@whoop.org>
  27
  28 # Still to do:
  29 #       - add perldoc documentation
  30 #       - Look more closely at some of the scarier bits :)
  31
  32 # 26/05/2001 -  Support for separate source and object trees.
  33 #               Return error code.
  34 #               Keith Owens <kaos@ocs.com.au>
  35
  36 # 23/09/2001 - Added support for typedefs, structs, enums and unions
  37 #              Support for Context section; can be terminated using empty line
  38 #              Small fixes (like spaces vs. \s in regex)
  39 # -- Tim Jansen <tim@tjansen.de>
  40
  41 # 25/07/2012 - Added support for HTML5
  42 # -- Dan Luedtke <mail@danrl.de>
  43
  44 sub usage {
  45     my $message = <<"EOF";
  46 Usage: $0 [OPTION ...] FILE ...
  47
  48 Read C language source or header FILEs, extract embedded documentation comments,
  49 and print formatted documentation to standard output.
  50
  51 The documentation comments are identified by "/**" opening comment mark. See
  52 Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
  53
  54 Output format selection (mutually exclusive):
  55   -man                  Output troff manual page format. This is the default.
  56   -rst                  Output reStructuredText format.
  57   -none                 Do not output documentation, only warnings.
  58
  59 Output selection (mutually exclusive):
  60   -export               Only output documentation for symbols that have been
  61                         exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
  62                         in any input FILE or -export-file FILE.
  63   -internal             Only output documentation for symbols that have NOT been
  64                         exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
  65                         in any input FILE or -export-file FILE.
  66   -function NAME        Only output documentation for the given function(s)
  67                         or DOC: section title(s). All other functions and DOC:
  68                         sections are ignored. May be specified multiple times.
  69   -nofunction NAME      Do NOT output documentation for the given function(s);
  70                         only output documentation for the other functions and
  71                         DOC: sections. May be specified multiple times.
  72
  73 Output selection modifiers:
  74   -no-doc-sections      Do not output DOC: sections.
  75   -enable-lineno        Enable output of #define LINENO lines. Only works with
  76                         reStructuredText format.
  77   -export-file FILE     Specify an additional FILE in which to look for
  78                         EXPORT_SYMBOL() and EXPORT_SYMBOL_GPL(). To be used with
  79                         -export or -internal. May be specified multiple times.
  80
  81 Other parameters:
  82   -v                    Verbose output, more warnings and other information.
  83   -h                    Print this help.
  84
  85 EOF
  86     print $message;
  87     exit 1;
  88 }
  89
  90 #
  91 # format of comments.
  92 # In the following table, (...)? signifies optional structure.
  93 #                         (...)* signifies 0 or more structure elements
  94 # /**
  95 #  * function_name(:)? (- short description)?
  96 # (* @parameterx: (description of parameter x)?)*
  97 # (* a blank line)?
  98 #  * (Description:)? (Description of function)?
  99 #  * (section header: (section description)? )*
 100 #  (*)?*/
 101 #
 102 # So .. the trivial example would be:
 103 #
 104 # /**
 105 #  * my_function
 106 #  */
 107 #
 108 # If the Description: header tag is omitted, then there must be a blank line
 109 # after the last parameter specification.
 110 # e.g.
 111 # /**
 112 #  * my_function - does my stuff
 113 #  * @my_arg: its mine damnit
 114 #  *
 115 #  * Does my stuff explained.
 116 #  */
 117 #
 118 #  or, could also use:
 119 # /**
 120 #  * my_function - does my stuff
 121 #  * @my_arg: its mine damnit
 122 #  * Description: Does my stuff explained.
 123 #  */
 124 # etc.
 125 #
 126 # Besides functions you can also write documentation for structs, unions,
 127 # enums and typedefs. Instead of the function name you must write the name
 128 # of the declaration;  the struct/union/enum/typedef must always precede
 129 # the name. Nesting of declarations is not supported.
 130 # Use the argument mechanism to document members or constants.
 131 # e.g.
 132 # /**
 133 #  * struct my_struct - short description
 134 #  * @a: first member
 135 #  * @b: second member
 136 #  *
 137 #  * Longer description
 138 #  */
 139 # struct my_struct {
 140 #     int a;
 141 #     int b;
 142 # /* private: */
 143 #     int c;
 144 # };
 145 #
 146 # All descriptions can be multiline, except the short function description.
 147 #
 148 # For really longs structs, you can also describe arguments inside the
 149 # body of the struct.
 150 # eg.
 151 # /**
 152 #  * struct my_struct - short description
 153 #  * @a: first member
 154 #  * @b: second member
 155 #  *
 156 #  * Longer description
 157 #  */
 158 # struct my_struct {
 159 #     int a;
 160 #     int b;
 161 #     /**
 162 #      * @c: This is longer description of C
 163 #      *
 164 #      * You can use paragraphs to describe arguments
 165 #      * using this method.
 166 #      */
 167 #     int c;
 168 # };
 169 #
 170 # This should be use only for struct/enum members.
 171 #
 172 # You can also add additional sections. When documenting kernel functions you
 173 # should document the "Context:" of the function, e.g. whether the functions
 174 # can be called form interrupts. Unlike other sections you can end it with an
 175 # empty line.
 176 # A non-void function should have a "Return:" section describing the return
 177 # value(s).
 178 # Example-sections should contain the string EXAMPLE so that they are marked
 179 # appropriately in DocBook.
 180 #
 181 # Example:
 182 # /**
 183 #  * user_function - function that can only be called in user context
 184 #  * @a: some argument
 185 #  * Context: !in_interrupt()
 186 #  *
 187 #  * Some description
 188 #  * Example:
 189 #  *    user_function(22);
 190 #  */
 191 # ...
 192 #
 193 #
 194 # All descriptive text is further processed, scanning for the following special
 195 # patterns, which are highlighted appropriately.
 196 #
 197 # 'funcname()' - function
 198 # '$ENVVAR' - environmental variable
 199 # '&struct_name' - name of a structure (up to two words including 'struct')
 200 # '&struct_name.member' - name of a structure member
 201 # '@parameter' - name of a parameter
 202 # '%CONST' - name of a constant.
 203 # '``LITERAL``' - literal string without any spaces on it.
 204
 205 ## init lots of data
 206
 207 my $errors = 0;
 208 my $warnings = 0;
 209 my $anon_struct_union = 0;
 210
 211 # match expressions used to find embedded type information
 212 my $type_constant = '\b``([^\`]+)``\b';
 213 my $type_constant2 = '\%([-_\w]+)';
 214 my $type_func = '(\w+)\(\)';
 215 my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
 216 my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
 217 my $type_env = '(\$\w+)';
 218 my $type_enum = '\&(enum\s*([_\w]+))';
 219 my $type_struct = '\&(struct\s*([_\w]+))';
 220 my $type_typedef = '\&(typedef\s*([_\w]+))';
 221 my $type_union = '\&(union\s*([_\w]+))';
 222 my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
 223 my $type_fallback = '\&([_\w]+)';
 224 my $type_member_func = $type_member . '\(\)';
 225
 226 # Output conversion substitutions.
 227 #  One for each output format
 228
 229 # these are pretty rough
 230 my @highlights_man = (
 231                       [$type_constant, "\$1"],
 232                       [$type_constant2, "\$1"],
 233                       [$type_func, "\\\\fB\$1\\\\fP"],
 234                       [$type_enum, "\\\\fI\$1\\\\fP"],
 235                       [$type_struct, "\\\\fI\$1\\\\fP"],
 236                       [$type_typedef, "\\\\fI\$1\\\\fP"],
 237                       [$type_union, "\\\\fI\$1\\\\fP"],
 238                       [$type_param, "\\\\fI\$1\\\\fP"],
 239                       [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
 240                       [$type_fallback, "\\\\fI\$1\\\\fP"]
 241                      );
 242 my $blankline_man = "";
 243
 244 # rst-mode
 245 my @highlights_rst = (
 246                        [$type_constant, "``\$1``"],
 247                        [$type_constant2, "``\$1``"],
 248                        # Note: need to escape () to avoid func matching later
 249                        [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
 250                        [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
 251                        [$type_fp_param, "**\$1\\\\(\\\\)**"],
 252                        [$type_func, "\$1()"],
 253                        [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
 254                        [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
 255                        [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
 256                        [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
 257                        # in rst this can refer to any type
 258                        [$type_fallback, "\\:c\\:type\\:`\$1`"],
 259                        [$type_param, "**\$1**"]
 260                       );
 261 my $blankline_rst = "\n";
 262
 263 # read arguments
 264 if ($#ARGV == -1) {
 265     usage();
 266 }
 267
 268 my $kernelversion;
 269 my $dohighlight = "";
 270
 271 my $verbose = 0;
 272 my $output_mode = "rst";
 273 my $output_preformatted = 0;
 274 my $no_doc_sections = 0;
 275 my $enable_lineno = 0;
 276 my @highlights = @highlights_rst;
 277 my $blankline = $blankline_rst;
 278 my $modulename = "Kernel API";
 279
 280 use constant {
 281     OUTPUT_ALL          => 0, # output all symbols and doc sections
 282     OUTPUT_INCLUDE      => 1, # output only specified symbols
 283     OUTPUT_EXCLUDE      => 2, # output everything except specified symbols
 284     OUTPUT_EXPORTED     => 3, # output exported symbols
 285     OUTPUT_INTERNAL     => 4, # output non-exported symbols
 286 };
 287 my $output_selection = OUTPUT_ALL;
 288 my $show_not_found = 0; # No longer used
 289
 290 my @export_file_list;
 291
 292 my @build_time;
 293 if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
 294     (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
 295     @build_time = gmtime($seconds);
 296 } else {
 297     @build_time = localtime;
 298 }
 299
 300 my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
 301                 'July', 'August', 'September', 'October',
 302                 'November', 'December')[$build_time[4]] .
 303   " " . ($build_time[5]+1900);
 304
 305 # Essentially these are globals.
 306 # They probably want to be tidied up, made more localised or something.
 307 # CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
 308 # could cause "use of undefined value" or other bugs.
 309 my ($function, %function_table, %parametertypes, $declaration_purpose);
 310 my $declaration_start_line;
 311 my ($type, $declaration_name, $return_type);
 312 my ($newsection, $newcontents, $prototype, $brcount, %source_map);
 313
 314 if (defined($ENV{'KBUILD_VERBOSE'})) {
 315         $verbose = "$ENV{'KBUILD_VERBOSE'}";
 316 }
 317
 318 # Generated docbook code is inserted in a template at a point where
 319 # docbook v3.1 requires a non-zero sequence of RefEntry's; see:
 320 # http://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
 321 # We keep track of number of generated entries and generate a dummy
 322 # if needs be to ensure the expanded template can be postprocessed
 323 # into html.
 324 my $section_counter = 0;
 325
 326 my $lineprefix="";
 327
 328 # Parser states
 329 use constant {
 330     STATE_NORMAL        => 0, # normal code
 331     STATE_NAME          => 1, # looking for function name
 332     STATE_BODY_MAYBE    => 2, # body - or maybe more description
 333     STATE_BODY          => 3, # the body of the comment
 334     STATE_PROTO         => 4, # scanning prototype
 335     STATE_DOCBLOCK      => 5, # documentation block
 336     STATE_INLINE        => 6, # gathering documentation outside main block
 337 };
 338 my $state;
 339 my $in_doc_sect;
 340 my $leading_space;
 341
 342 # Inline documentation state
 343 use constant {
 344     STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
 345     STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
 346     STATE_INLINE_TEXT   => 2, # looking for member documentation
 347     STATE_INLINE_END    => 3, # done
 348     STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
 349                               # Spit a warning as it's not
 350                               # proper kernel-doc and ignore the rest.
 351 };
 352 my $inline_doc_state;
 353
 354 #declaration types: can be
 355 # 'function', 'struct', 'union', 'enum', 'typedef'
 356 my $decl_type;
 357
 358 my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
 359 my $doc_end = '\*/';
 360 my $doc_com = '\s*\*\s*';
 361 my $doc_com_body = '\s*\* ?';
 362 my $doc_decl = $doc_com . '(\w+)';
 363 # @params and a strictly limited set of supported section names
 364 my $doc_sect = $doc_com .
 365     '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:(.*)';
 366 my $doc_content = $doc_com_body . '(.*)';
 367 my $doc_block = $doc_com . 'DOC:\s*(.*)?';
 368 my $doc_inline_start = '^\s*/\*\*\s*$';
 369 my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
 370 my $doc_inline_end = '^\s*\*/\s*$';
 371 my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
 372 my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
 373
 374 my %parameterdescs;
 375 my %parameterdesc_start_lines;
 376 my @parameterlist;
 377 my %sections;
 378 my @sectionlist;
 379 my %section_start_lines;
 380 my $sectcheck;
 381 my $struct_actual;
 382
 383 my $contents = "";
 384 my $new_start_line = 0;
 385
 386 # the canonical section names. see also $doc_sect above.
 387 my $section_default = "Description";    # default section
 388 my $section_intro = "Introduction";
 389 my $section = $section_default;
 390 my $section_context = "Context";
 391 my $section_return = "Return";
 392
 393 my $undescribed = "-- undescribed --";
 394
 395 reset_state();
 396
 397 while ($ARGV[0] =~ m/^--?(.*)/) {
 398     my $cmd = $1;
 399     shift @ARGV;
 400     if ($cmd eq "man") {
 401         $output_mode = "man";
 402         @highlights = @highlights_man;
 403         $blankline = $blankline_man;
 404     } elsif ($cmd eq "rst") {
 405         $output_mode = "rst";
 406         @highlights = @highlights_rst;
 407         $blankline = $blankline_rst;
 408     } elsif ($cmd eq "none") {
 409         $output_mode = "none";
 410     } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
 411         $modulename = shift @ARGV;
 412     } elsif ($cmd eq "function") { # to only output specific functions
 413         $output_selection = OUTPUT_INCLUDE;
 414         $function = shift @ARGV;
 415         $function_table{$function} = 1;
 416     } elsif ($cmd eq "nofunction") { # output all except specific functions
 417         $output_selection = OUTPUT_EXCLUDE;
 418         $function = shift @ARGV;
 419         $function_table{$function} = 1;
 420     } elsif ($cmd eq "export") { # only exported symbols
 421         $output_selection = OUTPUT_EXPORTED;
 422         %function_table = ();
 423     } elsif ($cmd eq "internal") { # only non-exported symbols
 424         $output_selection = OUTPUT_INTERNAL;
 425         %function_table = ();
 426     } elsif ($cmd eq "export-file") {
 427         my $file = shift @ARGV;
 428         push(@export_file_list, $file);
 429     } elsif ($cmd eq "v") {
 430         $verbose = 1;
 431     } elsif (($cmd eq "h") || ($cmd eq "help")) {
 432         usage();
 433     } elsif ($cmd eq 'no-doc-sections') {
 434             $no_doc_sections = 1;
 435     } elsif ($cmd eq 'enable-lineno') {
 436             $enable_lineno = 1;
 437     } elsif ($cmd eq 'show-not-found') {
 438         $show_not_found = 1;  # A no-op but don't fail
 439     } else {
 440         # Unknown argument
 441         usage();
 442     }
 443 }
 444
 445 # continue execution near EOF;
 446
 447 # get kernel version from env
 448 sub get_kernel_version() {
 449     my $version = 'unknown kernel version';
 450
 451     if (defined($ENV{'KERNELVERSION'})) {
 452         $version = $ENV{'KERNELVERSION'};
 453     }
 454     return $version;
 455 }
 456
 457 #
 458 sub print_lineno {
 459     my $lineno = shift;
 460     if ($enable_lineno && defined($lineno)) {
 461         print "#define LINENO " . $lineno . "\n";
 462     }
 463 }
 464 ##
 465 # dumps section contents to arrays/hashes intended for that purpose.
 466 #
 467 sub dump_section {
 468     my $file = shift;
 469     my $name = shift;
 470     my $contents = join "\n", @_;
 471
 472     if ($name =~ m/$type_param/) {
 473         $name = $1;
 474         $parameterdescs{$name} = $contents;
 475         $sectcheck = $sectcheck . $name . " ";
 476         $parameterdesc_start_lines{$name} = $new_start_line;
 477         $new_start_line = 0;
 478     } elsif ($name eq "@\.\.\.") {
 479         $name = "...";
 480         $parameterdescs{$name} = $contents;
 481         $sectcheck = $sectcheck . $name . " ";
 482         $parameterdesc_start_lines{$name} = $new_start_line;
 483         $new_start_line = 0;
 484     } else {
 485         if (defined($sections{$name}) && ($sections{$name} ne "")) {
 486             # Only warn on user specified duplicate section names.
 487             if ($name ne $section_default) {
 488                 print STDERR "${file}:$.: warning: duplicate section name '$name'\n";
 489                 ++$warnings;
 490             }
 491             $sections{$name} .= $contents;
 492         } else {
 493             $sections{$name} = $contents;
 494             push @sectionlist, $name;
 495             $section_start_lines{$name} = $new_start_line;
 496             $new_start_line = 0;
 497         }
 498     }
 499 }
 500
 501 ##
 502 # dump DOC: section after checking that it should go out
 503 #
 504 sub dump_doc_section {
 505     my $file = shift;
 506     my $name = shift;
 507     my $contents = join "\n", @_;
 508
 509     if ($no_doc_sections) {
 510         return;
 511     }
 512
 513     if (($output_selection == OUTPUT_ALL) ||
 514         ($output_selection == OUTPUT_INCLUDE &&
 515          defined($function_table{$name})) ||
 516         ($output_selection == OUTPUT_EXCLUDE &&
 517          !defined($function_table{$name})))
 518     {
 519         dump_section($file, $name, $contents);
 520         output_blockhead({'sectionlist' => \@sectionlist,
 521                           'sections' => \%sections,
 522                           'module' => $modulename,
 523                           'content-only' => ($output_selection != OUTPUT_ALL), });
 524     }
 525 }
 526
 527 ##
 528 # output function
 529 #
 530 # parameterdescs, a hash.
 531 #  function => "function name"
 532 #  parameterlist => @list of parameters
 533 #  parameterdescs => %parameter descriptions
 534 #  sectionlist => @list of sections
 535 #  sections => %section descriptions
 536 #
 537
 538 sub output_highlight {
 539     my $contents = join "\n",@_;
 540     my $line;
 541
 542 #   DEBUG
 543 #   if (!defined $contents) {
 544 #       use Carp;
 545 #       confess "output_highlight got called with no args?\n";
 546 #   }
 547
 548 #   print STDERR "contents b4:$contents\n";
 549     eval $dohighlight;
 550     die $@ if $@;
 551 #   print STDERR "contents af:$contents\n";
 552
 553     foreach $line (split "\n", $contents) {
 554         if (! $output_preformatted) {
 555             $line =~ s/^\s*//;
 556         }
 557         if ($line eq ""){
 558             if (! $output_preformatted) {
 559                 print $lineprefix, $blankline;
 560             }
 561         } else {
 562             if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
 563                 print "\\&$line";
 564             } else {
 565                 print $lineprefix, $line;
 566             }
 567         }
 568         print "\n";
 569     }
 570 }
 571
 572 ##
 573 # output function in man
 574 sub output_function_man(%) {
 575     my %args = %{$_[0]};
 576     my ($parameter, $section);
 577     my $count;
 578
 579     print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
 580
 581     print ".SH NAME\n";
 582     print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
 583
 584     print ".SH SYNOPSIS\n";
 585     if ($args{'functiontype'} ne "") {
 586         print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
 587     } else {
 588         print ".B \"" . $args{'function'} . "\n";
 589     }
 590     $count = 0;
 591     my $parenth = "(";
 592     my $post = ",";
 593     foreach my $parameter (@{$args{'parameterlist'}}) {
 594         if ($count == $#{$args{'parameterlist'}}) {
 595             $post = ");";
 596         }
 597         $type = $args{'parametertypes'}{$parameter};
 598         if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
 599             # pointer-to-function
 600             print ".BI \"" . $parenth . $1 . "\" " . $parameter . " \") (" . $2 . ")" . $post . "\"\n";
 601         } else {
 602             $type =~ s/([^\*])$/$1 /;
 603             print ".BI \"" . $parenth . $type . "\" " . $parameter . " \"" . $post . "\"\n";
 604         }
 605         $count++;
 606         $parenth = "";
 607     }
 608
 609     print ".SH ARGUMENTS\n";
 610     foreach $parameter (@{$args{'parameterlist'}}) {
 611         my $parameter_name = $parameter;
 612         $parameter_name =~ s/\[.*//;
 613
 614         print ".IP \"" . $parameter . "\" 12\n";
 615         output_highlight($args{'parameterdescs'}{$parameter_name});
 616     }
 617     foreach $section (@{$args{'sectionlist'}}) {
 618         print ".SH \"", uc $section, "\"\n";
 619         output_highlight($args{'sections'}{$section});
 620     }
 621 }
 622
 623 ##
 624 # output enum in man
 625 sub output_enum_man(%) {
 626     my %args = %{$_[0]};
 627     my ($parameter, $section);
 628     my $count;
 629
 630     print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
 631
 632     print ".SH NAME\n";
 633     print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
 634
 635     print ".SH SYNOPSIS\n";
 636     print "enum " . $args{'enum'} . " {\n";
 637     $count = 0;
 638     foreach my $parameter (@{$args{'parameterlist'}}) {
 639         print ".br\n.BI \"    $parameter\"\n";
 640         if ($count == $#{$args{'parameterlist'}}) {
 641             print "\n};\n";
 642             last;
 643         }
 644         else {
 645             print ", \n.br\n";
 646         }
 647         $count++;
 648     }
 649
 650     print ".SH Constants\n";
 651     foreach $parameter (@{$args{'parameterlist'}}) {
 652         my $parameter_name = $parameter;
 653         $parameter_name =~ s/\[.*//;
 654
 655         print ".IP \"" . $parameter . "\" 12\n";
 656         output_highlight($args{'parameterdescs'}{$parameter_name});
 657     }
 658     foreach $section (@{$args{'sectionlist'}}) {
 659         print ".SH \"$section\"\n";
 660         output_highlight($args{'sections'}{$section});
 661     }
 662 }
 663
 664 ##
 665 # output struct in man
 666 sub output_struct_man(%) {
 667     my %args = %{$_[0]};
 668     my ($parameter, $section);
 669
 670     print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
 671
 672     print ".SH NAME\n";
 673     print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
 674
 675     my $declaration = $args{'definition'};
 676     $declaration =~ s/\t/  /g;
 677     $declaration =~ s/\n/"\n.br\n.BI \"/g;
 678     print ".SH SYNOPSIS\n";
 679     print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
 680     print ".BI \"$declaration\n};\n.br\n\n";
 681
 682     print ".SH Members\n";
 683     foreach $parameter (@{$args{'parameterlist'}}) {
 684         ($parameter =~ /^#/) && next;
 685
 686         my $parameter_name = $parameter;
 687         $parameter_name =~ s/\[.*//;
 688
 689         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 690         print ".IP \"" . $parameter . "\" 12\n";
 691         output_highlight($args{'parameterdescs'}{$parameter_name});
 692     }
 693     foreach $section (@{$args{'sectionlist'}}) {
 694         print ".SH \"$section\"\n";
 695         output_highlight($args{'sections'}{$section});
 696     }
 697 }
 698
 699 ##
 700 # output typedef in man
 701 sub output_typedef_man(%) {
 702     my %args = %{$_[0]};
 703     my ($parameter, $section);
 704
 705     print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
 706
 707     print ".SH NAME\n";
 708     print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
 709
 710     foreach $section (@{$args{'sectionlist'}}) {
 711         print ".SH \"$section\"\n";
 712         output_highlight($args{'sections'}{$section});
 713     }
 714 }
 715
 716 sub output_blockhead_man(%) {
 717     my %args = %{$_[0]};
 718     my ($parameter, $section);
 719     my $count;
 720
 721     print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
 722
 723     foreach $section (@{$args{'sectionlist'}}) {
 724         print ".SH \"$section\"\n";
 725         output_highlight($args{'sections'}{$section});
 726     }
 727 }
 728
 729 ##
 730 # output in restructured text
 731 #
 732
 733 #
 734 # This could use some work; it's used to output the DOC: sections, and
 735 # starts by putting out the name of the doc section itself, but that tends
 736 # to duplicate a header already in the template file.
 737 #
 738 sub output_blockhead_rst(%) {
 739     my %args = %{$_[0]};
 740     my ($parameter, $section);
 741
 742     foreach $section (@{$args{'sectionlist'}}) {
 743         if ($output_selection != OUTPUT_INCLUDE) {
 744             print "**$section**\n\n";
 745         }
 746         print_lineno($section_start_lines{$section});
 747         output_highlight_rst($args{'sections'}{$section});
 748         print "\n";
 749     }
 750 }
 751
 752 #
 753 # Apply the RST highlights to a sub-block of text.
 754 #
 755 sub highlight_block($) {
 756     # The dohighlight kludge requires the text be called $contents
 757     my $contents = shift;
 758     eval $dohighlight;
 759     die $@ if $@;
 760     return $contents;
 761 }
 762
 763 #
 764 # Regexes used only here.
 765 #
 766 my $sphinx_literal = '^[^.].*::$';
 767 my $sphinx_cblock = '^\.\.\ +code-block::';
 768
 769 sub output_highlight_rst {
 770     my $input = join "\n",@_;
 771     my $output = "";
 772     my $line;
 773     my $in_literal = 0;
 774     my $litprefix;
 775     my $block = "";
 776
 777     foreach $line (split "\n",$input) {
 778         #
 779         # If we're in a literal block, see if we should drop out
 780         # of it.  Otherwise pass the line straight through unmunged.
 781         #
 782         if ($in_literal) {
 783             if (! ($line =~ /^\s*$/)) {
 784                 #
 785                 # If this is the first non-blank line in a literal
 786                 # block we need to figure out what the proper indent is.
 787                 #
 788                 if ($litprefix eq "") {
 789                     $line =~ /^(\s*)/;
 790                     $litprefix = '^' . $1;
 791                     $output .= $line . "\n";
 792                 } elsif (! ($line =~ /$litprefix/)) {
 793                     $in_literal = 0;
 794                 } else {
 795                     $output .= $line . "\n";
 796                 }
 797             } else {
 798                 $output .= $line . "\n";
 799             }
 800         }
 801         #
 802         # Not in a literal block (or just dropped out)
 803         #
 804         if (! $in_literal) {
 805             $block .= $line . "\n";
 806             if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
 807                 $in_literal = 1;
 808                 $litprefix = "";
 809                 $output .= highlight_block($block);
 810                 $block = ""
 811             }
 812         }
 813     }
 814
 815     if ($block) {
 816         $output .= highlight_block($block);
 817     }
 818     foreach $line (split "\n", $output) {
 819         print $lineprefix . $line . "\n";
 820     }
 821 }
 822
 823 sub output_function_rst(%) {
 824     my %args = %{$_[0]};
 825     my ($parameter, $section);
 826     my $oldprefix = $lineprefix;
 827     my $start = "";
 828
 829     if ($args{'typedef'}) {
 830         print ".. c:type:: ". $args{'function'} . "\n\n";
 831         print_lineno($declaration_start_line);
 832         print "   **Typedef**: ";
 833         $lineprefix = "";
 834         output_highlight_rst($args{'purpose'});
 835         $start = "\n\n**Syntax**\n\n  ``";
 836     } else {
 837         print ".. c:function:: ";
 838     }
 839     if ($args{'functiontype'} ne "") {
 840         $start .= $args{'functiontype'} . " " . $args{'function'} . " (";
 841     } else {
 842         $start .= $args{'function'} . " (";
 843     }
 844     print $start;
 845
 846     my $count = 0;
 847     foreach my $parameter (@{$args{'parameterlist'}}) {
 848         if ($count ne 0) {
 849             print ", ";
 850         }
 851         $count++;
 852         $type = $args{'parametertypes'}{$parameter};
 853
 854         if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
 855             # pointer-to-function
 856             print $1 . $parameter . ") (" . $2;
 857         } else {
 858             print $type . " " . $parameter;
 859         }
 860     }
 861     if ($args{'typedef'}) {
 862         print ");``\n\n";
 863     } else {
 864         print ")\n\n";
 865         print_lineno($declaration_start_line);
 866         $lineprefix = "   ";
 867         output_highlight_rst($args{'purpose'});
 868         print "\n";
 869     }
 870
 871     print "**Parameters**\n\n";
 872     $lineprefix = "  ";
 873     foreach $parameter (@{$args{'parameterlist'}}) {
 874         my $parameter_name = $parameter;
 875         $parameter_name =~ s/\[.*//;
 876         $type = $args{'parametertypes'}{$parameter};
 877
 878         if ($type ne "") {
 879             print "``$type $parameter``\n";
 880         } else {
 881             print "``$parameter``\n";
 882         }
 883
 884         print_lineno($parameterdesc_start_lines{$parameter_name});
 885
 886         if (defined($args{'parameterdescs'}{$parameter_name}) &&
 887             $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
 888             output_highlight_rst($args{'parameterdescs'}{$parameter_name});
 889         } else {
 890             print "  *undescribed*\n";
 891         }
 892         print "\n";
 893     }
 894
 895     $lineprefix = $oldprefix;
 896     output_section_rst(@_);
 897 }
 898
 899 sub output_section_rst(%) {
 900     my %args = %{$_[0]};
 901     my $section;
 902     my $oldprefix = $lineprefix;
 903     $lineprefix = "";
 904
 905     foreach $section (@{$args{'sectionlist'}}) {
 906         print "**$section**\n\n";
 907         print_lineno($section_start_lines{$section});
 908         output_highlight_rst($args{'sections'}{$section});
 909         print "\n";
 910     }
 911     print "\n";
 912     $lineprefix = $oldprefix;
 913 }
 914
 915 sub output_enum_rst(%) {
 916     my %args = %{$_[0]};
 917     my ($parameter);
 918     my $oldprefix = $lineprefix;
 919     my $count;
 920     my $name = "enum " . $args{'enum'};
 921
 922     print "\n\n.. c:type:: " . $name . "\n\n";
 923     print_lineno($declaration_start_line);
 924     $lineprefix = "   ";
 925     output_highlight_rst($args{'purpose'});
 926     print "\n";
 927
 928     print "**Constants**\n\n";
 929     $lineprefix = "  ";
 930     foreach $parameter (@{$args{'parameterlist'}}) {
 931         print "``$parameter``\n";
 932         if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
 933             output_highlight_rst($args{'parameterdescs'}{$parameter});
 934         } else {
 935             print "  *undescribed*\n";
 936         }
 937         print "\n";
 938     }
 939
 940     $lineprefix = $oldprefix;
 941     output_section_rst(@_);
 942 }
 943
 944 sub output_typedef_rst(%) {
 945     my %args = %{$_[0]};
 946     my ($parameter);
 947     my $oldprefix = $lineprefix;
 948     my $name = "typedef " . $args{'typedef'};
 949
 950     print "\n\n.. c:type:: " . $name . "\n\n";
 951     print_lineno($declaration_start_line);
 952     $lineprefix = "   ";
 953     output_highlight_rst($args{'purpose'});
 954     print "\n";
 955
 956     $lineprefix = $oldprefix;
 957     output_section_rst(@_);
 958 }
 959
 960 sub output_struct_rst(%) {
 961     my %args = %{$_[0]};
 962     my ($parameter);
 963     my $oldprefix = $lineprefix;
 964     my $name = $args{'type'} . " " . $args{'struct'};
 965
 966     print "\n\n.. c:type:: " . $name . "\n\n";
 967     print_lineno($declaration_start_line);
 968     $lineprefix = "   ";
 969     output_highlight_rst($args{'purpose'});
 970     print "\n";
 971
 972     print "**Definition**\n\n";
 973     print "::\n\n";
 974     my $declaration = $args{'definition'};
 975     $declaration =~ s/\t/  /g;
 976     print "  " . $args{'type'} . " " . $args{'struct'} . " {\n$declaration  };\n\n";
 977
 978     print "**Members**\n\n";
 979     $lineprefix = "  ";
 980     foreach $parameter (@{$args{'parameterlist'}}) {
 981         ($parameter =~ /^#/) && next;
 982
 983         my $parameter_name = $parameter;
 984         $parameter_name =~ s/\[.*//;
 985
 986         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 987         $type = $args{'parametertypes'}{$parameter};
 988         print_lineno($parameterdesc_start_lines{$parameter_name});
 989         print "``" . $parameter . "``\n";
 990         output_highlight_rst($args{'parameterdescs'}{$parameter_name});
 991         print "\n";
 992     }
 993     print "\n";
 994
 995     $lineprefix = $oldprefix;
 996     output_section_rst(@_);
 997 }
 998
 999 ## none mode output functions
1000
1001 sub output_function_none(%) {
1002 }
1003
1004 sub output_enum_none(%) {
1005 }
1006
1007 sub output_typedef_none(%) {
1008 }
1009
1010 sub output_struct_none(%) {
1011 }
1012
1013 sub output_blockhead_none(%) {
1014 }
1015
1016 ##
1017 # generic output function for all types (function, struct/union, typedef, enum);
1018 # calls the generated, variable output_ function name based on
1019 # functype and output_mode
1020 sub output_declaration {
1021     no strict 'refs';
1022     my $name = shift;
1023     my $functype = shift;
1024     my $func = "output_${functype}_$output_mode";
1025     if (($output_selection == OUTPUT_ALL) ||
1026         (($output_selection == OUTPUT_INCLUDE ||
1027           $output_selection == OUTPUT_EXPORTED) &&
1028          defined($function_table{$name})) ||
1029         (($output_selection == OUTPUT_EXCLUDE ||
1030           $output_selection == OUTPUT_INTERNAL) &&
1031          !($functype eq "function" && defined($function_table{$name}))))
1032     {
1033         &$func(@_);
1034         $section_counter++;
1035     }
1036 }
1037
1038 ##
1039 # generic output function - calls the right one based on current output mode.
1040 sub output_blockhead {
1041     no strict 'refs';
1042     my $func = "output_blockhead_" . $output_mode;
1043     &$func(@_);
1044     $section_counter++;
1045 }
1046
1047 ##
1048 # takes a declaration (struct, union, enum, typedef) and
1049 # invokes the right handler. NOT called for functions.
1050 sub dump_declaration($$) {
1051     no strict 'refs';
1052     my ($prototype, $file) = @_;
1053     my $func = "dump_" . $decl_type;
1054     &$func(@_);
1055 }
1056
1057 sub dump_union($$) {
1058     dump_struct(@_);
1059 }
1060
1061 sub dump_struct($$) {
1062     my $x = shift;
1063     my $file = shift;
1064
1065     if ($x =~ /(struct|union)\s+(\w+)\s*\{(.*)\}(\s*(__packed|__aligned|____cacheline_aligned_in_smp|__attribute__\s*\(\([a-z0-9,_\s\(\)]*\)\)))*/) {
1066         my $decl_type = $1;
1067         $declaration_name = $2;
1068         my $members = $3;
1069
1070         # ignore members marked private:
1071         $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1072         $members =~ s/\/\*\s*private:.*//gosi;
1073         # strip comments:
1074         $members =~ s/\/\*.*?\*\///gos;
1075         # strip attributes
1076         $members =~ s/\s*__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)/ /gi;
1077         $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1078         $members =~ s/\s*__packed\s*/ /gos;
1079         $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1080         $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1081         # replace DECLARE_BITMAP
1082         $members =~ s/DECLARE_BITMAP\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1083         # replace DECLARE_HASHTABLE
1084         $members =~ s/DECLARE_HASHTABLE\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1085         # replace DECLARE_KFIFO
1086         $members =~ s/DECLARE_KFIFO\s*\(([^,)]+),\s*([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1087         # replace DECLARE_KFIFO_PTR
1088         $members =~ s/DECLARE_KFIFO_PTR\s*\(([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1089
1090         my $declaration = $members;
1091
1092         # Split nested struct/union elements as newer ones
1093         while ($members =~ m/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/) {
1094                 my $newmember;
1095                 my $maintype = $1;
1096                 my $ids = $4;
1097                 my $content = $3;
1098                 foreach my $id(split /,/, $ids) {
1099                         $newmember .= "$maintype $id; ";
1100
1101                         $id =~ s/[:\[].*//;
1102                         $id =~ s/^\s*\**(\S+)\s*/$1/;
1103                         foreach my $arg (split /;/, $content) {
1104                                 next if ($arg =~ m/^\s*$/);
1105                                 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1106                                         # pointer-to-function
1107                                         my $type = $1;
1108                                         my $name = $2;
1109                                         my $extra = $3;
1110                                         next if (!$name);
1111                                         if ($id =~ m/^\s*$/) {
1112                                                 # anonymous struct/union
1113                                                 $newmember .= "$type$name$extra; ";
1114                                         } else {
1115                                                 $newmember .= "$type$id.$name$extra; ";
1116                                         }
1117                                 } else {
1118                                         my $type;
1119                                         my $names;
1120                                         $arg =~ s/^\s+//;
1121                                         $arg =~ s/\s+$//;
1122                                         # Handle bitmaps
1123                                         $arg =~ s/:\s*\d+\s*//g;
1124                                         # Handle arrays
1125                                         $arg =~ s/\[.*\]//g;
1126                                         # The type may have multiple words,
1127                                         # and multiple IDs can be defined, like:
1128                                         #       const struct foo, *bar, foobar
1129                                         # So, we remove spaces when parsing the
1130                                         # names, in order to match just names
1131                                         # and commas for the names
1132                                         $arg =~ s/\s*,\s*/,/g;
1133                                         if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1134                                                 $type = $1;
1135                                                 $names = $2;
1136                                         } else {
1137                                                 $newmember .= "$arg; ";
1138                                                 next;
1139                                         }
1140                                         foreach my $name (split /,/, $names) {
1141                                                 $name =~ s/^\s*\**(\S+)\s*/$1/;
1142                                                 next if (($name =~ m/^\s*$/));
1143                                                 if ($id =~ m/^\s*$/) {
1144                                                         # anonymous struct/union
1145                                                         $newmember .= "$type $name; ";
1146                                                 } else {
1147                                                         $newmember .= "$type $id.$name; ";
1148                                                 }
1149                                         }
1150                                 }
1151                         }
1152                 }
1153                 $members =~ s/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/$newmember/;
1154         }
1155
1156         # Ignore other nested elements, like enums
1157         $members =~ s/(\{[^\{\}]*\})//g;
1158
1159         create_parameterlist($members, ';', $file, $declaration_name);
1160         check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1161
1162         # Adjust declaration for better display
1163         $declaration =~ s/([\{;])/$1\n/g;
1164         $declaration =~ s/\}\s+;/};/g;
1165         # Better handle inlined enums
1166         do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1167
1168         my @def_args = split /\n/, $declaration;
1169         my $level = 1;
1170         $declaration = "";
1171         foreach my $clause (@def_args) {
1172                 $clause =~ s/^\s+//;
1173                 $clause =~ s/\s+$//;
1174                 $clause =~ s/\s+/ /;
1175                 next if (!$clause);
1176                 $level-- if ($clause =~ m/(\})/ && $level > 1);
1177                 if (!($clause =~ m/^\s*#/)) {
1178                         $declaration .= "\t" x $level;
1179                 }
1180                 $declaration .= "\t" . $clause . "\n";
1181                 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1182         }
1183         output_declaration($declaration_name,
1184                            'struct',
1185                            {'struct' => $declaration_name,
1186                             'module' => $modulename,
1187                             'definition' => $declaration,
1188                             'parameterlist' => \@parameterlist,
1189                             'parameterdescs' => \%parameterdescs,
1190                             'parametertypes' => \%parametertypes,
1191                             'sectionlist' => \@sectionlist,
1192                             'sections' => \%sections,
1193                             'purpose' => $declaration_purpose,
1194                             'type' => $decl_type
1195                            });
1196     }
1197     else {
1198         print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1199         ++$errors;
1200     }
1201 }
1202
1203
1204 sub show_warnings($$) {
1205         my $functype = shift;
1206         my $name = shift;
1207
1208         return 1 if ($output_selection == OUTPUT_ALL);
1209
1210         if ($output_selection == OUTPUT_EXPORTED) {
1211                 if (defined($function_table{$name})) {
1212                         return 1;
1213                 } else {
1214                         return 0;
1215                 }
1216         }
1217         if ($output_selection == OUTPUT_INTERNAL) {
1218                 if (!($functype eq "function" && defined($function_table{$name}))) {
1219                         return 1;
1220                 } else {
1221                         return 0;
1222                 }
1223         }
1224         if ($output_selection == OUTPUT_INCLUDE) {
1225                 if (defined($function_table{$name})) {
1226                         return 1;
1227                 } else {
1228                         return 0;
1229                 }
1230         }
1231         if ($output_selection == OUTPUT_EXCLUDE) {
1232                 if (!defined($function_table{$name})) {
1233                         return 1;
1234                 } else {
1235                         return 0;
1236                 }
1237         }
1238         die("Please add the new output type at show_warnings()");
1239 }
1240
1241 sub dump_enum($$) {
1242     my $x = shift;
1243     my $file = shift;
1244
1245     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1246     # strip #define macros inside enums
1247     $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1248
1249     if ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1250         $declaration_name = $1;
1251         my $members = $2;
1252         my %_members;
1253
1254         $members =~ s/\s+$//;
1255
1256         foreach my $arg (split ',', $members) {
1257             $arg =~ s/^\s*(\w+).*/$1/;
1258             push @parameterlist, $arg;
1259             if (!$parameterdescs{$arg}) {
1260                 $parameterdescs{$arg} = $undescribed;
1261                 if (show_warnings("enum", $declaration_name)) {
1262                         print STDERR "${file}:$.: warning: Enum value '$arg' not described in enum '$declaration_name'\n";
1263                 }
1264             }
1265             $_members{$arg} = 1;
1266         }
1267
1268         while (my ($k, $v) = each %parameterdescs) {
1269             if (!exists($_members{$k})) {
1270                 if (show_warnings("enum", $declaration_name)) {
1271                      print STDERR "${file}:$.: warning: Excess enum value '$k' description in '$declaration_name'\n";
1272                 }
1273             }
1274         }
1275
1276         output_declaration($declaration_name,
1277                            'enum',
1278                            {'enum' => $declaration_name,
1279                             'module' => $modulename,
1280                             'parameterlist' => \@parameterlist,
1281                             'parameterdescs' => \%parameterdescs,
1282                             'sectionlist' => \@sectionlist,
1283                             'sections' => \%sections,
1284                             'purpose' => $declaration_purpose
1285                            });
1286     }
1287     else {
1288         print STDERR "${file}:$.: error: Cannot parse enum!\n";
1289         ++$errors;
1290     }
1291 }
1292
1293 sub dump_typedef($$) {
1294     my $x = shift;
1295     my $file = shift;
1296
1297     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1298
1299     # Parse function prototypes
1300     if ($x =~ /typedef\s+(\w+)\s*\(\*\s*(\w\S+)\s*\)\s*\((.*)\);/ ||
1301         $x =~ /typedef\s+(\w+)\s*(\w\S+)\s*\s*\((.*)\);/) {
1302
1303         # Function typedefs
1304         $return_type = $1;
1305         $declaration_name = $2;
1306         my $args = $3;
1307
1308         create_parameterlist($args, ',', $file, $declaration_name);
1309
1310         output_declaration($declaration_name,
1311                            'function',
1312                            {'function' => $declaration_name,
1313                             'typedef' => 1,
1314                             'module' => $modulename,
1315                             'functiontype' => $return_type,
1316                             'parameterlist' => \@parameterlist,
1317                             'parameterdescs' => \%parameterdescs,
1318                             'parametertypes' => \%parametertypes,
1319                             'sectionlist' => \@sectionlist,
1320                             'sections' => \%sections,
1321                             'purpose' => $declaration_purpose
1322                            });
1323         return;
1324     }
1325
1326     while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1327         $x =~ s/\(*.\)\s*;$/;/;
1328         $x =~ s/\[*.\]\s*;$/;/;
1329     }
1330
1331     if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1332         $declaration_name = $1;
1333
1334         output_declaration($declaration_name,
1335                            'typedef',
1336                            {'typedef' => $declaration_name,
1337                             'module' => $modulename,
1338                             'sectionlist' => \@sectionlist,
1339                             'sections' => \%sections,
1340                             'purpose' => $declaration_purpose
1341                            });
1342     }
1343     else {
1344         print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1345         ++$errors;
1346     }
1347 }
1348
1349 sub save_struct_actual($) {
1350     my $actual = shift;
1351
1352     # strip all spaces from the actual param so that it looks like one string item
1353     $actual =~ s/\s*//g;
1354     $struct_actual = $struct_actual . $actual . " ";
1355 }
1356
1357 sub create_parameterlist($$$$) {
1358     my $args = shift;
1359     my $splitter = shift;
1360     my $file = shift;
1361     my $declaration_name = shift;
1362     my $type;
1363     my $param;
1364
1365     # temporarily replace commas inside function pointer definition
1366     while ($args =~ /(\([^\),]+),/) {
1367         $args =~ s/(\([^\),]+),/$1#/g;
1368     }
1369
1370     foreach my $arg (split($splitter, $args)) {
1371         # strip comments
1372         $arg =~ s/\/\*.*\*\///;
1373         # strip leading/trailing spaces
1374         $arg =~ s/^\s*//;
1375         $arg =~ s/\s*$//;
1376         $arg =~ s/\s+/ /;
1377
1378         if ($arg =~ /^#/) {
1379             # Treat preprocessor directive as a typeless variable just to fill
1380             # corresponding data structures "correctly". Catch it later in
1381             # output_* subs.
1382             push_parameter($arg, "", $file);
1383         } elsif ($arg =~ m/\(.+\)\s*\(/) {
1384             # pointer-to-function
1385             $arg =~ tr/#/,/;
1386             $arg =~ m/[^\(]+\(\*?\s*([\w\.]*)\s*\)/;
1387             $param = $1;
1388             $type = $arg;
1389             $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1390             save_struct_actual($param);
1391             push_parameter($param, $type, $file, $declaration_name);
1392         } elsif ($arg) {
1393             $arg =~ s/\s*:\s*/:/g;
1394             $arg =~ s/\s*\[/\[/g;
1395
1396             my @args = split('\s*,\s*', $arg);
1397             if ($args[0] =~ m/\*/) {
1398                 $args[0] =~ s/(\*+)\s*/ $1/;
1399             }
1400
1401             my @first_arg;
1402             if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1403                     shift @args;
1404                     push(@first_arg, split('\s+', $1));
1405                     push(@first_arg, $2);
1406             } else {
1407                     @first_arg = split('\s+', shift @args);
1408             }
1409
1410             unshift(@args, pop @first_arg);
1411             $type = join " ", @first_arg;
1412
1413             foreach $param (@args) {
1414                 if ($param =~ m/^(\*+)\s*(.*)/) {
1415                     save_struct_actual($2);
1416                     push_parameter($2, "$type $1", $file, $declaration_name);
1417                 }
1418                 elsif ($param =~ m/(.*?):(\d+)/) {
1419                     if ($type ne "") { # skip unnamed bit-fields
1420                         save_struct_actual($1);
1421                         push_parameter($1, "$type:$2", $file, $declaration_name)
1422                     }
1423                 }
1424                 else {
1425                     save_struct_actual($param);
1426                     push_parameter($param, $type, $file, $declaration_name);
1427                 }
1428             }
1429         }
1430     }
1431 }
1432
1433 sub push_parameter($$$$) {
1434         my $param = shift;
1435         my $type = shift;
1436         my $file = shift;
1437         my $declaration_name = shift;
1438
1439         if (($anon_struct_union == 1) && ($type eq "") &&
1440             ($param eq "}")) {
1441                 return;         # ignore the ending }; from anon. struct/union
1442         }
1443
1444         $anon_struct_union = 0;
1445         $param =~ s/[\[\)].*//;
1446
1447         if ($type eq "" && $param =~ /\.\.\.$/)
1448         {
1449             if (!$param =~ /\w\.\.\.$/) {
1450               # handles unnamed variable parameters
1451               $param = "...";
1452             }
1453             elsif ($param =~ /\w\.\.\.$/) {
1454               # for named variable parameters of the form `x...`, remove the dots
1455               $param =~ s/\.\.\.$//;
1456             }
1457             if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1458                 $parameterdescs{$param} = "variable arguments";
1459             }
1460         }
1461         elsif ($type eq "" && ($param eq "" or $param eq "void"))
1462         {
1463             $param="void";
1464             $parameterdescs{void} = "no arguments";
1465         }
1466         elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1467         # handle unnamed (anonymous) union or struct:
1468         {
1469                 $type = $param;
1470                 $param = "{unnamed_" . $param . "}";
1471                 $parameterdescs{$param} = "anonymous\n";
1472                 $anon_struct_union = 1;
1473         }
1474
1475         # warn if parameter has no description
1476         # (but ignore ones starting with # as these are not parameters
1477         # but inline preprocessor statements);
1478         # Note: It will also ignore void params and unnamed structs/unions
1479         if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1480                 $parameterdescs{$param} = $undescribed;
1481
1482                 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1483                         print STDERR
1484                               "${file}:$.: warning: Function parameter or member '$param' not described in '$declaration_name'\n";
1485                         ++$warnings;
1486                 }
1487         }
1488
1489         # strip spaces from $param so that it is one continuous string
1490         # on @parameterlist;
1491         # this fixes a problem where check_sections() cannot find
1492         # a parameter like "addr[6 + 2]" because it actually appears
1493         # as "addr[6", "+", "2]" on the parameter list;
1494         # but it's better to maintain the param string unchanged for output,
1495         # so just weaken the string compare in check_sections() to ignore
1496         # "[blah" in a parameter string;
1497         ###$param =~ s/\s*//g;
1498         push @parameterlist, $param;
1499         $type =~ s/\s\s+/ /g;
1500         $parametertypes{$param} = $type;
1501 }
1502
1503 sub check_sections($$$$$) {
1504         my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1505         my @sects = split ' ', $sectcheck;
1506         my @prms = split ' ', $prmscheck;
1507         my $err;
1508         my ($px, $sx);
1509         my $prm_clean;          # strip trailing "[array size]" and/or beginning "*"
1510
1511         foreach $sx (0 .. $#sects) {
1512                 $err = 1;
1513                 foreach $px (0 .. $#prms) {
1514                         $prm_clean = $prms[$px];
1515                         $prm_clean =~ s/\[.*\]//;
1516                         $prm_clean =~ s/__attribute__\s*\(\([a-z,_\*\s\(\)]*\)\)//i;
1517                         # ignore array size in a parameter string;
1518                         # however, the original param string may contain
1519                         # spaces, e.g.:  addr[6 + 2]
1520                         # and this appears in @prms as "addr[6" since the
1521                         # parameter list is split at spaces;
1522                         # hence just ignore "[..." for the sections check;
1523                         $prm_clean =~ s/\[.*//;
1524
1525                         ##$prm_clean =~ s/^\**//;
1526                         if ($prm_clean eq $sects[$sx]) {
1527                                 $err = 0;
1528                                 last;
1529                         }
1530                 }
1531                 if ($err) {
1532                         if ($decl_type eq "function") {
1533                                 print STDERR "${file}:$.: warning: " .
1534                                         "Excess function parameter " .
1535                                         "'$sects[$sx]' " .
1536                                         "description in '$decl_name'\n";
1537                                 ++$warnings;
1538                         }
1539                 }
1540         }
1541 }
1542
1543 ##
1544 # Checks the section describing the return value of a function.
1545 sub check_return_section {
1546         my $file = shift;
1547         my $declaration_name = shift;
1548         my $return_type = shift;
1549
1550         # Ignore an empty return type (It's a macro)
1551         # Ignore functions with a "void" return type. (But don't ignore "void *")
1552         if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1553                 return;
1554         }
1555
1556         if (!defined($sections{$section_return}) ||
1557             $sections{$section_return} eq "") {
1558                 print STDERR "${file}:$.: warning: " .
1559                         "No description found for return value of " .
1560                         "'$declaration_name'\n";
1561                 ++$warnings;
1562         }
1563 }
1564
1565 ##
1566 # takes a function prototype and the name of the current file being
1567 # processed and spits out all the details stored in the global
1568 # arrays/hashes.
1569 sub dump_function($$) {
1570     my $prototype = shift;
1571     my $file = shift;
1572     my $noret = 0;
1573
1574     $prototype =~ s/^static +//;
1575     $prototype =~ s/^extern +//;
1576     $prototype =~ s/^asmlinkage +//;
1577     $prototype =~ s/^inline +//;
1578     $prototype =~ s/^__inline__ +//;
1579     $prototype =~ s/^__inline +//;
1580     $prototype =~ s/^__always_inline +//;
1581     $prototype =~ s/^noinline +//;
1582     $prototype =~ s/__init +//;
1583     $prototype =~ s/__init_or_module +//;
1584     $prototype =~ s/__meminit +//;
1585     $prototype =~ s/__must_check +//;
1586     $prototype =~ s/__weak +//;
1587     $prototype =~ s/__sched +//;
1588     $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1589     my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1590     $prototype =~ s/__attribute__\s*\(\(
1591             (?:
1592                  [\w\s]++          # attribute name
1593                  (?:\([^)]*+\))?   # attribute arguments
1594                  \s*+,?            # optional comma at the end
1595             )+
1596           \)\)\s+//x;
1597
1598     # Yes, this truly is vile.  We are looking for:
1599     # 1. Return type (may be nothing if we're looking at a macro)
1600     # 2. Function name
1601     # 3. Function parameters.
1602     #
1603     # All the while we have to watch out for function pointer parameters
1604     # (which IIRC is what the two sections are for), C types (these
1605     # regexps don't even start to express all the possibilities), and
1606     # so on.
1607     #
1608     # If you mess with these regexps, it's a good idea to check that
1609     # the following functions' documentation still comes out right:
1610     # - parport_register_device (function pointer parameters)
1611     # - atomic_set (macro)
1612     # - pci_match_device, __copy_to_user (long return type)
1613
1614     if ($define && $prototype =~ m/^()([a-zA-Z0-9_~:]+)\s+/) {
1615         # This is an object-like macro, it has no return type and no parameter
1616         # list.
1617         # Function-like macros are not allowed to have spaces between
1618         # declaration_name and opening parenthesis (notice the \s+).
1619         $return_type = $1;
1620         $declaration_name = $2;
1621         $noret = 1;
1622     } elsif ($prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1623         $prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1624         $prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1625         $prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1626         $prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1627         $prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1628         $prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1629         $prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1630         $prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1631         $prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1632         $prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1633         $prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1634         $prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1635         $prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1636         $prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1637         $prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1638         $prototype =~ m/^(\w+\s+\w+\s*\*+\s*\w+\s*\*+\s*)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/)  {
1639         $return_type = $1;
1640         $declaration_name = $2;
1641         my $args = $3;
1642
1643         create_parameterlist($args, ',', $file, $declaration_name);
1644     } else {
1645         print STDERR "${file}:$.: warning: cannot understand function prototype: '$prototype'\n";
1646         return;
1647     }
1648
1649         my $prms = join " ", @parameterlist;
1650         check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1651
1652         # This check emits a lot of warnings at the moment, because many
1653         # functions don't have a 'Return' doc section. So until the number
1654         # of warnings goes sufficiently down, the check is only performed in
1655         # verbose mode.
1656         # TODO: always perform the check.
1657         if ($verbose && !$noret) {
1658                 check_return_section($file, $declaration_name, $return_type);
1659         }
1660
1661     output_declaration($declaration_name,
1662                        'function',
1663                        {'function' => $declaration_name,
1664                         'module' => $modulename,
1665                         'functiontype' => $return_type,
1666                         'parameterlist' => \@parameterlist,
1667                         'parameterdescs' => \%parameterdescs,
1668                         'parametertypes' => \%parametertypes,
1669                         'sectionlist' => \@sectionlist,
1670                         'sections' => \%sections,
1671                         'purpose' => $declaration_purpose
1672                        });
1673 }
1674
1675 sub reset_state {
1676     $function = "";
1677     %parameterdescs = ();
1678     %parametertypes = ();
1679     @parameterlist = ();
1680     %sections = ();
1681     @sectionlist = ();
1682     $sectcheck = "";
1683     $struct_actual = "";
1684     $prototype = "";
1685
1686     $state = STATE_NORMAL;
1687     $inline_doc_state = STATE_INLINE_NA;
1688 }
1689
1690 sub tracepoint_munge($) {
1691         my $file = shift;
1692         my $tracepointname = 0;
1693         my $tracepointargs = 0;
1694
1695         if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1696                 $tracepointname = $1;
1697         }
1698         if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1699                 $tracepointname = $1;
1700         }
1701         if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1702                 $tracepointname = $2;
1703         }
1704         $tracepointname =~ s/^\s+//; #strip leading whitespace
1705         if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1706                 $tracepointargs = $1;
1707         }
1708         if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1709                 print STDERR "${file}:$.: warning: Unrecognized tracepoint format: \n".
1710                              "$prototype\n";
1711         } else {
1712                 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1713         }
1714 }
1715
1716 sub syscall_munge() {
1717         my $void = 0;
1718
1719         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1720 ##      if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1721         if ($prototype =~ m/SYSCALL_DEFINE0/) {
1722                 $void = 1;
1723 ##              $prototype = "long sys_$1(void)";
1724         }
1725
1726         $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1727         if ($prototype =~ m/long (sys_.*?),/) {
1728                 $prototype =~ s/,/\(/;
1729         } elsif ($void) {
1730                 $prototype =~ s/\)/\(void\)/;
1731         }
1732
1733         # now delete all of the odd-number commas in $prototype
1734         # so that arg types & arg names don't have a comma between them
1735         my $count = 0;
1736         my $len = length($prototype);
1737         if ($void) {
1738                 $len = 0;       # skip the for-loop
1739         }
1740         for (my $ix = 0; $ix < $len; $ix++) {
1741                 if (substr($prototype, $ix, 1) eq ',') {
1742                         $count++;
1743                         if ($count % 2 == 1) {
1744                                 substr($prototype, $ix, 1) = ' ';
1745                         }
1746                 }
1747         }
1748 }
1749
1750 sub process_proto_function($$) {
1751     my $x = shift;
1752     my $file = shift;
1753
1754     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1755
1756     if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1757         # do nothing
1758     }
1759     elsif ($x =~ /([^\{]*)/) {
1760         $prototype .= $1;
1761     }
1762
1763     if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1764         $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1765         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1766         $prototype =~ s@^\s+@@gos; # strip leading spaces
1767         if ($prototype =~ /SYSCALL_DEFINE/) {
1768                 syscall_munge();
1769         }
1770         if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1771             $prototype =~ /DEFINE_SINGLE_EVENT/)
1772         {
1773                 tracepoint_munge($file);
1774         }
1775         dump_function($prototype, $file);
1776         reset_state();
1777     }
1778 }
1779
1780 sub process_proto_type($$) {
1781     my $x = shift;
1782     my $file = shift;
1783
1784     $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1785     $x =~ s@^\s+@@gos; # strip leading spaces
1786     $x =~ s@\s+$@@gos; # strip trailing spaces
1787     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1788
1789     if ($x =~ /^#/) {
1790         # To distinguish preprocessor directive from regular declaration later.
1791         $x .= ";";
1792     }
1793
1794     while (1) {
1795         if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1796             if( length $prototype ) {
1797                 $prototype .= " "
1798             }
1799             $prototype .= $1 . $2;
1800             ($2 eq '{') && $brcount++;
1801             ($2 eq '}') && $brcount--;
1802             if (($2 eq ';') && ($brcount == 0)) {
1803                 dump_declaration($prototype, $file);
1804                 reset_state();
1805                 last;
1806             }
1807             $x = $3;
1808         } else {
1809             $prototype .= $x;
1810             last;
1811         }
1812     }
1813 }
1814
1815
1816 sub map_filename($) {
1817     my $file;
1818     my ($orig_file) = @_;
1819
1820     if (defined($ENV{'SRCTREE'})) {
1821         $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1822     } else {
1823         $file = $orig_file;
1824     }
1825
1826     if (defined($source_map{$file})) {
1827         $file = $source_map{$file};
1828     }
1829
1830     return $file;
1831 }
1832
1833 sub process_export_file($) {
1834     my ($orig_file) = @_;
1835     my $file = map_filename($orig_file);
1836
1837     if (!open(IN,"<$file")) {
1838         print STDERR "Error: Cannot open file $file\n";
1839         ++$errors;
1840         return;
1841     }
1842
1843     while (<IN>) {
1844         if (/$export_symbol/) {
1845             $function_table{$2} = 1;
1846         }
1847     }
1848
1849     close(IN);
1850 }
1851
1852 #
1853 # Parsers for the various processing states.
1854 #
1855 # STATE_NORMAL: looking for the /** to begin everything.
1856 #
1857 sub process_normal() {
1858     if (/$doc_start/o) {
1859         $state = STATE_NAME;    # next line is always the function name
1860         $in_doc_sect = 0;
1861         $declaration_start_line = $. + 1;
1862     }
1863 }
1864
1865 #
1866 # STATE_NAME: Looking for the "name - description" line
1867 #
1868 sub process_name($$) {
1869     my $file = shift;
1870     my $identifier;
1871     my $descr;
1872
1873     if (/$doc_block/o) {
1874         $state = STATE_DOCBLOCK;
1875         $contents = "";
1876         $new_start_line = $. + 1;
1877
1878         if ( $1 eq "" ) {
1879             $section = $section_intro;
1880         } else {
1881             $section = $1;
1882         }
1883     }
1884     elsif (/$doc_decl/o) {
1885         $identifier = $1;
1886         if (/\s*([\w\s]+?)(\(\))?\s*-/) {
1887             $identifier = $1;
1888         }
1889
1890         $state = STATE_BODY;
1891         # if there's no @param blocks need to set up default section
1892         # here
1893         $contents = "";
1894         $section = $section_default;
1895         $new_start_line = $. + 1;
1896         if (/-(.*)/) {
1897             # strip leading/trailing/multiple spaces
1898             $descr= $1;
1899             $descr =~ s/^\s*//;
1900             $descr =~ s/\s*$//;
1901             $descr =~ s/\s+/ /g;
1902             $declaration_purpose = $descr;
1903             $state = STATE_BODY_MAYBE;
1904         } else {
1905             $declaration_purpose = "";
1906         }
1907
1908         if (($declaration_purpose eq "") && $verbose) {
1909             print STDERR "${file}:$.: warning: missing initial short description on line:\n";
1910             print STDERR $_;
1911             ++$warnings;
1912         }
1913
1914         if ($identifier =~ m/^struct\b/) {
1915             $decl_type = 'struct';
1916         } elsif ($identifier =~ m/^union\b/) {
1917             $decl_type = 'union';
1918         } elsif ($identifier =~ m/^enum\b/) {
1919             $decl_type = 'enum';
1920         } elsif ($identifier =~ m/^typedef\b/) {
1921             $decl_type = 'typedef';
1922         } else {
1923             $decl_type = 'function';
1924         }
1925
1926         if ($verbose) {
1927             print STDERR "${file}:$.: info: Scanning doc for $identifier\n";
1928         }
1929     } else {
1930         print STDERR "${file}:$.: warning: Cannot understand $_ on line $.",
1931             " - I thought it was a doc line\n";
1932         ++$warnings;
1933         $state = STATE_NORMAL;
1934     }
1935 }
1936
1937
1938 #
1939 # STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
1940 #
1941 sub process_body($$) {
1942     my $file = shift;
1943
1944     # Until all named variable macro parameters are
1945     # documented using the bare name (`x`) rather than with
1946     # dots (`x...`), strip the dots:
1947     if ($section =~ /\w\.\.\.$/) {
1948         $section =~ s/\.\.\.$//;
1949
1950         if ($verbose) {
1951             print STDERR "${file}:$.: warning: Variable macro arguments should be documented without dots\n";
1952             ++$warnings;
1953         }
1954     }
1955
1956     if (/$doc_sect/i) { # case insensitive for supported section names
1957         $newsection = $1;
1958         $newcontents = $2;
1959
1960         # map the supported section names to the canonical names
1961         if ($newsection =~ m/^description$/i) {
1962             $newsection = $section_default;
1963         } elsif ($newsection =~ m/^context$/i) {
1964             $newsection = $section_context;
1965         } elsif ($newsection =~ m/^returns?$/i) {
1966             $newsection = $section_return;
1967         } elsif ($newsection =~ m/^\@return$/) {
1968             # special: @return is a section, not a param description
1969             $newsection = $section_return;
1970         }
1971
1972         if (($contents ne "") && ($contents ne "\n")) {
1973             if (!$in_doc_sect && $verbose) {
1974                 print STDERR "${file}:$.: warning: contents before sections\n";
1975                 ++$warnings;
1976             }
1977             dump_section($file, $section, $contents);
1978             $section = $section_default;
1979         }
1980
1981         $in_doc_sect = 1;
1982         $state = STATE_BODY;
1983         $contents = $newcontents;
1984         $new_start_line = $.;
1985         while (substr($contents, 0, 1) eq " ") {
1986             $contents = substr($contents, 1);
1987         }
1988         if ($contents ne "") {
1989             $contents .= "\n";
1990         }
1991         $section = $newsection;
1992         $leading_space = undef;
1993     } elsif (/$doc_end/) {
1994         if (($contents ne "") && ($contents ne "\n")) {
1995             dump_section($file, $section, $contents);
1996             $section = $section_default;
1997             $contents = "";
1998         }
1999         # look for doc_com + <text> + doc_end:
2000         if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2001             print STDERR "${file}:$.: warning: suspicious ending line: $_";
2002             ++$warnings;
2003         }
2004
2005         $prototype = "";
2006         $state = STATE_PROTO;
2007         $brcount = 0;
2008     } elsif (/$doc_content/) {
2009         # miguel-style comment kludge, look for blank lines after
2010         # @parameter line to signify start of description
2011         if ($1 eq "") {
2012             if ($section =~ m/^@/ || $section eq $section_context) {
2013                 dump_section($file, $section, $contents);
2014                 $section = $section_default;
2015                 $contents = "";
2016                 $new_start_line = $.;
2017             } else {
2018                 $contents .= "\n";
2019             }
2020             $state = STATE_BODY;
2021         } elsif ($state == STATE_BODY_MAYBE) {
2022             # Continued declaration purpose
2023             chomp($declaration_purpose);
2024             $declaration_purpose .= " " . $1;
2025             $declaration_purpose =~ s/\s+/ /g;
2026         } else {
2027             my $cont = $1;
2028             if ($section =~ m/^@/ || $section eq $section_context) {
2029                 if (!defined $leading_space) {
2030                     if ($cont =~ m/^(\s+)/) {
2031                         $leading_space = $1;
2032                     } else {
2033                         $leading_space = "";
2034                     }
2035                 }
2036                 $cont =~ s/^$leading_space//;
2037             }
2038             $contents .= $cont . "\n";
2039         }
2040     } else {
2041         # i dont know - bad line?  ignore.
2042         print STDERR "${file}:$.: warning: bad line: $_";
2043         ++$warnings;
2044     }
2045 }
2046
2047
2048 #
2049 # STATE_PROTO: reading a function/whatever prototype.
2050 #
2051 sub process_proto($$) {
2052     my $file = shift;
2053
2054     if (/$doc_inline_oneline/) {
2055         $section = $1;
2056         $contents = $2;
2057         if ($contents ne "") {
2058             $contents .= "\n";
2059             dump_section($file, $section, $contents);
2060             $section = $section_default;
2061             $contents = "";
2062         }
2063     } elsif (/$doc_inline_start/) {
2064         $state = STATE_INLINE;
2065         $inline_doc_state = STATE_INLINE_NAME;
2066     } elsif ($decl_type eq 'function') {
2067         process_proto_function($_, $file);
2068     } else {
2069         process_proto_type($_, $file);
2070     }
2071 }
2072
2073 #
2074 # STATE_DOCBLOCK: within a DOC: block.
2075 #
2076 sub process_docblock($$) {
2077     my $file = shift;
2078
2079     if (/$doc_end/) {
2080         dump_doc_section($file, $section, $contents);
2081         $section = $section_default;
2082         $contents = "";
2083         $function = "";
2084         %parameterdescs = ();
2085         %parametertypes = ();
2086         @parameterlist = ();
2087         %sections = ();
2088         @sectionlist = ();
2089         $prototype = "";
2090         $state = STATE_NORMAL;
2091     } elsif (/$doc_content/) {
2092         if ( $1 eq "" ) {
2093             $contents .= $blankline;
2094         } else {
2095             $contents .= $1 . "\n";
2096         }
2097     }
2098 }
2099
2100 #
2101 # STATE_INLINE: docbook comments within a prototype.
2102 #
2103 sub process_inline($$) {
2104     my $file = shift;
2105
2106     # First line (state 1) needs to be a @parameter
2107     if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2108         $section = $1;
2109         $contents = $2;
2110         $new_start_line = $.;
2111         if ($contents ne "") {
2112             while (substr($contents, 0, 1) eq " ") {
2113                 $contents = substr($contents, 1);
2114             }
2115             $contents .= "\n";
2116         }
2117         $inline_doc_state = STATE_INLINE_TEXT;
2118         # Documentation block end */
2119     } elsif (/$doc_inline_end/) {
2120         if (($contents ne "") && ($contents ne "\n")) {
2121             dump_section($file, $section, $contents);
2122             $section = $section_default;
2123             $contents = "";
2124         }
2125         $state = STATE_PROTO;
2126         $inline_doc_state = STATE_INLINE_NA;
2127         # Regular text
2128     } elsif (/$doc_content/) {
2129         if ($inline_doc_state == STATE_INLINE_TEXT) {
2130             $contents .= $1 . "\n";
2131             # nuke leading blank lines
2132             if ($contents =~ /^\s*$/) {
2133                 $contents = "";
2134             }
2135         } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2136             $inline_doc_state = STATE_INLINE_ERROR;
2137             print STDERR "${file}:$.: warning: ";
2138             print STDERR "Incorrect use of kernel-doc format: $_";
2139             ++$warnings;
2140         }
2141     }
2142 }
2143
2144
2145 sub process_file($) {
2146     my $file;
2147     my $initial_section_counter = $section_counter;
2148     my ($orig_file) = @_;
2149
2150     $file = map_filename($orig_file);
2151
2152     if (!open(IN,"<$file")) {
2153         print STDERR "Error: Cannot open file $file\n";
2154         ++$errors;
2155         return;
2156     }
2157
2158     $. = 1;
2159
2160     $section_counter = 0;
2161     while (<IN>) {
2162         while (s/\\\s*$//) {
2163             $_ .= <IN>;
2164         }
2165         # Replace tabs by spaces
2166         while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2167         # Hand this line to the appropriate state handler
2168         if ($state == STATE_NORMAL) {
2169             process_normal();
2170         } elsif ($state == STATE_NAME) {
2171             process_name($file, $_);
2172         } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE) {
2173             process_body($file, $_);
2174         } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2175             process_inline($file, $_);
2176         } elsif ($state == STATE_PROTO) {
2177             process_proto($file, $_);
2178         } elsif ($state == STATE_DOCBLOCK) {
2179             process_docblock($file, $_);
2180         }
2181     }
2182
2183     # Make sure we got something interesting.
2184     if ($initial_section_counter == $section_counter && $
2185         output_mode ne "none") {
2186         if ($output_selection == OUTPUT_INCLUDE) {
2187             print STDERR "${file}:1: warning: '$_' not found\n"
2188                 for keys %function_table;
2189         }
2190         else {
2191             print STDERR "${file}:1: warning: no structured comments found\n";
2192         }
2193     }
2194 }
2195
2196
2197 $kernelversion = get_kernel_version();
2198
2199 # generate a sequence of code that will splice in highlighting information
2200 # using the s// operator.
2201 for (my $k = 0; $k < @highlights; $k++) {
2202     my $pattern = $highlights[$k][0];
2203     my $result = $highlights[$k][1];
2204 #   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2205     $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2206 }
2207
2208 # Read the file that maps relative names to absolute names for
2209 # separate source and object directories and for shadow trees.
2210 if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2211         my ($relname, $absname);
2212         while(<SOURCE_MAP>) {
2213                 chop();
2214                 ($relname, $absname) = (split())[0..1];
2215                 $relname =~ s:^/+::;
2216                 $source_map{$relname} = $absname;
2217         }
2218         close(SOURCE_MAP);
2219 }
2220
2221 if ($output_selection == OUTPUT_EXPORTED ||
2222     $output_selection == OUTPUT_INTERNAL) {
2223
2224     push(@export_file_list, @ARGV);
2225
2226     foreach (@export_file_list) {
2227         chomp;
2228         process_export_file($_);
2229     }
2230 }
2231
2232 foreach (@ARGV) {
2233     chomp;
2234     process_file($_);
2235 }
2236 if ($verbose && $errors) {
2237   print STDERR "$errors errors\n";
2238 }
2239 if ($verbose && $warnings) {
2240   print STDERR "$warnings warnings\n";
2241 }
2242
2243 exit($output_mode eq "none" ? 0 : $errors);