Tests/CMakeTests/CheckSourceTreeTest.cmake.in

   1 # Check the CMake source tree and report anything suspicious...
   2 #
   3 message("=============================================================================")
   4 message("CTEST_FULL_OUTPUT (Avoid ctest truncation of output)")
   5 message("")
   6 message("CMake_BINARY_DIR='${CMake_BINARY_DIR}'")
   7 message("CMake_SOURCE_DIR='${CMake_SOURCE_DIR}'")
   8 message("CVS_EXECUTABLE='${CVS_EXECUTABLE}'")
   9 message("ENV{DASHBOARD_TEST_FROM_CTEST}='$ENV{DASHBOARD_TEST_FROM_CTEST}'")
  10 message("")
  11
  12
  13 # Is the build directory the same as or underneath the source directory?
  14 # (i.e. - is it an "in source" build?)
  15 #
  16 set(in_source_build 0)
  17
  18 if(CMake_SOURCE_DIR STREQUAL "${CMake_BINARY_DIR}")
  19   message("build dir *is* source dir")
  20   set(in_source_build 1)
  21 else()
  22   string(LENGTH "${CMake_SOURCE_DIR}" src_len)
  23   string(LENGTH "${CMake_BINARY_DIR}" bin_len)
  24
  25   if(bin_len GREATER src_len)
  26     math(EXPR substr_len "${src_len}+1")
  27     string(SUBSTRING "${CMake_BINARY_DIR}" 0 ${substr_len} bin_dir)
  28     if(bin_dir STREQUAL "${CMake_SOURCE_DIR}/")
  29       message("build dir is under source dir")
  30       set(in_source_build 1)
  31     endif()
  32   endif()
  33 endif()
  34
  35 message("src_len='${src_len}'")
  36 message("bin_len='${bin_len}'")
  37 message("substr_len='${substr_len}'")
  38 message("bin_dir='${bin_dir}'")
  39 message("in_source_build='${in_source_build}'")
  40 message("")
  41
  42
  43 # Check with "cvs -q -n up -dP" if there are any local modifications to the
  44 # CMake source tree:
  45 #
  46 message("=============================================================================")
  47 message("Copy/paste this command to reproduce:")
  48 message("cd \"${CMake_SOURCE_DIR}\" && \"${CVS_EXECUTABLE}\" -q -n up -dP")
  49 message("")
  50 execute_process(COMMAND ${CVS_EXECUTABLE} -q -n up -dP
  51   WORKING_DIRECTORY ${CMake_SOURCE_DIR}
  52   OUTPUT_VARIABLE ov
  53   ERROR_VARIABLE ev
  54   RESULT_VARIABLE rv)
  55
  56 message("Results of running '${CVS_EXECUTABLE} -q -n up -dP'")
  57 message("rv='${rv}'")
  58 message("ov='${ov}'")
  59 message("ev='${ev}'")
  60 message("")
  61
  62 # Analyze cvs output:
  63 #
  64 set(additions 0)
  65 set(conflicts 0)
  66 set(modifications 0)
  67 set(nonadditions 0)
  68
  69 if(NOT ov STREQUAL "")
  70   string(REPLACE ";" "\\\\;" lines "${ov}")
  71   string(REPLACE "\n" "E;" lines "${lines}")
  72
  73   foreach(line ${lines})
  74     message("'${line}'")
  75
  76     # But do not consider files that exist just because some user poked around
  77     # the file system with Windows Explorer or with the Finder from a Mac...
  78     # ('Thumbs.db' and '.DS_Store' files...)
  79     #
  80     set(consider 1)
  81     set(ignore_files_regex "^(. |.*(/|\\\\))(\\.DS_Store|Thumbs.db)E$")
  82     if(line MATCHES "${ignore_files_regex}")
  83       message("   line matches '${ignore_files_regex}' -- not considered")
  84       set(consider 0)
  85     endif()
  86
  87     if(consider)
  88       if(line MATCHES "^A ")
  89         message("   locally added file/directory detected...")
  90         set(additions 1)
  91       endif()
  92
  93       if(line MATCHES "^C ")
  94         message("   conflict detected...")
  95         set(conflicts 1)
  96       endif()
  97
  98       if(line MATCHES "^M ")
  99         message("   locally modified file detected...")
 100         set(modifications 1)
 101       endif()
 102
 103       if(line MATCHES "^\\? ")
 104         message("   locally non-added file/directory detected...")
 105         set(nonadditions 1)
 106       endif()
 107     endif()
 108   endforeach()
 109 endif()
 110
 111 message("=============================================================================")
 112 message("additions='${additions}'")
 113 message("conflicts='${conflicts}'")
 114 message("modifications='${modifications}'")
 115 message("nonadditions='${nonadditions}'")
 116 message("")
 117
 118
 119 # Decide if the test passes or fails:
 120 #
 121 message("=============================================================================")
 122
 123 if("$ENV{DASHBOARD_TEST_FROM_CTEST}" STREQUAL "")
 124
 125   # developers are allowed to have local additions and modifications...
 126   set(is_dashboard 0)
 127   message("interactive test run")
 128   message("")
 129
 130 else()
 131
 132   set(is_dashboard 1)
 133   message("dashboard test run")
 134   message("")
 135
 136   # but dashboard machines are not allowed to have local additions or modifications...
 137   if(additions)
 138     message(FATAL_ERROR "test fails: local source tree additions")
 139   endif()
 140
 141   if(modifications)
 142     message(FATAL_ERROR "test fails: local source tree modifications")
 143   endif()
 144
 145   #
 146   # It's a dashboard run if ctest was run with '-D ExperimentalTest' or some
 147   # other -D arg on its command line or if ctest is running a -S script to run
 148   # a dashboard... Running ctest like that sets the DASHBOARD_TEST_FROM_CTEST
 149   # env var.
 150   #
 151
 152 endif()
 153
 154
 155 # ...and nobody is allowed to have local non-additions or conflicts...
 156 # Not even developers.
 157 #
 158 if(nonadditions)
 159   if(in_source_build AND is_dashboard)
 160     message("
 161 warning: test results confounded because this is an 'in-source' build - cannot
 162 distinguish between non-added files that are in-source build products and
 163 non-added source files that somebody forgot to 'cvs add'... - this is only ok
 164 if this is intentionally an in-source dashboard build... Developers should
 165 use out-of-source builds to verify a clean source tree with this test...
 166
 167 Allowing test to pass despite the warning message...
 168 ")
 169   else()
 170     message(FATAL_ERROR "test fails: local source tree non-additions: use cvs add before committing, or remove the files from the source tree")
 171   endif()
 172 endif()
 173
 174 if(conflicts)
 175   message(FATAL_ERROR "test fails: local source tree conflicts: resolve before committing")
 176 endif()
 177
 178
 179 # Still here? Good then...
 180 #
 181 message("test passes")
 182 message("")