components/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6
   7 # Collection of all components. You wouldn't link to this, but this is rather
   8 # to reference the files so they can be compiled by the build system.
   9 group("all_components") {
  10   visibility = "//:*"  # Only for the root targets to bring in.
  11
  12   deps = [
  13     "//components/auto_login_parser",
  14     "//components/autofill/content/browser",
  15     "//components/autofill/content/common",
  16     "//components/autofill/content/renderer",
  17     "//components/bookmarks/browser",
  18     "//components/bookmarks/common",
  19     "//components/bookmarks/test",
  20     "//components/captive_portal",
  21     "//components/cdm/browser",
  22     "//components/cdm/common",
  23     "//components/cdm/renderer",
  24     "//components/cloud_devices/common",
  25     "//components/component_updater",
  26     "//components/crash/app",
  27     "//components/crash/browser",
  28     "//components/crx_file",
  29     "//components/data_reduction_proxy/browser",
  30     "//components/data_reduction_proxy/common",
  31     "//components/dom_distiller/core",
  32     "//components/domain_reliability",
  33     "//components/enhanced_bookmarks",
  34     "//components/favicon/core",
  35     "//components/favicon_base",
  36     "//components/feedback",
  37     "//components/gcm_driver",
  38     "//components/google/core/browser",
  39     "//components/history/core/browser",
  40     "//components/history/core/common",
  41     "//components/history/core/test",
  42     "//components/infobars/core",
  43     "//components/infobars/test:test_support",
  44     "//components/invalidation",
  45     "//components/json_schema",
  46     "//components/keyed_service/content",
  47     "//components/language_usage_metrics",
  48     "//components/leveldb_proto",
  49     "//components/metrics",
  50     "//components/navigation_interception",
  51     "//components/navigation_metrics",
  52     "//components/network_time",
  53     "//components/omaha_query_params",
  54     "//components/omnibox",
  55     "//components/onc",
  56     "//components/os_crypt",
  57     "//components/pairing",
  58     "//components/password_manager/content/browser",
  59     "//components/password_manager/core/browser",
  60     "//components/password_manager/core/common",
  61     "//components/pdf/browser",
  62     "//components/pdf/common",
  63     "//components/pdf/renderer",
  64     "//components/plugins/renderer",
  65     "//components/policy",
  66     "//components/power",
  67     "//components/precache/core",
  68     "//components/precache/content",
  69     "//components/pref_registry",
  70     "//components/proximity_auth",
  71     "//components/query_parser",
  72     "//components/rappor",
  73     "//components/renderer_context_menu",
  74     "//components/resources:components_resources",
  75     "//components/search",
  76     "//components/search_engines",
  77     "//components/search_provider_logos",
  78     "//components/sessions",
  79     "//components/signin/core/browser",
  80     "//components/startup_metric_utils",
  81     "//components/strings",
  82     "//components/sync_driver",
  83     "//components/tracing",
  84     "//components/translate/content/browser",
  85     "//components/translate/content/common",
  86     "//components/translate/content/renderer",
  87     "//components/translate/core/browser",
  88     "//components/translate/core/common",
  89     "//components/url_fixer",
  90     "//components/url_matcher",
  91     "//components/usb_service",
  92     "//components/user_manager",
  93     "//components/user_prefs",
  94     "//components/variations",
  95     "//components/visitedlink/browser",
  96     "//components/visitedlink/common",
  97     "//components/visitedlink/renderer",
  98     "//components/web_modal",
  99     "//components/webdata/common",
 100     "//components/wifi",
 101   ]
 102
 103   if (!is_win && !is_mac) {
 104     deps -= [ "//components/wifi" ]
 105   }
 106   if (!is_chromeos) {
 107     deps -= [ "//components/pairing" ]
 108   }
 109
 110   if (is_ios) {
 111     deps -= [ "//components/keyed_service/content" ]
 112   }
 113
 114   if (!enable_plugins) {
 115     deps -= [
 116       "//components/pdf/browser",
 117       "//components/pdf/common",
 118       "//components/pdf/renderer",
 119     ]
 120   }
 121
 122   if (is_android) {
 123     deps -= [
 124       "//components/autofill/content/browser",  # Blocked on content/blink.
 125       "//components/autofill/content/common",  # Blocked on content.
 126       "//components/autofill/content/renderer",  # Blocked on content/blink.
 127       "//components/crash/app",  # Should work, needs checking.
 128       "//components/crash/browser",  # Should work, needs checking.
 129       "//components/captive_portal",  # Should work, needs checking.
 130       "//components/cloud_devices/common",  # Should work, needs checking.
 131       "//components/cdm/browser",  # Blocked on content.
 132       "//components/cdm/common",  # Blocked on content.
 133       "//components/cdm/renderer",  # Blocked on content.
 134       "//components/data_reduction_proxy/browser",  # Should work, needs checking.
 135       "//components/data_reduction_proxy/common",  # Should work, needs checking.
 136       "//components/dom_distiller/core",  # Blocked on content.
 137       "//components/domain_reliability",  # Blocked on content.
 138       "//components/favicon_base",  # Should work, needs checking.
 139       "//components/favicon/core",  # Blocked on keyed service.
 140       "//components/feedback",  # Blocked on content.
 141       "//components/gcm_driver",  # Should work, needs checking.
 142       "//components/google/core/browser",  # Should work, needs checking.
 143       "//components/history/core/browser",  # Should work, needs checking.
 144       "//components/history/core/common",  # Should work, needs checking.
 145       "//components/history/core/test",  # Should work, needs checking.
 146       "//components/infobars/core",  # Should work, needs checking.
 147       "//components/infobars/test:test_support",  # Should work, needs checking.
 148       "//components/invalidation",  # Should work, needs checking.
 149       "//components/json_schema",  # Should work, needs checking.
 150       "//components/keyed_service/content",  # Blocked on content.
 151       "//components/navigation_interception",  # Blocked on content.
 152       "//components/omnibox",  # Should work, needs checking.
 153       "//components/password_manager/content/browser",  # Blocked on content.
 154       "//components/password_manager/core/browser",  # Should work, needs checking.
 155       "//components/password_manager/core/common",  # Should work, needs checking.
 156       "//components/plugins/renderer",  # Blocked on blink.
 157       "//components/power",  # Blocked on content.
 158       "//components/policy",  # Blocked on content (indirectly via autofill).
 159       "//components/precache/content",  # Blocked on content.
 160       "//components/precache/core",  # Should work, needs checking.
 161       "//components/rappor",  # Should work, needs checking.
 162       "//components/renderer_context_menu",  # Blocked on content.
 163       "//components/search_engines",  # Should work, needs checking.
 164       "//components/search_provider_logos",  # Should work, needs checking.
 165       "//components/sessions",  # Blocked on content.
 166       "//components/signin/core/browser",  # Should work, needs checking.
 167       "//components/translate/content/browser",  # Blocked on content.
 168       "//components/translate/content/common",  # Blocked on content.
 169       "//components/translate/content/renderer",  # Blocked on content.
 170       "//components/usb_service",  # Blocked on content.
 171       "//components/user_prefs",  # Blocked on content.
 172       "//components/visitedlink/browser",  # Blocked on content.
 173       "//components/visitedlink/common",  # Blocked on content.
 174       "//components/visitedlink/renderer",  # Blocked on blink
 175       "//components/web_modal",  # Blocked on content.
 176     ]
 177   }
 178
 179   if (!is_ios && !is_android) {
 180     deps += [
 181       "//components/copresence",
 182       "//components/storage_monitor",
 183     ]
 184   }
 185 }
 186
 187 # TODO(GYP) enable when it links.
 188 if (false) {
 189
 190 # To add a unit test to this target, make a "unit_test" source_set in your
 191 # component (it's important to use a source_set instead of a static library or
 192 # no tests will run) and add a reference here. You can add more than one unit
 193 # test target if convenient.
 194 test("components_unittests") {
 195   sources = [
 196     "test/run_all_unittests.cc",
 197   ]
 198
 199   # Add only ":unit_tests" dependencies here. If your tests have dependencies
 200   # (this would at least include the component itself), they should be on the
 201   # test source set and not here.
 202   deps = [
 203     "//components/auto_login_parser:unit_tests",
 204     "//components/autofill/content/browser:unit_tests",
 205     "//components/autofill/core/browser:unit_tests",
 206     "//components/autofill/core/common:unit_tests",
 207     "//components/bookmarks/browser:unit_tests",
 208     "//components/captive_portal:unit_tests",
 209     "//components/cloud_devices/common:unit_tests",
 210     "//components/component_updater:unit_tests",
 211     "//components/crx_file:unit_tests",
 212     "//components/data_reduction_proxy/browser:unit_tests",
 213     "//components/data_reduction_proxy/common:unit_tests",
 214     "//components/dom_distiller/core:unit_tests",
 215     "//components/domain_reliability:unit_tests",
 216     "//components/omnibox:unit_tests",
 217     "//components/ownership:unit_tests",
 218     "//components/proximity_auth:unit_tests",
 219   ]
 220
 221   # TODO(GYP) need this target.
 222   #'breakpad/app/crash_keys_win_unittest.cc',
 223
 224   # Precache tests need these defines.
 225   #configs += [ "//components/precache/core:precache_config" ]
 226 }
 227
 228 }