CMakeLists.txt

   1 # If we are not building as a part of LLVM, build Clang as an
   2 # standalone project, using LLVM as an external library:
   3 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
   4   project(Clang)
   5   cmake_minimum_required(VERSION 2.8)
   6
   7   set(CLANG_PATH_TO_LLVM_SOURCE "" CACHE PATH
   8     "Path to LLVM source code. Not necessary if using an installed LLVM.")
   9   set(CLANG_PATH_TO_LLVM_BUILD "" CACHE PATH
  10     "Path to the directory where LLVM was built or installed.")
  11
  12   if( CLANG_PATH_TO_LLVM_SOURCE )
  13     if( NOT EXISTS "${CLANG_PATH_TO_LLVM_SOURCE}/cmake/config-ix.cmake" )
  14       message(FATAL_ERROR "Please set CLANG_PATH_TO_LLVM_SOURCE to the root directory of LLVM source code.")
  15     else()
  16       get_filename_component(LLVM_MAIN_SRC_DIR ${CLANG_PATH_TO_LLVM_SOURCE}
  17         ABSOLUTE)
  18       list(APPEND CMAKE_MODULE_PATH "${LLVM_MAIN_SRC_DIR}/cmake/modules")
  19     endif()
  20   endif()
  21
  22   if( NOT EXISTS "${CLANG_PATH_TO_LLVM_BUILD}/bin/tblgen${CMAKE_EXECUTABLE_SUFFIX}" )
  23     message(FATAL_ERROR "Please set CLANG_PATH_TO_LLVM_BUILD to a directory containing a LLVM build.")
  24   endif()
  25
  26   list(APPEND CMAKE_MODULE_PATH "${CLANG_PATH_TO_LLVM_BUILD}/share/llvm/cmake")
  27
  28   get_filename_component(PATH_TO_LLVM_BUILD ${CLANG_PATH_TO_LLVM_BUILD}
  29     ABSOLUTE)
  30
  31   include(AddLLVM)
  32   include(TableGen)
  33   include("${CLANG_PATH_TO_LLVM_BUILD}/share/llvm/cmake/LLVM.cmake")
  34   include(HandleLLVMOptions)
  35
  36   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  37
  38   set(LLVM_MAIN_INCLUDE_DIR "${LLVM_MAIN_SRC_DIR}/include")
  39   set(LLVM_BINARY_DIR ${CMAKE_BINARY_DIR})
  40
  41   set(CMAKE_INCLUDE_CURRENT_DIR ON)
  42   include_directories("${PATH_TO_LLVM_BUILD}/include" "${LLVM_MAIN_INCLUDE_DIR}")
  43   if( NOT PATH_TO_LLVM_BUILD STREQUAL LLVM_MAIN_SRC_DIR )
  44     include_directories("${LLVM_MAIN_INCLUDE_DIR}")
  45   endif()
  46   link_directories("${PATH_TO_LLVM_BUILD}/lib")
  47
  48   set(LLVM_TABLEGEN_EXE "${PATH_TO_LLVM_BUILD}/bin/tblgen")
  49
  50   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
  51   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib )
  52   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib )
  53
  54   add_definitions( -D__STDC_LIMIT_MACROS )
  55   add_definitions( -D__STDC_CONSTANT_MACROS )
  56
  57   set( CLANG_BUILT_STANDALONE 1 )
  58 endif()
  59
  60 set(CLANG_RESOURCE_DIR "" CACHE STRING
  61   "Relative directory from the Clang binary to its resource files.")
  62
  63 set(C_INCLUDE_DIRS "" CACHE STRING
  64   "Colon separated list of directories clang will search for headers.")
  65
  66 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  67 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  68
  69 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  70   message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
  71 "the makefiles distributed with LLVM. Please create a directory and run cmake "
  72 "from there, passing the path to this source directory as the last argument. "
  73 "This process created the file `CMakeCache.txt' and the directory "
  74 "`CMakeFiles'. Please delete them.")
  75 endif()
  76
  77 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  78   file(GLOB_RECURSE
  79     tablegenned_files_on_include_dir
  80     "${CLANG_SOURCE_DIR}/include/clang/*.inc")
  81   if( tablegenned_files_on_include_dir )
  82     message(FATAL_ERROR "Apparently there is a previous in-source build, "
  83 "probably as the result of running `configure' and `make' on "
  84 "${CLANG_SOURCE_DIR}. This may cause problems. The suspicious files are:\n"
  85 "${tablegenned_files_on_include_dir}\nPlease clean the source directory.")
  86   endif()
  87 endif()
  88
  89 # Compute the Clang version from the LLVM version.
  90 string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  91   ${PACKAGE_VERSION})
  92 message(STATUS "Clang version: ${CLANG_VERSION}")
  93
  94 string(REGEX REPLACE "([0-9]+)\\.[0-9]+(\\.[0-9]+)?" "\\1" CLANG_VERSION_MAJOR
  95   ${CLANG_VERSION})
  96 string(REGEX REPLACE "[0-9]+\\.([0-9]+)(\\.[0-9]+)?" "\\1" CLANG_VERSION_MINOR
  97   ${CLANG_VERSION})
  98 if (${CLANG_VERSION} MATCHES "[0-9]+\\.[0-9]+\\.[0-9]+")
  99   set(CLANG_HAS_VERSION_PATCHLEVEL 1)
 100   string(REGEX REPLACE "[0-9]+\\.[0-9]+\\.([0-9]+)" "\\1" CLANG_VERSION_PATCHLEVEL
 101     ${CLANG_VERSION})
 102 else()
 103   set(CLANG_HAS_VERSION_PATCHLEVEL 0)
 104 endif()
 105
 106 # Configure the Version.inc file.
 107 configure_file(
 108   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 109   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 110
 111 # Add appropriate flags for GCC
 112 if (CMAKE_COMPILER_IS_GNUCXX)
 113   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wcast-qual -fno-strict-aliasing -pedantic -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings")
 114 endif ()
 115
 116 if (APPLE)
 117   set(CMAKE_MODULE_LINKER_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 118 endif ()
 119
 120 configure_file(
 121   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 122   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)
 123
 124 macro(add_clang_library name)
 125   llvm_process_sources(srcs ${ARGN})
 126   if(MSVC_IDE OR XCODE)
 127     string( REGEX MATCHALL "/[^/]+" split_path ${CMAKE_CURRENT_SOURCE_DIR})
 128     list( GET split_path -1 dir)
 129     file( GLOB_RECURSE headers
 130       ../../../include/clang/StaticAnalyzer${dir}/*.h
 131       ../../../include/clang/StaticAnalyzer${dir}/*.td
 132       ../../../include/clang/StaticAnalyzer${dir}/*.def
 133       ../../include/clang${dir}/*.h
 134       ../../include/clang${dir}/*.td
 135       ../../include/clang${dir}/*.def)
 136     set(srcs ${srcs} ${headers})
 137   endif(MSVC_IDE OR XCODE)
 138   if (MODULE)
 139     set(libkind MODULE)
 140   elseif (SHARED_LIBRARY)
 141     set(libkind SHARED)
 142   else()
 143     set(libkind)
 144   endif()
 145   add_library( ${name} ${libkind} ${srcs} )
 146   if( LLVM_COMMON_DEPENDS )
 147     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 148   endif( LLVM_COMMON_DEPENDS )
 149   if( LLVM_USED_LIBS )
 150     foreach(lib ${LLVM_USED_LIBS})
 151       target_link_libraries( ${name} ${lib} )
 152     endforeach(lib)
 153   endif( LLVM_USED_LIBS )
 154   if( LLVM_LINK_COMPONENTS )
 155     llvm_config(${name} ${LLVM_LINK_COMPONENTS})
 156   endif( LLVM_LINK_COMPONENTS )
 157   if (LLVM_COMMON_LIBS)
 158     target_link_libraries(${name} ${LLVM_COMMON_LIBS})
 159   endif()
 160   if( NOT MINGW )
 161     get_system_libs(llvm_system_libs)
 162     if( llvm_system_libs )
 163       target_link_libraries(${name} ${llvm_system_libs})
 164     endif()
 165   endif()
 166   add_dependencies(${name} ClangDiagnosticCommon)
 167   if(MSVC)
 168     get_target_property(cflag ${name} COMPILE_FLAGS)
 169     if(NOT cflag)
 170       set(cflag "")
 171     endif(NOT cflag)
 172     set(cflag "${cflag} /Za")
 173     set_target_properties(${name} PROPERTIES COMPILE_FLAGS ${cflag})
 174   endif(MSVC)
 175   install(TARGETS ${name}
 176     LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 177     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 178 endmacro(add_clang_library)
 179
 180 macro(add_clang_executable name)
 181   add_llvm_executable( ${name} ${ARGN} )
 182 endmacro(add_clang_executable)
 183
 184 include_directories(
 185   ${CMAKE_CURRENT_SOURCE_DIR}/include
 186   ${CMAKE_CURRENT_BINARY_DIR}/include
 187   )
 188
 189 install(DIRECTORY include/
 190   DESTINATION include
 191   FILES_MATCHING
 192   PATTERN "*.def"
 193   PATTERN "*.h"
 194   PATTERN "*.td"
 195   PATTERN ".svn" EXCLUDE
 196   )
 197
 198 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 199   DESTINATION include
 200   FILES_MATCHING
 201   PATTERN "CMakeFiles" EXCLUDE
 202   PATTERN "*.inc"
 203   )
 204
 205 add_definitions( -D_GNU_SOURCE -DHAVE_CLANG_CONFIG_H )
 206
 207 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs." OFF)
 208 if(CLANG_BUILD_EXAMPLES)
 209   add_subdirectory(examples)
 210 endif ()
 211
 212 add_subdirectory(include)
 213 add_subdirectory(lib)
 214 add_subdirectory(tools)
 215 add_subdirectory(runtime)
 216
 217 # TODO: docs.
 218 add_subdirectory(test)
 219
 220 # FIXME: unittests require gtest.
 221 if( NOT CLANG_BUILT_STANDALONE )
 222   add_subdirectory(unittests)
 223 endif()
 224
 225 # Workaround for MSVS10 to avoid the Dialog Hell
 226 # FIXME: This could be removed with future version of CMake.
 227 if( CLANG_BUILT_STANDALONE AND MSVC_VERSION EQUAL 1600 )
 228   set(CLANG_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/Clang.sln")
 229   if( EXISTS "${CLANG_SLN_FILENAME}" )
 230     file(APPEND "${CLANG_SLN_FILENAME}" "\n# This should be regenerated!\n")
 231   endif()
 232 endif()