content/common/user_agent_ios.mm

   1 // Copyright 2014 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "content/public/common/user_agent.h"
   6
   7 #import <UIKit/UIKit.h>
   8
   9 #include <sys/sysctl.h>
  10 #include <string>
  11
  12 #include "base/mac/scoped_nsobject.h"
  13 #include "base/strings/string_util.h"
  14 #include "base/strings/stringprintf.h"
  15 #include "base/strings/sys_string_conversions.h"
  16 #include "base/sys_info.h"
  17
  18 namespace {
  19
  20 struct UAVersions {
  21   const char* safari_version_string;
  22   const char* webkit_version_string;
  23 };
  24
  25 struct OSVersionMap {
  26   int32 major_os_version;
  27   int32 minor_os_version;
  28   UAVersions ua_versions;
  29 };
  30
  31 const UAVersions& GetUAVersionsForCurrentOS() {
  32   // The WebKit version can be extracted dynamically from UIWebView, but the
  33   // Safari version can't be, so a lookup table is used instead (for both, since
  34   // the reported versions should stay in sync).
  35   static const OSVersionMap version_map[] = {
  36     { 7, 1, { "9537.53",   "537.51.2" } },
  37     { 7, 0, { "9537.53",   "537.51.1" } },
  38     // 6.1 has the same values as 6.0.
  39     { 6, 0, { "8536.25",   "536.26" } },
  40   };
  41
  42   int32 os_major_version = 0;
  43   int32 os_minor_version = 0;
  44   int32 os_bugfix_version = 0;
  45   base::SysInfo::OperatingSystemVersionNumbers(&os_major_version,
  46                                                &os_minor_version,
  47                                                &os_bugfix_version);
  48
  49   // Return the versions corresponding to the first (and thus highest) OS
  50   // version less than or equal to the given OS version.
  51   for (unsigned int i = 0; i < arraysize(version_map); ++i) {
  52     if (os_major_version > version_map[i].major_os_version ||
  53         (os_major_version == version_map[i].major_os_version &&
  54          os_minor_version >= version_map[i].minor_os_version))
  55       return version_map[i].ua_versions;
  56   }
  57   NOTREACHED();
  58   return version_map[arraysize(version_map) - 1].ua_versions;
  59 }
  60
  61 }  // namespace
  62
  63 namespace content {
  64
  65 std::string BuildOSCpuInfo() {
  66   int32 os_major_version = 0;
  67   int32 os_minor_version = 0;
  68   int32 os_bugfix_version = 0;
  69   base::SysInfo::OperatingSystemVersionNumbers(&os_major_version,
  70                                                &os_minor_version,
  71                                                &os_bugfix_version);
  72   std::string os_version;
  73   if (os_bugfix_version == 0) {
  74     base::StringAppendF(&os_version,
  75                         "%d_%d",
  76                         os_major_version,
  77                         os_minor_version);
  78   } else {
  79     base::StringAppendF(&os_version,
  80                         "%d_%d_%d",
  81                         os_major_version,
  82                         os_minor_version,
  83                         os_bugfix_version);
  84   }
  85
  86   // Remove the end of the platform name. For example "iPod touch" becomes
  87   // "iPod".
  88   std::string platform = base::SysNSStringToUTF8(
  89       [[UIDevice currentDevice] model]);
  90   size_t position = platform.find_first_of(" ");
  91   if (position != std::string::npos)
  92     platform = platform.substr(0, position);
  93
  94   std::string os_cpu;
  95   base::StringAppendF(
  96       &os_cpu,
  97       "%s; CPU %s %s like Mac OS X",
  98       platform.c_str(),
  99       (platform == "iPad") ? "OS" : "iPhone OS",
 100       os_version.c_str());
 101
 102   return os_cpu;
 103 }
 104
 105 std::string BuildUserAgentFromProduct(const std::string& product) {
 106   // Retrieve the kernel build number.
 107   int mib[2] = {CTL_KERN, KERN_OSVERSION};
 108   unsigned int namelen = sizeof(mib) / sizeof(mib[0]);
 109   size_t bufferSize = 0;
 110   sysctl(mib, namelen, NULL, &bufferSize, NULL, 0);
 111   char kernel_version[bufferSize];
 112   int result = sysctl(mib, namelen, kernel_version, &bufferSize, NULL, 0);
 113   DCHECK(result == 0);
 114
 115   UAVersions ua_versions = GetUAVersionsForCurrentOS();
 116
 117   std::string user_agent;
 118   base::StringAppendF(&user_agent,
 119                       "Mozilla/5.0 (%s) AppleWebKit/%s"
 120                       " (KHTML, like Gecko) %s Mobile/%s Safari/%s",
 121                       BuildOSCpuInfo().c_str(),
 122                       ua_versions.webkit_version_string,
 123                       product.c_str(),
 124                       kernel_version,
 125                       ua_versions.safari_version_string);
 126
 127   return user_agent;
 128 }
 129
 130 }  // namespace content