Tests/CMakeTests/GetFilenameComponentRealpathTest.cmake.in

   1 set(bindir ${CMAKE_CURRENT_BINARY_DIR})
   2
   3 #
   4 # Test nonexistent REALPATH & ABSOLUTE resolution
   5 #
   6 get_filename_component(nonexistent1 ${bindir}/THIS_IS_A_NONEXISTENT_FILE REALPATH)
   7 get_filename_component(nonexistent2 ${bindir}/THIS_IS_A_NONEXISTENT_FILE ABSOLUTE)
   8 if(NOT nonexistent1 STREQUAL "${bindir}/THIS_IS_A_NONEXISTENT_FILE")
   9     message(FATAL_ERROR "REALPATH is not preserving nonexistent files")
  10 endif()
  11 if(NOT nonexistent2 STREQUAL "${bindir}/THIS_IS_A_NONEXISTENT_FILE")
  12     message(FATAL_ERROR "ABSOLUTE is not preserving nonexistent files")
  13 endif()
  14
  15 #
  16 # Test symbolic link resolution
  17 #
  18 if(UNIX)
  19     # file1 => file2 => file3 (real)
  20     file(WRITE ${bindir}/file3 "test file")
  21
  22     find_program(LN NAMES "ln")
  23     if(LN)
  24         # Create symlinks using "ln -s"
  25         if(NOT EXISTS ${bindir}/file2)
  26             execute_process(COMMAND ${LN} "-s" "${bindir}/file3" "${bindir}/file2")
  27         endif()
  28         if(NOT EXISTS ${bindir}/file1)
  29             execute_process(COMMAND ${LN} "-s" "${bindir}/file2" "${bindir}/file1")
  30         endif()
  31
  32         get_filename_component(file1 ${bindir}/file1 REALPATH)
  33         get_filename_component(file2 ${bindir}/file2 REALPATH)
  34         get_filename_component(file3 ${bindir}/file3 REALPATH)
  35
  36         if(NOT file3 STREQUAL "${bindir}/file3")
  37             message(FATAL_ERROR "CMake fails resolving REALPATH file file3")
  38         endif()
  39
  40         if(NOT file2 STREQUAL "${bindir}/file3")
  41             message(FATAL_ERROR "CMake fails resolving simple symlink")
  42         endif()
  43
  44         if(NOT file1 STREQUAL "${bindir}/file3")
  45             message(FATAL_ERROR "CMake fails resolving double symlink")
  46         endif()
  47
  48         # cleanup
  49         file(REMOVE ${bindir}/file1)
  50         file(REMOVE ${bindir}/file2)
  51         if(EXISTS file1 OR EXISTS file2)
  52            message(FATAL_ERROR "removal of file1 or file2 failed")
  53         endif()
  54     endif(LN)
  55
  56     file(REMOVE ${bindir}/file3)
  57 endif()