ash/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8
   9 gypi_values = exec_script("//build/gypi_to_gn.py",
  10                           [ rebase_path("ash.gyp") ],
  11                           "scope",
  12                           [ "ash.gyp" ])
  13
  14 component("ash") {
  15   sources = gypi_values.ash_sources
  16
  17   defines = [ "ASH_IMPLEMENTATION" ]
  18
  19   public_deps = [
  20     "//ash/resources",
  21     "//ash/strings",
  22   ]
  23   deps = [
  24     "//base",
  25     "//base:i18n",
  26     "//base/third_party/dynamic_annotations",
  27     "//cc",
  28     "//components/device_event_log",
  29     "//components/user_manager",
  30     "//components/wallpaper",
  31     "//content/public/browser",
  32     "//media",
  33     "//net",
  34     "//skia",
  35     "//third_party/icu",
  36     "//ui/accessibility",
  37     "//ui/app_list",
  38     "//ui/aura",
  39     "//ui/base",
  40     "//ui/base/ime",
  41     "//ui/compositor",
  42     "//ui/events",
  43     "//ui/events:events_base",
  44     "//ui/events:gesture_detection",
  45     "//ui/events/devices",
  46     "//ui/gfx",
  47     "//ui/gfx/geometry",
  48     "//ui/keyboard",
  49     "//ui/message_center",
  50     "//ui/resources",
  51     "//ui/strings",
  52     "//ui/views",
  53     "//ui/views/controls/webview",
  54     "//ui/web_dialogs",
  55     "//ui/wm",
  56     "//url",
  57   ]
  58
  59   if (is_win) {
  60     sources -= [
  61       "sticky_keys/sticky_keys_controller.cc",
  62       "sticky_keys/sticky_keys_controller.h",
  63     ]
  64
  65     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  66     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  67   }
  68
  69   if (use_x11) {
  70     configs += [
  71       "//build/config/linux:x11",
  72       "//build/config/linux:xfixes",
  73     ]
  74     deps += [
  75       "//ui/events/platform",
  76       "//ui/gfx/x",
  77     ]
  78   } else {
  79     sources -= [
  80       "host/ash_window_tree_host_x11.cc",
  81       "host/ash_window_tree_host_x11.h",
  82       "wm/maximize_mode/scoped_disable_internal_mouse_and_keyboard_x11.cc",
  83       "wm/maximize_mode/scoped_disable_internal_mouse_and_keyboard_x11.h",
  84     ]
  85   }
  86
  87   if (use_ozone) {
  88     deps += [
  89       "//ui/events/ozone:events_ozone",
  90       "//ui/ozone",
  91     ]
  92   }
  93
  94   if (is_chromeos) {
  95     deps += [
  96       "//device/bluetooth",
  97       "//ui/display",
  98       "//ui/display/util",
  99       "//chromeos",
 100       "//chromeos:power_manager_proto",
 101       "//ui/chromeos/resources",
 102       "//ui/chromeos/strings",
 103       "//ui/chromeos:ui_chromeos",
 104     ]
 105   } else {
 106     sources -= [
 107       "accelerators/key_hold_detector.cc",
 108       "accelerators/key_hold_detector.h",
 109       "accelerators/magnifier_key_scroller.cc",
 110       "accelerators/magnifier_key_scroller.h",
 111       "accelerators/spoken_feedback_toggler.cc",
 112       "accelerators/spoken_feedback_toggler.h",
 113       "display/display_configurator_animation.cc",
 114       "display/display_configurator_animation.h",
 115       "display/resolution_notification_controller.cc",
 116       "display/resolution_notification_controller.h",
 117       "system/tray/media_security/media_capture_observer.h",
 118       "system/tray/media_security/multi_profile_media_tray_item.cc",
 119       "system/tray/media_security/multi_profile_media_tray_item.h",
 120       "touch/touch_transformer_controller.cc",
 121       "touch/touch_transformer_controller.h",
 122       "touch/touchscreen_util.cc",
 123       "touch/touchscreen_util.h",
 124       "virtual_keyboard_controller.cc",
 125       "virtual_keyboard_controller.h",
 126     ]
 127   }
 128
 129   if (!use_ozone) {
 130     sources -= [
 131       "host/ash_window_tree_host_ozone.cc",
 132       "wm/maximize_mode/scoped_disable_internal_mouse_and_keyboard_ozone.cc",
 133       "wm/maximize_mode/scoped_disable_internal_mouse_and_keyboard_ozone.h",
 134     ]
 135   }
 136 }
 137
 138 component("ash_with_content") {
 139   sources = [
 140     "content_support/ash_with_content_export.h",
 141     "content_support/gpu_support_impl.cc",
 142     "content_support/gpu_support_impl.h",
 143     "keyboard_overlay/keyboard_overlay_delegate.cc",
 144     "keyboard_overlay/keyboard_overlay_delegate.h",
 145     "keyboard_overlay/keyboard_overlay_view.cc",
 146     "keyboard_overlay/keyboard_overlay_view.h",
 147   ]
 148
 149   defines = [ "ASH_WITH_CONTENT_IMPLEMENTATION" ]
 150
 151   public_deps = [
 152     ":ash",
 153   ]
 154   deps = [
 155     "//base",
 156     "//base/third_party/dynamic_annotations",
 157     "//content/public/browser",
 158     "//ipc",
 159     "//skia",
 160     "//ui/aura",
 161     "//ui/base",
 162     "//ui/compositor",
 163     "//ui/events",
 164     "//ui/gfx",
 165     "//ui/gfx/geometry",
 166     "//ui/resources",
 167     "//ui/strings",
 168     "//ui/views",
 169     "//ui/views/controls/webview",
 170     "//ui/web_dialogs",
 171     "//url",
 172   ]
 173 }
 174
 175 static_library("test_support") {
 176   testonly = true
 177   sources = gypi_values.ash_test_support_sources
 178
 179   public_deps = [
 180     ":ash",
 181   ]
 182   deps = [
 183     "//ash/resources",
 184     "//content/test:test_support",
 185     "//skia",
 186     "//testing/gtest",
 187     "//ui/accessibility",
 188     "//ui/app_list",
 189     "//ui/app_list:test_support",
 190     "//ui/events:events_base",
 191     "//ui/events/devices",
 192     "//ui/gl",
 193     "//ui/views",
 194     "//ui/views:test_support",
 195   ]
 196
 197   if (is_win) {
 198     sources += [
 199       "test/test_metro_viewer_process_host.cc",
 200       "test/test_metro_viewer_process_host.h",
 201     ]
 202     deps += [
 203       "//ipc",
 204       "//ui/metro_viewer",
 205       "//ui/platform_window/win",
 206       "//win8:metro_viewer",
 207       "//win8:test_support_win8",
 208       "//win8:test_registrar",
 209     ]
 210   }
 211 }
 212
 213 static_library("ash_shell_lib") {
 214   testonly = true
 215   sources = gypi_values.ash_shell_lib_sources
 216
 217   deps = [
 218     ":ash",
 219     ":ash_with_content",
 220     ":test_support",
 221     "//ash/resources",
 222     "//ash/strings",
 223     "//base",
 224     "//base:i18n",
 225
 226     #"//chrome:packed_resources",  TODO(GYP)
 227     "//content",
 228     "//content/shell:content_shell_lib",
 229     "//net",
 230     "//skia",
 231     "//third_party/icu",
 232     "//ui/app_list",
 233     "//ui/aura",
 234     "//ui/base",
 235     "//ui/base/ime",
 236     "//ui/compositor",
 237     "//ui/events",
 238     "//ui/events:events_base",
 239     "//ui/gfx",
 240     "//ui/gfx/geometry",
 241     "//ui/keyboard",
 242     "//ui/message_center",
 243     "//ui/resources",
 244     "//ui/views",
 245     "//ui/views:test_support",
 246     "//ui/views/examples:views_examples_lib",
 247     "//ui/views/examples:views_examples_with_content_lib",
 248   ]
 249 }
 250
 251 test("ash_unittests") {
 252   sources = gypi_values.ash_unittests_sources
 253
 254   deps = [
 255     ":ash",
 256     ":ash_with_content",
 257     ":test_support",
 258     "//ash/resources",
 259     "//ash/strings",
 260     "//base",
 261     "//base/allocator",
 262     "//base/test:test_support",
 263     "//components/user_manager",
 264     "//content/public/browser",
 265     "//content/test:test_support",
 266     "//skia",
 267     "//testing/gtest",
 268     "//third_party/icu",
 269     "//ui/accessibility",
 270     "//ui/aura",
 271     "//ui/aura:test_support",
 272     "//ui/base",
 273     "//ui/base/ime",
 274     "//ui/base:test_support",
 275     "//ui/compositor",
 276     "//ui/compositor:test_support",
 277     "//ui/events",
 278     "//ui/events/devices",
 279     "//ui/events:test_support",
 280     "//ui/events:gesture_detection",
 281     "//ui/gfx",
 282     "//ui/gfx/geometry",
 283     "//ui/keyboard",
 284     "//ui/message_center",
 285     "//ui/message_center:test_support",
 286     "//ui/resources",
 287     "//ui/views",
 288     "//ui/views:test_support",
 289     "//ui/views/controls/webview:test_support",
 290     "//ui/web_dialogs:test_support",
 291     "//ui/wm",
 292     "//url",
 293   ]
 294
 295   if (!is_chromeos) {
 296     sources -= [
 297       # TODO(zork): fix this test to build on Windows. See: crosbug.com/26906
 298       "focus_cycler_unittest.cc",
 299
 300       # All tests for multiple displays: not supported on Windows Ash.
 301       "wm/drag_window_resizer_unittest.cc",
 302
 303       # Accelerometer is only available on Chrome OS.
 304       "wm/maximize_mode/maximize_mode_controller_unittest.cc",
 305
 306       # Can't resize on Windows Ash. http://crbug.com/165962
 307       "autoclick/autoclick_unittest.cc",
 308       "magnifier/magnification_controller_unittest.cc",
 309       "sticky_keys/sticky_keys_overlay_unittest.cc",
 310       "system/tray/media_security/multi_profile_media_tray_item_unittest.cc",
 311       "virtual_keyboard_controller_unittest.cc",
 312       "wm/workspace/workspace_window_resizer_unittest.cc",
 313     ]
 314     sources += [
 315       #'<(SHARED_INTERMEDIATE_DIR)/ui/resources/ui_unscaled_resources.rc',  TODO(GYP)
 316     ]
 317   }
 318
 319   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 320
 321   if (!use_x11) {
 322     sources -= [ "host/ash_window_tree_host_x11_unittest.cc" ]
 323   }
 324   if (is_chromeos) {
 325     sources += [ "first_run/first_run_helper_unittest.cc" ]
 326     deps += [
 327       "//device/bluetooth",
 328       "//ui/display",
 329       "//ui/display:test_util",
 330       "//ui/display/types",
 331       "//chromeos:power_manager_proto",
 332       "//chromeos:test_support_without_gmock",
 333     ]
 334   } else {
 335     sources -= [
 336       "accelerators/magnifier_key_scroller_unittest.cc",
 337       "accelerators/spoken_feedback_toggler_unittest.cc",
 338       "display/resolution_notification_controller_unittest.cc",
 339       "touch/touchscreen_util_unittest.cc",
 340     ]
 341   }
 342
 343   if (!use_x11 || !is_chromeos) {
 344     sources -= [ "touch/touch_transformer_controller_unittest.cc" ]
 345   }
 346
 347   # TODO(GYP) is this necessary?
 348   #['OS=="linux" and component=="shared_library" and use_allocator!="none"', {
 349   # ldflags = "-rdynamic"
 350
 351   if (!is_chromeos || use_ozone) {
 352     sources -= [ "sticky_keys/sticky_keys_unittest.cc" ]  # crbug.com/354035
 353   }
 354 }
 355
 356 executable("ash_shell") {
 357   testonly = true
 358   sources = [
 359     "shell/shell_main.cc",
 360   ]
 361
 362   deps = [
 363     ":ash_shell_lib",
 364     "//components/user_manager",
 365   ]
 366
 367   if (is_win) {
 368     configs -= [ "//build/config/win:console" ]
 369     configs += [ "//build/config/win:windowed" ]
 370     deps += [ "//sandbox" ]
 371   }
 372
 373   if (is_chromeos) {
 374     deps += [ "//device/bluetooth" ]
 375   }
 376 }
 377
 378 test("ash_shell_unittests") {
 379   sources = [
 380     "shell/window_watcher_unittest.cc",
 381     "test/ash_unittests.cc",
 382   ]
 383
 384   deps = [
 385     ":ash_shell_lib",
 386     ":test_support",
 387     "//base/test:test_support",
 388     "//components/user_manager",
 389     "//content/test:test_support",
 390     "//skia",
 391     "//testing/gtest",
 392     "//ui/accessibility",
 393   ]
 394
 395   if (is_chromeos) {
 396     deps += [ "//ui/display" ]
 397   }
 398 }
 399 # When adding support for isolates, please have a look at run-time dependencies
 400 # in the ash_unittests_run target in ash.gyp.