sqlite.lisp

   1 (defpackage :sqlite
   2   (:use :cl :iter)
   3   (:export :sqlite-handle
   4            :connect
   5            :disconnect
   6            :sqlite-statement
   7            :prepare-statement
   8            :finalize-statement
   9            :step-statement
  10            :reset-statement
  11            :statement-column-value
  12            :bind-parameter
  13            :execute-non-query
  14            :execute-to-list
  15            :execute-single
  16            :execute-one-row-m-v
  17            :last-insert-rowid
  18            :with-transaction
  19            :with-open-database))
  20
  21 (in-package :sqlite)
  22
  23 ;(declaim (optimize (speed 3) (safety 0) (debug 0)))
  24
  25 (defclass sqlite-handle ()
  26   ((handle :accessor handle)
  27    (database-path :accessor database-path)
  28    (cache :accessor cache)
  29    (statements :initform nil :accessor sqlite-handle-statements))
  30   (:documentation "Class that encapsulates the connection to the database. Use connect and disconnect."))
  31
  32 (defmethod initialize-instance :after ((object sqlite-handle) &key (database-path ":memory:") &allow-other-keys)
  33   (cffi:with-foreign-object (ppdb 'sqlite-ffi:p-sqlite3)
  34     (let ((error-code (sqlite-ffi:sqlite3-open database-path ppdb)))
  35       (if (eq error-code :ok)
  36           (setf (handle object) (cffi:mem-ref ppdb 'sqlite-ffi:p-sqlite3)
  37                 (database-path object) database-path)
  38           (error "Received error code ~A when trying to open sqlite3 database ~A"
  39                  error-code database-path))))
  40   (setf (cache object) (make-instance 'sqlite.cache:mru-cache :cache-size 16 :destructor #'really-finalize-statement)))
  41
  42 (defun connect (database-path)
  43   "Connect to the sqlite database at the given DATABASE-PATH. Returns the SQLITE-HANDLE connected to the database. Use DISCONNECT to disconnect."
  44   (make-instance 'sqlite-handle
  45                  :database-path (etypecase database-path
  46                                   (string database-path)
  47                                   (pathname (namestring database-path)))))
  48
  49 (defun disconnect (handle)
  50   "Disconnects the given HANDLE from the database. All further operations on the handle are invalid."
  51   (sqlite.cache:purge-cache (cache handle))
  52   (iter (with statements = (copy-list (sqlite-handle-statements handle)))
  53         (declare (dynamic-extent statements))
  54         (for statement in statements)
  55         (really-finalize-statement statement))
  56   (let ((error-code (sqlite-ffi:sqlite3-close (handle handle))))
  57     (unless (eq error-code :ok)
  58       (error "Received error code ~A when trying to close ~A (connected to ~A)" error-code handle (database-path handle)))))
  59
  60 (defclass sqlite-statement ()
  61   ((db :reader db :initarg :db)
  62    (handle :accessor handle)
  63    (sql :reader sql :initarg :sql)
  64    (columns-count :accessor resultset-columns-count)
  65    (columns-names :accessor resultset-columns-names)
  66    (parameters-count :accessor parameters-count)
  67    (parameters-names :accessor parameters-names))
  68   (:documentation "Class that represents the prepared statement."))
  69
  70 (defmethod initialize-instance :after ((object sqlite-statement) &key &allow-other-keys)
  71   (cffi:with-foreign-object (p-statement 'sqlite-ffi:p-sqlite3-stmt)
  72     (cffi:with-foreign-object (p-tail '(:pointer :char))
  73       (cffi:with-foreign-string (sql (sql object))
  74         (let ((error-code (sqlite-ffi:sqlite3-prepare (handle (db object)) sql -1 p-statement p-tail)))
  75           (unless (eq error-code :ok)
  76             (error "Error when trying to prepare sqlite statement '~A'. Code: ~A, message: ~A" (sql object) error-code (sqlite-ffi:sqlite3-errmsg (handle (db object)))))
  77           (unless (zerop (cffi:mem-ref (cffi:mem-ref p-tail '(:pointer :char)) :uchar))
  78             (error "SQL string '~A' contains more than one SQL statements" (sql object)))
  79           (setf (handle object) (cffi:mem-ref p-statement 'sqlite-ffi:p-sqlite3-stmt)
  80                 (resultset-columns-count object) (sqlite-ffi:sqlite3-column-count (handle object))
  81                 (resultset-columns-names object) (loop
  82                                                     for i below (resultset-columns-count object)
  83                                                     collect (sqlite-ffi:sqlite3-column-name (handle object) i))
  84                 (parameters-count object) (sqlite-ffi:sqlite3-bind-parameter-count (handle object))
  85                 (parameters-names object) (loop
  86                                              for i from 1 to (parameters-count object)
  87                                              collect (sqlite-ffi:sqlite3-bind-parameter-name (handle object) i))))))))
  88
  89 (defun prepare-statement (db sql)
  90   "Prepare the statement to the DB that will execute the commands that are in SQL.
  91
  92 Returns the SQLITE-STATEMENT.
  93
  94 SQL must contain exactly one statement.
  95 SQL may have some positional (not named) parameters specified with question marks.
  96
  97 Example:
  98
  99  select name from users where id = ?"
 100   (or (sqlite.cache:get-from-cache (cache db) sql)
 101       (let ((statement (make-instance 'sqlite-statement :db db :sql sql)))
 102         (push statement (sqlite-handle-statements db))
 103         statement)))
 104
 105 (defun really-finalize-statement (statement)
 106   (setf (sqlite-handle-statements (db statement))
 107         (delete statement (sqlite-handle-statements (db statement))))
 108   (sqlite-ffi:sqlite3-finalize (handle statement)))
 109
 110 (defun finalize-statement (statement)
 111   "Finalizes the statement and signals that associated resources may be released.
 112 Note: does not immediately release resources because statements are cached."
 113   (progn
 114     (let ((error-code (sqlite-ffi:sqlite3-reset (handle statement))))
 115      (unless (eq error-code :ok)
 116        (error "When resetting statement ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))
 117     (sqlite.cache:put-to-cache (cache (db statement)) (sql statement) statement)))
 118
 119 (defun step-statement (statement)
 120   "Steps to the next row of the resultset of STATEMENT.
 121 Returns T is successfully advanced to the next row and NIL if there are no more rows."
 122   (let ((error-code (sqlite-ffi:sqlite3-step (handle statement))))
 123     (case error-code
 124       (:done nil)
 125       (:row t)
 126       (t (error "When stepping statement ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))))
 127
 128 (defun reset-statement (statement)
 129   "Resets the STATEMENT and prepare it to be called again."
 130   (let ((error-code (sqlite-ffi:sqlite3-reset (handle statement))))
 131     (unless (eq error-code :ok)
 132       (error "When resetting statment ~A (sql: ~A), error ~A (~A)" statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement)))))))
 133
 134 (defun statement-column-value (statement column-number)
 135   "Returns the COLUMN-NUMBER-th column's value of the current row of the STATEMENT. Columns are numbered from zero.
 136 Returns:
 137  * NIL for NULL
 138  * INTEGER for integers
 139  * DOUBLE-FLOAT for floats
 140  * STRING for text
 141  * (SIMPLE-ARRAY (UNSIGNED-BYTE 8)) for BLOBs"
 142   (let ((type (sqlite-ffi:sqlite3-column-type (handle statement) column-number)))
 143     (ecase type
 144       (:null nil)
 145       (:text (sqlite-ffi:sqlite3-column-text (handle statement) column-number))
 146       (:integer (sqlite-ffi:sqlite3-column-int64 (handle statement) column-number))
 147       (:float (sqlite-ffi:sqlite3-column-double (handle statement) column-number))
 148       (:blob (let* ((blob-length (sqlite-ffi:sqlite3-column-bytes (handle statement) column-number))
 149                     (result (make-array (the fixnum blob-length) :element-type '(unsigned-byte 8)))
 150                     (blob (sqlite-ffi:sqlite3-column-blob (handle statement) column-number)))
 151                (loop
 152                   for i below blob-length
 153                   do (setf (aref result i) (cffi:mem-aref blob :unsigned-char i)))
 154                result)))))
 155
 156 (defun execute-non-query (db sql &rest parameters)
 157   "Executes the query SQL to the database DB with given PARAMETERS. Returns nothing.
 158
 159 Example:
 160
 161 (execute-non-query db \"insert into users (user_name, real_name) values (?, ?)\" \"joe\" \"Joe the User\")
 162
 163 See BIND-PARAMETER for the list of supported parameter types."
 164   (declare (dynamic-extent parameters))
 165   (let ((stmt (prepare-statement db sql)))
 166     (iter (for i from 1)
 167           (declare (type fixnum i))
 168           (for value in parameters)
 169           (bind-parameter stmt i value))
 170     (step-statement stmt)
 171     (finalize-statement stmt)
 172     (values)))
 173
 174 (defun execute-to-list (db sql &rest parameters)
 175   "Executes the query SQL to the database DB with given PARAMETERS. Returns the results as list of lists.
 176
 177 Example:
 178
 179 (execute-to-list db \"select id, user_name, real_name from users where user_name = ?\" \"joe\")
 180 =>
 181 ((1 \"joe\" \"Joe the User\")
 182  (2 \"joe\" \"Another Joe\"))
 183
 184 See BIND-PARAMETER for the list of supported parameter types."
 185   (declare (dynamic-extent parameters))
 186   (let ((stmt (prepare-statement db sql))
 187         result)
 188     (iter (for i from 1)
 189           (declare (type fixnum i))
 190           (for value in parameters)
 191           (bind-parameter stmt i value))
 192     (loop (if (step-statement stmt)
 193               (push (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 194                           (declare (type fixnum i))
 195                           (collect (statement-column-value stmt i)))
 196                     result)
 197               (return)))
 198     (finalize-statement stmt)
 199     (nreverse result)))
 200
 201 (defun execute-one-row-m-v (db sql &rest parameters)
 202   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first row as multiple values.
 203
 204 Example:
 205 (execute-one-row-m-v db \"select id, user_name, real_name from users where id = ?\" 1)
 206 =>
 207 (values 1 \"joe\" \"Joe the User\")
 208
 209 See BIND-PARAMETER for the list of supported parameter types."
 210   (let ((stmt (prepare-statement db sql)))
 211     (unwind-protect
 212          (progn
 213            (iter (for i from 1)
 214                  (declare (type fixnum i))
 215                  (for value in parameters)
 216                  (bind-parameter stmt i value))
 217            (if (step-statement stmt)
 218                (return-from execute-one-row-m-v
 219                  (values-list (iter (for i from 0 below (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))))
 220                                     (declare (type fixnum i))
 221                                     (collect (statement-column-value stmt i)))))
 222                (return-from execute-one-row-m-v
 223                  (values-list (loop repeat (the fixnum (sqlite-ffi:sqlite3-column-count (handle stmt))) collect nil)))))
 224       (finalize-statement stmt))))
 225
 226 (defun statement-parameter-index (statement parameter-name)
 227   (sqlite-ffi:sqlite3-bind-parameter-index (handle statement) parameter-name))
 228
 229 (defun bind-parameter (statement parameter value)
 230   "Sets the PARAMETER-th parameter in STATEMENT to the VALUE.
 231 Parameters are numbered from one.
 232 Supported types:
 233  * NULL. Passed as NULL
 234  * INTEGER. Passed as an 64-bit integer
 235  * STRING. Passed as a string
 236  * FLOAT. Passed as a double
 237  * (VECTOR (UNSIGNED-BYTE 8)) and VECTOR that contains integers in range [0,256). Passed as a BLOB"
 238   (let ((index (etypecase parameter
 239                  (integer parameter)
 240                  (string (statement-parameter-index statement parameter)))))
 241     (declare (type fixnum index))
 242     (let ((error-code (typecase value
 243                         (null (sqlite-ffi:sqlite3-bind-null (handle statement) index))
 244                         (integer (sqlite-ffi:sqlite3-bind-int64 (handle statement) index value))
 245                         (double-float (sqlite-ffi:sqlite3-bind-double (handle statement) index value))
 246                         (real (sqlite-ffi:sqlite3-bind-double (handle statement) index (coerce value 'double-float)))
 247                         (string (sqlite-ffi:sqlite3-bind-text (handle statement) index value -1 (sqlite-ffi:destructor-transient)))
 248                         ((vector (unsigned-byte 8)) (cffi:with-pointer-to-vector-data (ptr value)
 249                                                       (sqlite-ffi:sqlite3-bind-blob (handle statement) index ptr (length value) (sqlite-ffi:destructor-transient))))
 250                         (vector (cffi:with-foreign-object (array :unsigned-char (length value))
 251                                   (loop
 252                                      for i from 0 below (length value)
 253                                      do (setf (cffi:mem-aref array :unsigned-char i) (aref value i)))
 254                                   (sqlite-ffi:sqlite3-bind-blob (handle statement) index array (length value) (sqlite-ffi:destructor-transient))))
 255                         (t (error "Do not know how to pass value ~A of type ~A to sqlite" value (type-of value))))))
 256       (unless (eq error-code :ok)
 257         (error "When binding parameter ~A to value ~A for statment ~A (sql: ~A), error ~A (~A)" parameter value statement (sql statement) error-code (sqlite-ffi:sqlite3-errmsg (handle (db statement))))))))
 258
 259 (defun execute-single (db sql &rest parameters)
 260   "Executes the query SQL to the database DB with given PARAMETERS. Returns the first column of the first row as single value.
 261
 262 Example:
 263 (execute-single db \"select user_name from users where id = ?\" 1)
 264 =>
 265 \"joe\"
 266
 267 See BIND-PARAMETER for the list of supported parameter types."
 268   (declare (dynamic-extent parameters))
 269   (let ((stmt (prepare-statement db sql)))
 270     (unwind-protect
 271          (progn
 272            (iter (for i from 1)
 273                  (declare (type fixnum i))
 274                  (for value in parameters)
 275                  (bind-parameter stmt i value))
 276            (if (step-statement stmt)
 277                (statement-column-value stmt 0)
 278                nil))
 279       (finalize-statement stmt))))
 280
 281 (defun last-insert-rowid (db)
 282   "Returns the auto-generated ID of the last inserted row on the database connection DB."
 283   (sqlite-ffi:sqlite3-last-insert-rowid (handle db)))
 284
 285 (defmacro with-transaction (db &body body)
 286   "Wraps the BODY inside the transaction."
 287   (let ((ok (gensym "TRANSACTION-COMMIT-"))
 288         (db-var (gensym "DB-"))
 289         (result (gensym "RESULT-")))
 290     `(let (,ok
 291            (,db-var ,db))
 292        (execute-non-query ,db-var "begin transaction")
 293        (unwind-protect
 294             (progn
 295               (let ((,result (progn
 296                                ,@body)))
 297                 (setf ,ok t)
 298                 ,result))
 299          (if ,ok
 300              (execute-non-query ,db-var "commit transaction")
 301              (execute-non-query ,db-var "rollback transaction"))))))
 302
 303 (defmacro with-open-database ((db path) &body body)
 304   `(let ((,db (connect ,path)))
 305      (unwind-protect
 306           (progn ,@body)
 307        (disconnect ,db))))
 308
 309 (defmacro-driver (FOR vars IN-SQLITE-QUERY query-expression ON-DATABASE db &optional WITH-PARAMETERS parameters)
 310   (let ((statement (gensym "STATEMENT-"))
 311         (kwd (if generate 'generate 'for)))
 312     `(progn (with ,statement = (prepare-statement ,db ,query-expression))
 313             (finally-protected (when ,statement (finalize-statement ,statement)))
 314             ,@(when parameters
 315                     (list `(initially ,@(iter (for i from 1)
 316                                               (for value in parameters)
 317                                               (collect `(sqlite:bind-parameter ,statement ,i ,value))))))
 318             (,kwd ,(if (symbolp vars)
 319                        `(values ,vars)
 320                        `(values ,@vars))
 321                   next (progn (if (step-statement ,statement)
 322                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 323                                                   (collect `(statement-column-value ,statement ,i))))
 324                                   (terminate)))))))
 325
 326 (defmacro-driver (FOR vars ON-SQLITE-STATEMENT statement)
 327   (let ((statement-var (gensym "STATEMENT-"))
 328         (kwd (if generate 'generate 'for)))
 329     `(progn (with ,statement-var = ,statement)
 330             (,kwd ,(if (symbolp vars)
 331                        `(values ,vars)
 332                        `(values ,@vars))
 333                   next (progn (if (step-statement ,statement-var)
 334                                   (values ,@(iter (for i from 0 below (if (symbolp vars) 1 (length vars)))
 335                                                   (collect `(statement-column-value ,statement-var ,i))))
 336                                   (terminate)))))))