crypto/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//testing/test.gni")
   7
   8 component("crypto") {
   9   output_name = "crcrypto"  # Avoid colliding with OpenSSL's libcrypto.
  10   sources = [
  11     "apple_keychain.h",
  12     "apple_keychain_ios.mm",
  13     "apple_keychain_mac.mm",
  14     "capi_util.cc",
  15     "capi_util.h",
  16     "crypto_export.h",
  17     "cssm_init.cc",
  18     "cssm_init.h",
  19     "curve25519.cc",
  20     "curve25519-donna.c",
  21     "curve25519.h",
  22     "ec_private_key.h",
  23     "ec_private_key_nss.cc",
  24     "ec_private_key_openssl.cc",
  25     "ec_signature_creator.cc",
  26     "ec_signature_creator.h",
  27     "ec_signature_creator_impl.h",
  28     "ec_signature_creator_nss.cc",
  29     "ec_signature_creator_openssl.cc",
  30     "encryptor.cc",
  31     "encryptor.h",
  32     "encryptor_nss.cc",
  33     "encryptor_openssl.cc",
  34     "ghash.cc",
  35     "ghash.h",
  36     "hkdf.cc",
  37     "hkdf.h",
  38     "hmac.cc",
  39     "hmac.h",
  40     "hmac_nss.cc",
  41     "hmac_openssl.cc",
  42     "mac_security_services_lock.cc",
  43     "mac_security_services_lock.h",
  44
  45     # TODO(brettw) these mocks should be moved to a test_support_crypto target
  46     # if possible.
  47     "mock_apple_keychain.cc",
  48     "mock_apple_keychain.h",
  49     "mock_apple_keychain_ios.cc",
  50     "mock_apple_keychain_mac.cc",
  51     "nss_util.cc",
  52     "nss_util.h",
  53     "nss_util_internal.h",
  54     "openssl_bio_string.cc",
  55     "openssl_bio_string.h",
  56     "openssl_util.cc",
  57     "openssl_util.h",
  58     "p224.cc",
  59     "p224.h",
  60     "p224_spake.cc",
  61     "p224_spake.h",
  62     "random.cc",
  63     "random.h",
  64     "rsa_private_key.cc",
  65     "rsa_private_key.h",
  66     "rsa_private_key_nss.cc",
  67     "rsa_private_key_openssl.cc",
  68     "scoped_capi_types.h",
  69     "scoped_nss_types.h",
  70     "secure_hash_default.cc",
  71     "secure_hash.h",
  72     "secure_hash_openssl.cc",
  73     "secure_util.cc",
  74     "secure_util.h",
  75     "sha2.cc",
  76     "sha2.h",
  77     "signature_creator.h",
  78     "signature_creator_nss.cc",
  79     "signature_creator_openssl.cc",
  80     "signature_verifier.h",
  81     "signature_verifier_nss.cc",
  82     "signature_verifier_openssl.cc",
  83     "symmetric_key.h",
  84     "symmetric_key_nss.cc",
  85     "symmetric_key_openssl.cc",
  86     "third_party/nss/chromium-blapi.h",
  87     "third_party/nss/chromium-blapit.h",
  88     "third_party/nss/chromium-nss.h",
  89     "third_party/nss/chromium-sha256.h",
  90     "third_party/nss/pk11akey.cc",
  91     "third_party/nss/rsawrapr.c",
  92     "third_party/nss/secsign.cc",
  93     "third_party/nss/sha512.cc",
  94   ]
  95
  96   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  97   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  98
  99   deps = [
 100     ":platform",
 101     "//base",
 102     "//base/third_party/dynamic_annotations",
 103   ]
 104
 105   if (!is_mac && !is_ios) {
 106     sources -= [
 107       "apple_keychain.h",
 108       "mock_apple_keychain.cc",
 109       "mock_apple_keychain.h",
 110     ]
 111   }
 112
 113   if (!is_mac) {
 114     sources -= [
 115       "cssm_init.cc",
 116       "cssm_init.h",
 117       "mac_security_services_lock.cc",
 118       "mac_security_services_lock.h",
 119     ]
 120   }
 121   if (!is_win) {
 122     sources -= [
 123       "capi_util.cc",
 124       "capi_util.h",
 125     ]
 126   }
 127
 128   if (is_android) {
 129     deps += [ "//third_party/android_tools:cpu_features" ]
 130   }
 131
 132   if (use_openssl) {
 133     # Remove NSS files when using OpenSSL
 134     sources -= [
 135       "ec_private_key_nss.cc",
 136       "ec_signature_creator_nss.cc",
 137       "encryptor_nss.cc",
 138       "hmac_nss.cc",
 139       "nss_util.cc",
 140       "nss_util.h",
 141       "nss_util_internal.h",
 142       "rsa_private_key_nss.cc",
 143       "secure_hash_default.cc",
 144       "signature_creator_nss.cc",
 145       "signature_verifier_nss.cc",
 146       "symmetric_key_nss.cc",
 147       "third_party/nss/chromium-blapi.h",
 148       "third_party/nss/chromium-blapit.h",
 149       "third_party/nss/chromium-nss.h",
 150       "third_party/nss/pk11akey.cc",
 151       "third_party/nss/rsawrapr.c",
 152       "third_party/nss/secsign.cc",
 153     ]
 154   } else {
 155     # Remove OpenSSL when using NSS.
 156     sources -= [
 157       "ec_private_key_openssl.cc",
 158       "ec_signature_creator_openssl.cc",
 159       "encryptor_openssl.cc",
 160       "hmac_openssl.cc",
 161       "openssl_bio_string.cc",
 162       "openssl_bio_string.h",
 163       "openssl_util.cc",
 164       "openssl_util.h",
 165       "rsa_private_key_openssl.cc",
 166       "secure_hash_openssl.cc",
 167       "signature_creator_openssl.cc",
 168       "signature_verifier_openssl.cc",
 169       "symmetric_key_openssl.cc",
 170     ]
 171   }
 172
 173   defines = [ "CRYPTO_IMPLEMENTATION" ]
 174 }
 175
 176 # TODO(GYP): TODO(dpranke), fix the compile errors for this stuff
 177 # and make it work.
 178 if (false && is_win) {
 179   # A minimal crypto subset for hmac-related stuff that small standalone
 180   # targets can use to reduce code size on Windows. This does not depend on
 181   # OpenSSL/NSS but will use Windows APIs for that functionality.
 182   source_set("crypto_minimal_win") {
 183     sources = [
 184       "crypto_export.h",
 185       "hmac.cc",
 186       "hmac.h",
 187       "hmac_win.cc",
 188       "scoped_capi_types.h",
 189       "scoped_nss_types.h",
 190       "secure_util.cc",
 191       "secure_util.h",
 192       "symmetric_key.h",
 193       "symmetric_key_win.cc",
 194       "third_party/nss/chromium-blapi.h",
 195       "third_party/nss/chromium-sha256.h",
 196       "third_party/nss/sha512.cc",
 197     ]
 198
 199     deps = [
 200       "//base",
 201       "//base/third_party/dynamic_annotations",
 202     ]
 203
 204     defines = [ "CRYPTO_IMPLEMENTATION" ]
 205   }
 206 }
 207
 208 # TODO(GYP): Make this link on win as well.
 209 if (!is_win) {
 210   test("crypto_unittests") {
 211     sources = [
 212       # Tests.
 213       "curve25519_unittest.cc",
 214       "ec_private_key_unittest.cc",
 215       "ec_signature_creator_unittest.cc",
 216       "encryptor_unittest.cc",
 217       "ghash_unittest.cc",
 218       "hkdf_unittest.cc",
 219       "hmac_unittest.cc",
 220       "nss_util_unittest.cc",
 221       "openssl_bio_string_unittest.cc",
 222       "p224_unittest.cc",
 223       "p224_spake_unittest.cc",
 224       "random_unittest.cc",
 225       "rsa_private_key_unittest.cc",
 226       "rsa_private_key_nss_unittest.cc",
 227       "secure_hash_unittest.cc",
 228       "sha2_unittest.cc",
 229       "signature_creator_unittest.cc",
 230       "signature_verifier_unittest.cc",
 231       "symmetric_key_unittest.cc",
 232     ]
 233
 234     if (use_openssl || !is_linux) {
 235       sources -= [ "rsa_private_key_nss_unittest.cc" ]
 236     }
 237
 238     if (use_openssl) {
 239       sources -= [ "nss_util_unittest.cc" ]
 240     } else {
 241       sources -= [ "openssl_bio_string_unittest.cc" ]
 242     }
 243
 244     deps = [
 245       ":crypto",
 246       ":platform",
 247       ":test_support",
 248       "//base",
 249       "//base/test:run_all_unittests",
 250       "//base/test:test_support",
 251       "//testing/gmock",
 252       "//testing/gtest",
 253     ]
 254   }
 255 }
 256
 257 source_set("test_support") {
 258   sources = [
 259     "scoped_test_nss_db.cc",
 260     "scoped_test_nss_db.h",
 261     "scoped_test_nss_chromeos_user.cc",
 262     "scoped_test_nss_chromeos_user.h",
 263     "scoped_test_system_nss_key_slot.cc",
 264     "scoped_test_system_nss_key_slot.h",
 265   ]
 266   deps = [
 267     ":crypto",
 268     ":platform",
 269     "//base",
 270   ]
 271
 272   if (!use_nss_certs) {
 273     sources -= [
 274       "scoped_test_nss_db.cc",
 275       "scoped_test_nss_db.h",
 276     ]
 277   }
 278
 279   if (!is_chromeos) {
 280     sources -= [
 281       "scoped_test_nss_chromeos_user.cc",
 282       "scoped_test_nss_chromeos_user.h",
 283       "scoped_test_system_nss_key_slot.cc",
 284       "scoped_test_system_nss_key_slot.h",
 285     ]
 286   }
 287 }
 288
 289 config("platform_config") {
 290   if (!use_openssl && is_clang) {
 291     # There is a broken header guard in /usr/include/nss/secmod.h:
 292     # https://bugzilla.mozilla.org/show_bug.cgi?id=884072
 293     cflags = [ "-Wno-header-guard" ]
 294   }
 295 }
 296
 297 # This is a meta-target that forwards to NSS's SSL library or OpenSSL,
 298 # according to the state of the crypto flags. A target just wanting to depend
 299 # on the current SSL library should just depend on this.
 300 group("platform") {
 301   if (use_openssl) {
 302     deps = [
 303       "//third_party/boringssl",
 304     ]
 305   } else {
 306     deps = [
 307       "//net/third_party/nss/ssl:libssl",
 308     ]
 309     if (is_linux) {
 310       # On Linux, we use the system NSS (excepting SSL where we always use our
 311       # own).
 312       #
 313       # We always need our SSL header search path to come before the system one
 314       # so our versions are used. The libssl target will add the search path we
 315       # want, but according to GN's ordering rules, public_configs' search path
 316       # will get applied before ones inherited from our dependencies.
 317       # Therefore, we need to explicitly list our custom libssl's config here
 318       # before the system one.
 319       public_configs = [
 320         ":platform_config",
 321         "//net/third_party/nss/ssl:ssl_config",
 322         "//third_party/nss:system_nss_no_ssl_config",
 323       ]
 324     } else {
 325       # Non-Linux platforms use the hermetic NSS from the tree.
 326       deps += [
 327         "//third_party/nss:nspr",
 328         "//third_party/nss:nss",
 329       ]
 330     }
 331   }
 332 }