third_party/sqlite/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 config("sqlite_config") {
   6   include_dirs = [ "." ]
   7 }
   8
   9 source_set("sqlite") {
  10   sources = [
  11     "amalgamation/sqlite3.h",
  12     "amalgamation/sqlite3.c",
  13
  14     # fts2.c currently has a lot of conflicts when added to
  15     # the amalgamation.  It is probably not worth fixing that.
  16     "src/ext/fts2/fts2.c",
  17     "src/ext/fts2/fts2.h",
  18     "src/ext/fts2/fts2_hash.c",
  19     "src/ext/fts2/fts2_hash.h",
  20     "src/ext/fts2/fts2_icu.c",
  21     "src/ext/fts2/fts2_porter.c",
  22     "src/ext/fts2/fts2_tokenizer.c",
  23     "src/ext/fts2/fts2_tokenizer.h",
  24     "src/ext/fts2/fts2_tokenizer1.c",
  25   ]
  26
  27   cflags = []
  28   defines = [
  29     "SQLITE_CORE",
  30     "SQLITE_ENABLE_BROKEN_FTS2",
  31     "SQLITE_ENABLE_FTS2",
  32     "SQLITE_ENABLE_FTS3",
  33     "SQLITE_ENABLE_ICU",
  34     "SQLITE_ENABLE_MEMORY_MANAGEMENT",
  35     "SQLITE_SECURE_DELETE",
  36     "SQLITE_SEPARATE_CACHE_POOLS",
  37     "THREADSAFE",
  38     "_HAS_EXCEPTIONS=0",
  39   ]
  40   if (is_chromeos) {
  41     defines += [
  42       # Despite obvious warnings about not using this flag in deployment, we
  43       # are turning off sync in ChromeOS and relying on the underlying
  44       # journaling filesystem to do error recovery properly. It's much faster.
  45       "SQLITE_NO_SYNC",
  46     ]
  47   }
  48   if (is_posix) {
  49     defines += [
  50       # Allow xSleep() call on Unix to use usleep() rather than sleep(), so it
  51       # will have microsecond precision.  Should only affect contended databases
  52       # via the busy callback.  Browser profile databases are mostly exclusive,
  53       # but renderer databases may allow for contention.
  54       "HAVE_USLEEP=1",
  55     ]
  56   }
  57
  58   include_dirs = [
  59     "amalgamation",
  60     "src/src",  # Needed for fts2 to build.
  61   ]
  62
  63   configs -= [ "//build/config/compiler:chromium_code" ]
  64   configs += [ "//build/config/compiler:no_chromium_code" ]
  65
  66   if (is_win) {
  67     cflags += [ "/wd4267" ]  # Conversion from size_t to "type".
  68   } else if (is_linux) {
  69     cflags += [
  70       # SQLite doesn"t believe in compiler warnings,
  71       # preferring testing.
  72       #   http://www.sqlite.org/faq.html#q17
  73       "-Wno-int-to-pointer-cast",
  74       "-Wno-pointer-to-int-cast",
  75     ]
  76     libs = [ "dl" ]
  77   } else if (is_mac || is_ios) {
  78     libs = [ "CoreFoundation.framework" ]
  79   } else if (is_android) {
  80     defines += [
  81       "SQLITE_DEFAULT_JOURNAL_SIZE_LIMIT=1048576",
  82       "SQLITE_DEFAULT_AUTOVACUUM=1",
  83       "SQLITE_TEMP_STORE=3",
  84       "SQLITE_ENABLE_FTS3_BACKWARDS",
  85       "DSQLITE_DEFAULT_FILE_FORMAT=4",
  86     ]
  87   }
  88
  89   if (is_clang) {
  90     cflags += [
  91       # sqlite does `if (*a++ && *b++);` in a non-buggy way.
  92       "-Wno-empty-body",
  93
  94       # sqlite has some `unsigned < 0` checks.
  95       "-Wno-tautological-compare",
  96
  97       # Needed because we don't have this commit yet:
  98       # https://github.com/mackyle/sqlite/commit/25df0fa050dcc9be7fb937b8e25be24049b3fef0
  99       "-Wno-pointer-bool-conversion",
 100     ]
 101   }
 102
 103   public_configs = [ ":sqlite_config" ]
 104
 105   deps = [
 106     "//third_party/icu",
 107   ]
 108 }
 109
 110 if (is_linux) {
 111   executable("sqlite_shell") {
 112     sources = [
 113       "src/src/shell.c",
 114       "src/src/shell_icu_linux.c",
 115
 116       # Include a dummy c++ file to force linking of libstdc++.
 117       "build_as_cpp.cc",
 118     ]
 119
 120     deps = [
 121       ":sqlite",
 122       "//third_party/icu",
 123     ]
 124   }
 125 }
 126
 127 if (is_ios) {
 128   source_set("sqlite_regexp") {
 129     sources = [
 130       "src/ext/icu/icu.c",
 131     ]
 132     deps = [
 133       "//third_party/icu",
 134     ]
 135   }
 136 }