sqlite.lisp

   1 (defpackage :sqlite
   2   (:use :cl :iter)
   3   (:export :sqlite-handle
   4            :connect
   5            :set-busy-timeout
   6            :disconnect
   7            :sqlite-statement
   8            :prepare-statement
   9            :finalize-statement
  10            :step-statement
  11            :reset-statement
  12            :statement-column-value
  13            :bind-parameter
  14            :execute-non-query
  15            :execute-to-list
  16            :execute-single
  17            :execute-one-row-m-v
  18            :last-insert-rowid
  19            :with-transaction
  20            :with-open-database))
  21
  22 (in-package :sqlite)
  23
  24 ;(declaim (optimize (speed 3) (safety 0) (debug 0)))
  25
  26 (defclass sqlite-handle ()
  27   ((handle :accessor handle)
  28    (database-path :accessor database-path)
  29    (cache :accessor cache)
  30    (statements :initform nil :accessor sqlite-handle-statements))
  31   (:documentation "Class that encapsulates the connection to the database. Use connect and disconnect."))
  32
  33 (defmethod initialize-instance :after ((object sqlite-handle) &key (database-path ":memory:") &allow-other-keys)
  34   (cffi:with-foreign-object (ppdb 'sqlite-ffi:p-sqlite3)
  35     (let ((error-code (sqlite-ffi:sqlite3-open database-path ppdb)))
  36       (if (eq error-code :ok)
  37           (setf (handle object) (cffi:mem-ref ppdb 'sqlite-ffi:p-sqlite3)
  38                 (database-path object) database-path)
  39           (error "Received error code ~A when trying to open sqlite3 database ~A"
  40                  error-code database-path))))
  41   (setf (cache object) (make-instance 'sqlite.cache:mru-cache :cache-size 16 :destructor #'really-finalize-statement)))
  42
  43 (defun connect (database-path &key busy-timeout)
  44   "Connect to the sqlite database at the given DATABASE-PATH. Returns the SQLITE-HANDLE connected to the database. Use DISCONNECT to disconnect.
  45    Operations will wait for locked databases for up to BUSY-TIMEOUT milliseconds; if BUSY-TIMEOUT is NIL, then operations on locked databases will fail immediately."
  46   (let ((db (make-instance 'sqlite-handle
  47                            :database-path (etypecase database-path
  48                                             (string database-path)
  49                                             (pathname (namestring database-path))))))
  50     (when busy-timeout
  51       (set-busy-timeout db busy-timeout))
  52     db))
  53
  54 (defun set-busy-timeout (db milliseconds)
  55   "Sets the maximum amount of time to wait for a locked database."
  56   (sqlite-ffi:sqlite3-busy-timeout (handle db) milliseconds))
  57
  58 (defun disconnect (handle)
  59   "Disconnects the given HANDLE from the database. All further operations on the handle are invalid."
  60   (sqlite.cache:purge-cache (cache handle))
  61   (iter (with statements = (copy-list (sqlite-handle-statements handle)))
  62         (declare (dynamic-extent statements))
  63         (for statement in statements)
  64         (really-finalize-statement statement))
  65   (let ((error-code (sqlite-ffi:sqlite3-close (handle handle))))
  66     (unless (eq error-code :ok)
  67       (error "Received error code ~A when trying to close ~A (connected to ~A)" error-code handle (database-path handle)))))
  68
  69 (defclass sqlite-statement ()
  70   ((db :reader db :initarg :db)
  71    (handle :accessor handle)
  72    (sql :reader sql :initarg :sql)
  73    (columns-count :accessor resultset-columns-count)
  74    (columns-names :accessor resultset-columns-names)
  75    (parameters-count :accessor parameters-count)
  76    (parameters-names :accessor parameters-names))
  77   (:documentation "Class that represents the prepared statement."))
  78
  79 (defmethod initialize-instance :after ((object sqlite-statement) &key &allow-other-keys)
  80   (cffi:with-foreign-object (p-statement 'sqlite-ffi:p-sqlite3-stmt)
  81     (cffi:with-foreign-object (p-tail '(:pointer :char))
  82       (cffi:with-foreign-string (sql (sql object))
  83         (let ((error-code (sqlite-ffi:sqlite3-prepare (handle (db object)) sql -1 p-statement p-tail)))
  84           (unless (eq error-code :ok)
  85             (error "Error when trying to prepare sqlite statement '~A'. Code: ~A, message: ~A" (sql object) error-code (sqlite-ffi:sqlite3-errmsg (handle (db object)))))
  86           (unless (zerop (cffi:mem-ref (cffi:mem-ref p-tail '(:pointer :char)) :uchar))
  87             (error "SQL string '~A' contains more than one SQL statements" (sql object)))
  88           (setf (handle object) (cffi:mem-ref p-statement 'sqlite-ffi:p-sqlite3-stmt)
  89                 (resultset-columns-count object) (sqlite-ffi:sqlite3-column-count (handle object))
  90                 (resultset-columns-names object) (loop
  91                                                     for i below (resultset-columns-count object)
  92                                                     collect (sqlite-ffi:sqlite3-column-name (handle object) i))
  93                 (parameters-count object) (sqlite-ffi:sqlite3-bind-parameter-count (handle object))
  94                 (parameters-names object) (loop
  95                                              for i from 1 to (parameters-count object)
  96                                              collect (sqlite-ffi:sqlite3-bind-parameter-name (handle object) i))))))))
  97
  98 (defun prepare-statement (db sql)
  99   "Prepare the statement to the DB that will execute the commands that are in SQL.
 100
 101 Returns the SQLITE-STATEMENT.
 102
 103 SQL must contain exactly one statement.
 104 SQL may have some positional (not named) parameters specified with question marks.
 105
 106 Example:
 107
 108  select name from users where id = ?"
 109   (or (sqlite.cache:get-from-cache (cache db) sql)
 110       (let ((statement (make-instance 'sqlite-statement :db db :sql sql)))
 111         (push statement (sqlite-handle-statements db))
 112         statement)))
 113
 114 (defun really-finalize-statement (statement)
 115   (setf (sqlite-handle-statements (db statement))
 116         (delete statement (sqlite-handle-statements (db statement))))
 117   (sqlite-ffi:sqlite3-finalize (handle statement)))
 118
 119 (defun finalize-statement (statement)
 120   "Finalizes the statement and signals that associated resources may be released.
 121 Note: does not immediately release resources because statements are cached."
 122   (progn
 123     (let ((error-code (sqlite-ffi:sqlite3-reset (handle statement))))
 124      (unless (eq error-code :ok)
 125        (error "When resetting statement ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))
 126     (sqlite.cache:put-to-cache (cache (db statement)) (sql statement) statement)))
 127
 128 (defun step-statement (statement)
 129   "Steps to the next row of the resultset of STATEMENT.
 130 Returns T is successfully advanced to the next row and NIL if there are no more rows."
 131   (let ((error-code (sqlite-ffi:sqlite3-step (handle statement))))
 132     (case error-code
 133       (:done nil)
 134       (:row t)
 135       (t (error "When stepping statement ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))))
 136
 137 (defun reset-statement (statement)
 138   "Resets the STATEMENT and prepare it to be called again."
 139   (let ((error-code (sqlite-ffi:sqlite3-reset (handle statement))))
 140     (unless (eq error-code :ok)
 141       (error "When resetting statment ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement)))))))
 142
 143 (defun statement-column-value (statement column-number)
 144   "Returns the COLUMN-NUMBER-th column's value of the current row of the STATEMENT. Columns are numbered from zero.
 145 Returns:
 146  * NIL for NULL
 147  * INTEGER for integers
 148  * DOUBLE-FLOAT for floats
 149  * STRING for text
 150  * (SIMPLE-ARRAY (UNSIGNED-BYTE 8)) for BLOBs"
 151   (let ((type (sqlite-ffi:sqlite3-column-type (handle statement) column-number)))
 152     (ecase type
 153       (:null nil)
 154       (:text (sqlite-ffi:sqlite3-column-text (handle statement) column-number))
 155       (:integer (sqlite-ffi:sqlite3-column-int64 (handle statement) column-number))
 156       (:float (sqlite-ffi:sqlite3-column-double (handle statement) column-number))
 157       (:blob (let* ((blob-length (sqlite-ffi:sqlite3-column-bytes (handle statement) column-number))
 158                     (result (make-array (the fixnum blob-length) :element-type '(unsigned-byte 8)))
 159                     (blob (sqlite-ffi:sqlite3-column-blob (handle statement) column-number)))
 160                (loop
 161                   for i below blob-length
 162                   do (setf (aref result i) (cffi:mem-aref blob :unsigned-char i)))
 163                result)))))
 164
 165 (defun execute-non-query (db sql &rest parameters)
 166   "Executes the query SQL to the database DB with given PARAMETERS. Returns nothing.
 167
 168 Example:
 169
 170 (execute-non-query db \"insert into users (user_name, real_name) values (?, ?)\" \"joe\" \"Joe the User\")
 171
 172 See BIND-PARAMETER for the list of supported parameter types."
 173   (declare (dynamic-extent parameters))
 174   (let ((stmt (prepare-statement db sql)))
 175     (iter (for i from 1)
 176           (declare (type fixnum i))
 177           (for value in parameters)
 178           (bind-parameter stmt i value))
 179     (step-statement stmt)
 180     (finalize-statement stmt)
 181     (values)))
 182
 183 (defun execute-to-list (db sql &rest parameters)
 184   "Executes the query SQL to the database DB with given PARAMETERS. Returns the results as list of lists.
 185
 186 Example:
 187
 188 (execute-to-list db \"select id, user_name, real_name from users where user_name = ?\" \"joe\")
 189 =>
 190 ((1 \"joe\" \"Joe the User\")
 191  (2 \"joe\" \"Another Joe\"))
 192
 193 See BIND-PARAMETER for the list of supported parameter types."
 194   (declare (dynamic-extent parameters))
 195   (let ((stmt (prepare-statement db sql))
 196         result)
 197     (iter (for i from 1)
 198           (declare (type fixnum i))
 199           (for value in parameters)
 200           (bind-parameter stmt i value))
 201     (loop (if (step-statement stmt)
 202               (push (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 203                           (declare (type fixnum i))
 204                           (collect (statement-column-value stmt i)))
 205                     result)
 206               (return)))
 207     (finalize-statement stmt)
 208     (nreverse result)))
 209
 210 (defun execute-one-row-m-v (db sql &rest parameters)
 211   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first row as multiple values.
 212
 213 Example:
 214 (execute-one-row-m-v db \"select id, user_name, real_name from users where id = ?\" 1)
 215 =>
 216 (values 1 \"joe\" \"Joe the User\")
 217
 218 See BIND-PARAMETER for the list of supported parameter types."
 219   (let ((stmt (prepare-statement db sql)))
 220     (unwind-protect
 221          (progn
 222            (iter (for i from 1)
 223                  (declare (type fixnum i))
 224                  (for value in parameters)
 225                  (bind-parameter stmt i value))
 226            (if (step-statement stmt)
 227                (return-from execute-one-row-m-v
 228                  (values-list (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 229                                     (declare (type fixnum i))
 230                                     (collect (statement-column-value stmt i)))))
 231                (return-from execute-one-row-m-v
 232                  (values-list (loop repeat (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))) collect nil)))))
 233       (finalize-statement stmt))))
 234
 235 (defun statement-parameter-index (statement parameter-name)
 236   (sqlite-ffi:sqlite3-bind-parameter-index (handle statement) parameter-name))
 237
 238 (defun bind-parameter (statement parameter value)
 239   "Sets the PARAMETER-th parameter in STATEMENT to the VALUE.
 240 Parameters are numbered from one.
 241 Supported types:
 242  * NULL. Passed as NULL
 243  * INTEGER. Passed as an 64-bit integer
 244  * STRING. Passed as a string
 245  * FLOAT. Passed as a double
 246  * (VECTOR (UNSIGNED-BYTE 8)) and VECTOR that contains integers in range [0,256). Passed as a BLOB"
 247   (let ((index (etypecase parameter
 248                  (integer parameter)
 249                  (string (statement-parameter-index statement parameter)))))
 250     (declare (type fixnum index))
 251     (let ((error-code (typecase value
 252                         (null (sqlite-ffi:sqlite3-bind-null (handle statement) index))
 253                         (integer (sqlite-ffi:sqlite3-bind-int64 (handle statement) index value))
 254                         (double-float (sqlite-ffi:sqlite3-bind-double (handle statement) index value))
 255                         (real (sqlite-ffi:sqlite3-bind-double (handle statement) index (coerce value 'double-float)))
 256                         (string (sqlite-ffi:sqlite3-bind-text (handle statement) index value -1 (sqlite-ffi:destructor-transient)))
 257                         ((vector (unsigned-byte 8)) (cffi:with-pointer-to-vector-data (ptr value)
 258                                                       (sqlite-ffi:sqlite3-bind-blob (handle statement) index ptr (length value) (sqlite-ffi:destructor-transient))))
 259                         (vector (cffi:with-foreign-object (array :unsigned-char (length value))
 260                                   (loop
 261                                      for i from 0 below (length value)
 262                                      do (setf (cffi:mem-aref array :unsigned-char i) (aref value i)))
 263                                   (sqlite-ffi:sqlite3-bind-blob (handle statement) index array (length value) (sqlite-ffi:destructor-transient))))
 264                         (t (error "Do not know how to pass value ~A of type ~A to sqlite" value (type-of value))))))
 265       (unless (eq error-code :ok)
 266         (error "When binding parameter ~A to value ~A for statment ~A (sql: ~A), error ~A (~A)" parameter value statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))))
 267
 268 (defun execute-single (db sql &rest parameters)
 269   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first column of the first row as single value.
 270
 271 Example:
 272 (execute-single db \"select user_name from users where id = ?\" 1)
 273 =>
 274 \"joe\"
 275
 276 See BIND-PARAMETER for the list of supported parameter types."
 277   (declare (dynamic-extent parameters))
 278   (let ((stmt (prepare-statement db sql)))
 279     (unwind-protect
 280          (progn
 281            (iter (for i from 1)
 282                  (declare (type fixnum i))
 283                  (for value in parameters)
 284                  (bind-parameter stmt i value))
 285            (if (step-statement stmt)
 286                (statement-column-value stmt 0)
 287                nil))
 288       (finalize-statement stmt))))
 289
 290 (defun last-insert-rowid (db)
 291   "Returns the auto-generated ID of the last inserted row on the database connection DB."
 292   (sqlite-ffi:sqlite3-last-insert-rowid (handle db)))
 293
 294 (defmacro with-transaction (db &body body)
 295   "Wraps the BODY inside the transaction."
 296   (let ((ok (gensym "TRANSACTION-COMMIT-"))
 297         (db-var (gensym "DB-"))
 298         (result (gensym "RESULT-")))
 299     `(let (,ok
 300            (,db-var ,db))
 301        (execute-non-query ,db-var "begin transaction")
 302        (unwind-protect
 303             (progn
 304               (let ((,result (progn
 305                                ,@body)))
 306                 (setf ,ok t)
 307                 ,result))
 308          (if ,ok
 309              (execute-non-query ,db-var "commit transaction")
 310              (execute-non-query ,db-var "rollback transaction"))))))
 311
 312 (defmacro with-open-database ((db path &key busy-timeout) &body body)
 313   `(let ((,db (connect ,path :busy-timeout ,busy-timeout)))
 314      (unwind-protect
 315           (progn ,@body)
 316        (disconnect ,db))))
 317
 318 (defmacro-driver (FOR vars IN-SQLITE-QUERY query-expression ON-DATABASE db &optional WITH-PARAMETERS parameters)
 319   (let ((statement (gensym "STATEMENT-"))
 320         (kwd (if generate 'generate 'for)))
 321     `(progn (with ,statement = (prepare-statement ,db ,query-expression))
 322             (finally-protected (when ,statement (finalize-statement ,statement)))
 323             ,@(when parameters
 324                     (list `(initially ,@(iter (for i from 1)
 325                                               (for value in parameters)
 326                                               (collect `(sqlite:bind-parameter ,statement ,i ,value))))))
 327             (,kwd ,(if (symbolp vars)
 328                        `(values ,vars)
 329                        `(values ,@vars))
 330                   next (progn (if (step-statement ,statement)
 331                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 332                                                   (collect `(statement-column-value ,statement ,i))))
 333                                   (terminate)))))))
 334
 335 (defmacro-driver (FOR vars ON-SQLITE-STATEMENT statement)
 336   (let ((statement-var (gensym "STATEMENT-"))
 337         (kwd (if generate 'generate 'for)))
 338     `(progn (with ,statement-var = ,statement)
 339             (,kwd ,(if (symbolp vars)
 340                        `(values ,vars)
 341                        `(values ,@vars))
 342                   next (progn (if (step-statement ,statement-var)
 343                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 344                                                   (collect `(statement-column-value ,statement-var ,i))))
 345                                   (terminate)))))))