BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This is the root build file for GN. GN will start processing by loading this
   6 # file, and recursively load all dependencies until all dependencies are either
   7 # resolved or known not to exist (which will cause the build to fail). So if
   8 # you add a new build file, there must be some path of dependencies from this
   9 # file to your new one or GN won't know about it.
  10
  11 import("//build/config/ui.gni")
  12
  13 # In GN, a "group" is a dummy target that just lists other targets.
  14 group("root") {
  15   # This should not be linked into production and depends on test targets.
  16   testonly = true
  17
  18   # Note that some dependencies are commented out. These are things that are
  19   # currently written but not hooked up to the build yet. They may need to be
  20   # completed or possibly just tested and then re-enabled.
  21   deps = [
  22     "//apps",
  23     "//ash",
  24     "//cc",
  25     "//cc/blink",
  26     "//chrome/browser",
  27     "//chrome/browser/devtools",
  28     "//chrome/browser/ui",
  29     "//chrome/browser/ui/views",
  30     "//chrome/common",
  31     "//chrome/plugin",
  32     "//chrome/renderer",
  33     "//chrome/service",
  34     "//chrome/utility",
  35     "//components:all_components",
  36     "//content",
  37     "//content/shell:content_shell",
  38     "//content/test:test_support",
  39     "//crypto",
  40     "//device/bluetooth",
  41     "//device/nfc",
  42     "//extensions/browser",
  43     "//extensions/common",
  44     "//extensions/common/api",
  45     "//extensions/renderer",
  46     "//gin",
  47     "//gpu",
  48     "//google_apis",
  49     "//google_apis/gcm",
  50     "//ipc",
  51     "//ipc/mojo",
  52     "//jingle:notifier",
  53     "//media",
  54     "//media/blink",
  55     "//media/cast",
  56     "//mojo",
  57     "//net",
  58     "//pdf",
  59     "//ppapi:ppapi_c",
  60     "//printing",
  61     "//remoting/client/plugin",
  62     "//sandbox",
  63     "//sdch",
  64     "//skia",
  65     "//storage/browser",
  66     "//sql",
  67     "//sync",
  68     "//third_party/WebKit/public:all_blink",
  69     "//third_party/angle:translator",
  70     "//third_party/brotli",
  71     "//third_party/cacheinvalidation",
  72     "//third_party/cld",
  73     "//third_party/cld_2",
  74     "//third_party/ffmpeg",
  75     "//third_party/flac",
  76     "//third_party/harfbuzz-ng",
  77     "//third_party/hunspell",
  78     "//third_party/iccjpeg",
  79     "//third_party/icu",
  80     "//third_party/leveldatabase",
  81     "//third_party/libaddressinput",
  82     "//third_party/libphonenumber",
  83     "//third_party/libjingle",
  84     "//third_party/libpng",
  85     "//third_party/libsrtp",
  86     "//third_party/libusb",
  87     "//third_party/libwebm",
  88     "//third_party/libwebp",
  89     "//third_party/libxslt",
  90     "//third_party/libyuv",
  91     "//third_party/lzma_sdk",
  92     "//third_party/mesa",
  93     "//third_party/opus",
  94     "//third_party/ots",
  95     "//third_party/protobuf:protobuf_lite",
  96     "//third_party/qcms",
  97     "//third_party/re2",
  98     "//third_party/smhasher:cityhash",
  99     "//third_party/smhasher:murmurhash3",
 100     "//third_party/smhasher:pmurhash",
 101     "//third_party/snappy",
 102     "//third_party/speex",
 103     "//third_party/usrsctp",
 104     "//third_party/widevine/cdm:version_h",
 105     "//third_party/webrtc",
 106     "//third_party/zlib",
 107     "//third_party:jpeg",
 108     "//tools/gn",
 109     "//tools/imagediff($host_toolchain)",
 110     "//ui/accessibility",
 111     "//ui/app_list",
 112     "//ui/aura",
 113     "//ui/base",
 114     "//ui/display",
 115     "//ui/events",
 116     "//ui/gfx",
 117     "//ui/gl",
 118     "//ui/keyboard",
 119     "//ui/native_theme",
 120     "//ui/resources",
 121     "//ui/snapshot",
 122     "//ui/strings",
 123     "//ui/surface",
 124     "//ui/views",
 125     "//ui/views/controls/webview",
 126     "//ui/web_dialogs",
 127     "//ui/wm",
 128     "//url",
 129     "//v8:v8",
 130   ]
 131
 132   if (!is_win) {
 133     deps += [ "//breakpad:symupload" ]
 134   }
 135
 136   if (is_linux) {
 137     deps += [
 138       "//dbus",
 139       "//third_party/fontconfig",
 140       "//third_party/freetype2",
 141     ]
 142   }
 143
 144   if (use_x11) {
 145     deps += [ "//tools/xdisplaycheck" ]
 146   }
 147
 148   if (is_win) {
 149     deps += [
 150       "//ui/metro_viewer",
 151     ]
 152   }
 153
 154   if (is_win || is_mac || is_chromeos) {
 155     # RLZ works on these platforms.
 156     deps += [
 157       "//rlz:rlz_lib",
 158     ]
 159   }
 160
 161   if (cpu_arch == "x86" || cpu_arch == "x64") {
 162     # YASM is x86/x64 only.
 163     deps += [ "//third_party/yasm($host_toolchain)" ]
 164   }
 165
 166   if (is_android) {
 167     deps += [
 168       "//content/shell/android:content_shell_apk",
 169       "//ui/android:ui_java",
 170       "//third_party/guava:guava_javalib",
 171       "//third_party/android_tools:android_gcm_java",
 172       "//third_party/android_tools:uiautomator_java",
 173       "//third_party/android_tools:android_support_v13_java",
 174       "//third_party/android_tools:android_support_v7_appcompat_java",
 175       "//third_party/android_tools:android_support_v7_mediarouter_java",
 176       "//third_party/eyesfree:eyesfree_java",
 177     ]
 178
 179     deps -= [
 180       "//apps",  # Needs testing.
 181       "//cc/blink", # Blocked on blink
 182       "//chrome/browser",  # Blocked on content.
 183       "//chrome/browser/devtools",  # Blocked on content.
 184       "//chrome/browser/ui",  # Blocked on content.
 185       "//chrome/browser/ui/views",  # Blocked on content.
 186       "//chrome/common",  # Blocked on content.
 187       "//chrome/plugin",  # Blocked on content.
 188       "//chrome/renderer",  # Blocked on content.
 189       "//chrome/service",  # Blocked on content.
 190       "//chrome/utility",  # Blocked on content.
 191       "//content",
 192       "//content/shell:content_shell",  # Blocked on content.
 193       "//content/test:test_support",  # Blocked on content.
 194       "//extensions/browser",
 195       "//extensions/common",
 196       "//extensions/common/api",
 197       "//extensions/renderer",
 198       "//media/blink",  # Blocked on blink
 199       "//pdf",  # Not compiled on Android in GYP yet, either.
 200       "//ppapi:ppapi_c",
 201       "//sandbox",
 202       "//third_party/libusb",
 203       "//ui/keyboard",  # Blocked on content.
 204
 205       # Blocked on neon stuff in vp8
 206       "//third_party/WebKit/public:all_blink",
 207
 208       # Seems to not be compiled on Android. Otherwise it will need a config.h.
 209       "//third_party/libxslt",
 210
 211       # Not relevant to Android.
 212       "//ash",
 213       "//tools/gn",
 214       "//ui/aura",
 215       "//ui/display",
 216       "//ui/views",
 217       "//ui/views/controls/webview",
 218
 219       # Fails on Android for unknown reasons.
 220       "//third_party/flac",
 221       "//breakpad:symupload",
 222
 223       # Not tested on Android yet:
 224       "//google_apis/gcm",
 225       "//remoting/client/plugin",
 226       "//storage/browser",
 227       "//third_party/cld_2",
 228       "//third_party/libaddressinput",
 229       "//third_party/ffmpeg",
 230       "//ui/app_list",
 231       "//ui/web_dialogs",
 232       "//ui/wm",
 233     ]
 234   }
 235
 236   if (use_ozone) {
 237     deps += [
 238       "//ui/ozone",
 239       "//ui/ozone/demo",
 240     ]
 241   }
 242
 243   # Non-mobile builds.
 244   if (!is_android && !is_ios) {
 245     deps += [
 246       "//device/usb",
 247     ]
 248   }
 249 }